Another Base Spell

[WolfieeifloW]

I know I've been asking this a lot, but I can't seem to find a suitable spell to base my custom spell off of.
Maybe I'm just overlooking them because I'm trying so hard to find them..

Anyways,
This time, I need a spell that's an attack modifier, not auto-cast, and active.
I need two, actually, but I can live with one.

Attack modifier meaning adds onto the unit's normal attack.
Does the units normal damage + the spells damage.
Think Searing Arrow, Black Arrow, etc.

 

[Weep]

This time, I need a spell that's an attack modifier, not auto-cast, and active.

What do you mean, "attack modifier"? You mean, like Roar? Or something else? It'd be useful to know what your goal is.

 

[NeuroToxin]

Roar increases attack damage, or decreases, Howl Of Terror increases/decreases both attack speed and attack damage (Damage is unverified)

 

[WolfieeifloW]

I mean something like Searing Arrows, Black Arrow, etc.
Something that just adds onto an attack (Does normal damage + spell damage).

 

[Grymlax]

Maybe I'm missunderstanding you but there is no active non-autocast attack modifier in the game. sure you don't want a passive one?

Othervise i guess you would have to trigger it.

Edit:
An easy way to trigger it would be to base your spell on a active ability, when casted you create a dummy hero unit at the location of your caster, give the dummy the same items as your hero and the same level, add a short death timer so he only has time to attack once and order him to attack the target unit of the spell. The only difference between your attack and the dummy's attack damage would be if you had some sort of damage buff on your caster.

 

[WolfieeifloW]

There's none?
Darnit..

I know, or at least I'm pretty sure, there's a way to detect a player trying to auto-cast a spell?
Couldn't I just use an auto-cast spell, but make the icon without the yellow borders, then just trigger it so if the player tries to auto-cast it, it won't let them?

 

[KaerfNomekop]

You can, by issuing the order "unflamingarrows" when a unit is issued "flamingarrows". Then make the icon a normal BTN, so that players don't suspect it to be an autocast ability in the first place. It works with several DotA spells, like Lich's Dark Ritual and Dark Seer's Surge.

 

[WolfieeifloW]

Hmm, this doesn't seem to work:

scope UnMangle initializer UMInit

    private function UMConditions takes nothing returns boolean
        call BJDebugMsg("Running Conditions")
        if (GetIssuedOrderId() == OrderId("flamingarrows")) then
            call BJDebugMsg("Passed conditions")
            call IssueImmediateOrder(GetTriggerUnit(), "unflamingarrows")
        endif
        return false
    endfunction
    
    private function UMInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call BJDebugMsg("Running!")
        
        call TriggerRegisterPlayerUnitEvent(t, Player(0), EVENT_PLAYER_UNIT_ISSUED_ORDER, null)
        call TriggerAddCondition(t, Condition(function UMConditions))
    endfunction

endscope

It shows all messages, but doesn't turn off the arrows.

 

[Tom_Kazansky]

you need to use 0.00s timer: issue "flamingarrows" -> 0.00s timer -> issue "unflamingarrows"

scope UnMangle initializer UMInit
    globals
        private unit TEMPUNIT
        // use one global unit for the callback of the timer
        // this is not really safe but I think the chance for it to screw up is really low
        private timer TEMPTIMER = CreateTimer()
    endglobals
    
    private function CallBack takes nothing returns nothing
        call BJDebugMsg("Turn off arrows")
        call IssueImmediateOrder(TEMPUNIT, "unflamingarrows")
    endfunction

    private function UMConditions takes nothing returns boolean
        call BJDebugMsg("Running Conditions")
        if (GetIssuedOrderId() == OrderId("flamingarrows")) then
            call BJDebugMsg("Passed conditions")
            set TEMPUNIT = GetTriggerUnit()
            call TimerStart( TEMPTIMER, 0.00, false, function CallBack )
        endif
        return false
    endfunction
    
    private function UMInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call BJDebugMsg("Running!")
        
        call TriggerRegisterPlayerUnitEvent(t, Player(0), EVENT_PLAYER_UNIT_ISSUED_ORDER, null)
        call TriggerAddCondition(t, Condition(function UMConditions))
    endfunction

endscope

 

[keychup]

I usually use this:

Ability Type: Abilities that apply a buff (eg: Auto-cast Black Arrow or Passive Slow Poison)

Event - A unit is attacked
Conditions - Level of Ability for Attacking Unit is greater than or equal to 1
Actions - Wait For Condition(Attacked Unit has Buff is Equal to True)
Cause Attacking Unit to damage Attacked Unit dealing X damage of damage type X and attack type Z

 

[WolfieeifloW]

That works, Tom_Kazansky.
However, is there anyway to make it not do the.. 'ting' sound?

 

[Tom_Kazansky]

>However, is there anyway to make it not do the.. 'ting' sound?

unfortunately, no

oh, and I just found this:

scope UnMangle initializer UMInit
    globals
        private unit TEMPUNIT
        // use one global unit for the callback of the timer
        // this is not really safe but I think the chance for it to screw up is really low
        private timer TEMPTIMER = CreateTimer()

        private constant integer  ABILITY_ID = 'AHfa'  //your ability
    endglobals
    
    private function CallBack takes nothing returns nothing
        call BJDebugMsg("Turn off arrows")
        call SetPlayerAbilityAvailable(GetOwningPlayer(TEMPUNIT),   ABILITY_ID   , true)   // enable
    endfunction

    private function UMConditions takes nothing returns boolean
        call BJDebugMsg("Running Conditions")
        if (GetIssuedOrderId() == OrderId("flamingarrows")) then
            call BJDebugMsg("Passed conditions")
            set TEMPUNIT = GetTriggerUnit()
            call SetPlayerAbilityAvailable(GetOwningPlayer(TEMPUNIT),   ABILITY_ID   ,false)  // disable
            call TimerStart( TEMPTIMER, 0.00, false, function CallBack )
        endif
        return false
    endfunction
    
    private function UMInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call BJDebugMsg("Running!")
        
        call TriggerRegisterPlayerUnitEvent(t, Player(0), EVENT_PLAYER_UNIT_ISSUED_ORDER, null)
        call TriggerAddCondition(t, Condition(function UMConditions))
    endfunction

endscope

instead of issue "unflamingarrows": do "disable ability" -> timer 0.00 -> "enable ability"
this way, the order of the unit will NOT be interrupted

 

[WolfieeifloW]

Thank you !
I chucked a SimError in there to make it look pretty:

scope UnMangle initializer UMInit

    globals
        private unit TEMPUNIT
        private timer TEMPTIMER = CreateTimer()
        private constant integer ABILITY_ID = 'A00C'  //your ability
    endglobals
    
    private function CallBack takes nothing returns nothing
        call SetPlayerAbilityAvailable(GetOwningPlayer(TEMPUNIT), ABILITY_ID, true)
    endfunction

    private function UMConditions takes nothing returns boolean
        if (GetIssuedOrderId() == OrderId("flamingarrows")) then
            set TEMPUNIT = GetTriggerUnit()
            call SetPlayerAbilityAvailable(GetOwningPlayer(TEMPUNIT), ABILITY_ID, false)
            call TimerStart(TEMPTIMER, 0.00, false, function CallBack)
            call SimError(Player(0), "This spell isn't auto-cast!")
        endif
        return false
    endfunction
    
    private function UMInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call TriggerRegisterPlayerUnitEvent(t, Player(0), EVENT_PLAYER_UNIT_ISSUED_ORDER, null)
        call TriggerAddCondition(t, Condition(function UMConditions))
    endfunction

endscope

 

[Weep]

However, is there anyway to make it not do the.. 'ting' sound?

You could overwrite the native "ting" sound with an imported small silent sound file, then re-import the actual "ting" sound and trigger it to play for other autocast abilities...