Dirac
22710180
- Reaction score
- 147
JASS:
library AmplifyDamage /* v1.0.4
*/uses/*
*/ DamageMod /* thehelper.net/forums/showthread.php/168198-Damage-Mod
A useful tool to handle percentual damage from units.
**********************************************************************/
globals
private constant integer AMPLIFY_DAMAGE_PRIORITY =3
//The priority sets before and after which damage mods the bonus damage
//is dealt.
endglobals
/**********************************************************************
*
* struct AmplifyDamage
*
* - Modifies unit damage dealt by percentual value.
* - Takes the unit's custom value as an instance.
*
* real amount
* - Determines how much percentual damage the will be
* - modified for the unit.
* readonly static DamageMod MOD
* - The mod used for this code.
* method addFilter takes code func returns triggercondition
* - If the filter returns false then it skips damage
* - modification.
* method removeFilter takes triggercondition whichCondition returns nothing
* - Disables the filter
*
*********************************************************************/
private module AmplifyDamageModule
readonly static DamageMod MOD
private trigger trig
real amount
method addFilter takes code func returns triggercondition
if null==this.trig then
set this.trig=CreateTrigger()
endif
return TriggerAddCondition(this.trig,Filter(func))
endmethod
method removeFilter takes triggercondition whichCondition returns nothing
call TriggerRemoveCondition(this.trig,whichCondition)
endmethod
private static method onDamage takes nothing returns boolean
local real result=thistype(Damage.sourceId).amount*Damage.dealt
if result>0 then
if not(null==thistype(Damage.sourceId).trig) then
if not(TriggerEvaluate(thistype(Damage.targetId).trig)) then
return false
endif
endif
call Damage.add(result)
endif
return false
endmethod
private static method onInit takes nothing returns nothing
set MOD=DamageMod.create(function thistype.onDamage,AMPLIFY_DAMAGE_PRIORITY)
endmethod
endmodule
struct AmplifyDamage extends array
implement AmplifyDamageModule
endstruct
endlibrary
