System BlueSin's Recipe System

[BlueSin]

The Recipe System is for items that require you to have certain
items before you can buy, or 'upgrade', to another, better item.
It handles many different scenarios, all demonstrated in a 'Demo Recipes' trigger. (See Below)

Please Credit if used.

Example Recipes:

//Recipe Input: (The Buying Unit, The New Item ID, Required Item #1 ID, Required Item #2 ID,
//        Required Item #3 ID, Gold Cost, Lumber Cost, Bought or Not)

function Trig_Test_Actions takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local integer id=GetItemTypeId(GetManipulatedItem())

//Upgraded Through Store
    //Axe
    if(id == 'I000' )then
        call Recipe(u, 'I000','I004','I005',0,100,200,true)
    endif
    //Sword
    if(id == 'I002' )then
        call Recipe(u, 'I002','I004','I004','I004',125,0,true)
    endif
    //Staff
    if(id == 'I001' )then
        call Recipe(u, 'I001','I005','I005',0,150,50,true)
    endif
    //Super Axe
    if(id == 'I003' )then
        call Recipe(u, 'I003','I005','I005',0,400,400,true)
    endif

//Simply Combined (No Store Involved)
    //Ghetto Orb
    if(id == 'I006')then
        call Recipe(u, 'I007','I006','I006','I006',0,0,false)
    endif
    //Good Orb (But also Great Orb + Good Orb=Ghetto Orb)
    if(id == 'I007')then
        call Recipe(u, 'I008','I007','I007',0,0,0,false)
        call Recipe(u, 'I006','I008','I008','I007',0,0,false)
    endif
    //Ghetto Orb
    if(id == 'I008')then
        call Recipe(u, 'I006','I008','I008','I007',0,0,false)
    endif

    set u=null 
endfunction

//===========================================================================
function InitTrig_Demo_Recipes takes nothing returns nothing
    set gg_trg_Demo_Recipes = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Demo_Recipes, EVENT_PLAYER_UNIT_PICKUP_ITEM )
    call TriggerAddAction( gg_trg_Demo_Recipes, function Trig_Test_Actions )
endfunction

EDIT:

> call Recipe(u, 'I000','I004','I005',0,100,200,true)

Does it explain, somewhere in that map, what that line might do?
If not, why not?
If yes, would I get it? Without knowing JASS?

This seems to be taking three weird numbers that I guess are IDs, what are the others?

Can I edit this thing somehow to work with 4 items + recipe = something?

 

[Vrogarr]

I used this system in my map and was fairly pleased with it once I modified it a bit.

The main problem I had before modifying it was in buying a trigger item, dropping it, and picking it back up. The item would remove itself from inventory just as if I had tried to purchase it without having the proper ingredient requirements.

My fix involved creating both a purchaseable dummy item to go in the shop and a "real" item that would be created when the purchased dummy item was acquired.

This also involved changing the "Recipe" Function as follows

function Recipe takes unit u, integer triggeritem, integer newitem, integer r1, integer r2, integer r3, integer g, integer l, boolean bought returns nothing
    local location loc
    local player p
    local boolean go=false
    if((r1==r2)and(r1==r3))then
        if(HasItem(u,r1,3)) then
            set go=true
        endif
    elseif((r1==r2)and(go==false))then
        if((HasItem(u,r1,2))and(HasItem(u,r3,1))) then
            set go=true
        endif
    elseif( (HasItem(u,r1,1)) and (HasItem(u,r2,1)) and (HasItem(u,r3,1)) and (go==false) )then
        set go=true
    endif

    if(go)then
        call RemoveItem(GetItemOfTypeFromUnitBJ(u, triggeritem) )
        call RemoveItem(GetItemOfTypeFromUnitBJ(u, r1) )
        call RemoveItem(GetItemOfTypeFromUnitBJ(u, r2) )
        call RemoveItem(GetItemOfTypeFromUnitBJ(u, r3) )
        call UnitAddItemById( u,newitem )
        set loc = GetUnitLoc(u)
        call AddSpecialEffectLocBJ( loc, "Abilities\\Spells\\Items\\AIam\\AIamTarget.mdl" )
        call DestroyEffect( bj_lastCreatedEffect )
        call RemoveLocation(loc)
    else
        if(bought)then
            call RemoveItem(GetItemOfTypeFromUnitBJ(u, triggeritem) )
            set p = GetOwningPlayer(u)
            call DisplayTextToPlayer(p, 0, 0, "|CFFFFFF00Insufficient Ingredients.")
            call AdjustPlayerStateBJ( g, p, PLAYER_STATE_RESOURCE_GOLD )
            call AdjustPlayerStateBJ( l, p, PLAYER_STATE_RESOURCE_LUMBER )
        endif           
    endif
    set u=null
    set loc=null
    set p=null
endfunction

As such, the Recipes trigger format had to be changed as well. Here is an example call:

//Upgraded Through Store
//if (id = fake item)
//    call Recipe(u, 'Trigger Item', 'Real Item', 'Real Ingredient', 'Real Ingredient', 'Real Ingredient', gold, lumber, true)

    //Banner of Fury, requires Ring of Dexterity, Boots of Speed, Gloves of Haste and 125 gold
    if(id == 'I01L' )then
        call Recipe(u, 'I01L', 'I01I','I004','I00D','I013',125,0,true)
    endif

I haven't used the non-store-bought items functionality in my map and cannot say if the changes I made will work with items created without purchasing something (ala DotA Perserverance or Battle Fury)