Calling a JASS Function

[Malice-]

I found a good JASS Code by Vex from wc3sear.ch, only thing is, I'm not sure how to call it. I got the variables you need down, and I know the event is map initilization, but what is the action to call the code?

This may serve no purpose, but here is the code:

function CreepRespawn_CampLength takes nothing returns real
    return 500.0
endfunction
 
function CreepRespawn_WaitTime takes nothing returns real
    return 60.0
endfunction
 
function CreepRespawn takes nothing returns gamecache
    if (udg_creepcamps==null) then
        set udg_creepcamps=InitGameCache("creepcamps.c")
    endif
    return udg_creepcamps
endfunction
 
function CreepRespawn_H2I takes handle h returns integer
    return h
    return 0
endfunction
 
function CreepRespawn_GetCamp takes gamecache g, string k returns group
    return GetStoredInteger(g,k,"camp")
    return null
endfunction
 
function RespawnCreepCamp takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local string k=I2S(CreepRespawn_H2I(u))
    local integer typeid = GetUnitTypeId(u)
    local gamecache g=CreepRespawn()
    local group camp=CreepRespawn_GetCamp(g,k)
    local real x=GetStoredReal(g,k,"sx")
    local real y=GetStoredReal(g,k,"sy")
    local real f=GetStoredReal(g,k,"sf")
    local rect r=bj_mapInitialPlayableArea
    if not( HaveStoredReal(g,k,"sx") ) then
    else
        call GroupRemoveUnit(camp,u)
        loop
            exitwhen FirstOfGroup(camp)==null
            call TriggerSleepAction(1)
        endloop
        call PolledWait(CreepRespawn_WaitTime())
        if IsUnitType(GetTriggerUnit(), UNIT_TYPE_HERO) then
            call SetUnitOwner( u, Player(1), false)
            call ReviveHero( u, x, y, true)
            call SetUnitOwner( u, Player(12), false)
            call GroupAddUnit(camp,u)
        else
            call FlushStoredMission(g,k)
            set u=CreateUnit( Player(12), typeid, x,y,f )
            set k=I2S(CreepRespawn_H2I(u))
            call DestroyEffect( AddSpecialEffectTarget( "Abilities\\Spells\\Human\\MassTeleport\\MassTeleportCaster.mdl", u, "origin"))
            call StoreReal( g ,k,"sx", x )
            call StoreReal( g ,k,"sy", y )
            call StoreReal( g ,k,"sf", f )
            call StoreInteger(g,k,"camp",CreepRespawn_H2I(camp) )
            call GroupAddUnit(camp,u)
        endif
    endif
    set camp=null
    set u=null
    set g=null
    set r=null
endfunction
 
function StartCreepCampRespawn_Filter takes nothing returns boolean
    return IsUnitOwnedByPlayer( GetFilterUnit(), Player(12) ) and IsUnitInGroup(GetFilterUnit(),bj_groupRemoveGroupDest)
endfunction
 
function StartCreepCampRespawn takes nothing returns trigger
    local trigger t = CreateTrigger()
    local gamecache g=CreepRespawn()
    local boolexpr B=Condition(function StartCreepCampRespawn_Filter)
    local group r=CreateGroup()
    local group aux=CreateGroup()
    local group aux2=CreateGroup()
    local group c
    local unit u
    local string k
    call GroupEnumUnitsOfPlayer(r,Player(12), null)
    set bj_groupRemoveGroupDest=r
    loop
        set u=FirstOfGroup(r)
        exitwhen u==null
        call GroupRemoveUnit(r,u)
        set c=CreateGroup()
        set bj_groupAddGroupDest=c
        call GroupClear(aux)
        loop
            call GroupClear(aux2)
            call GroupEnumUnitsInRange(aux2,GetUnitX(u),GetUnitY(u),CreepRespawn_CampLength(),B)
            call GroupAddGroup(aux2,aux)
            call GroupRemoveUnit(aux,u)
            call GroupRemoveUnit(r,u)
            call GroupAddUnit(c,u)
            set k=I2S(CreepRespawn_H2I(u))
            call StoreReal( g ,k,"sx", GetUnitX(u) )
            call StoreReal( g ,k,"sy", GetUnitY(u) )
            call StoreReal( g ,k,"sf", GetUnitFacing(u) )
            call StoreInteger(g,k,"camp",CreepRespawn_H2I(c) )
            set u=FirstOfGroup(aux)
            exitwhen u==null
        endloop
    endloop
    call DestroyGroup(r)
    call DestroyGroup(aux)
    call DestroyGroup(aux2)
    call DestroyBoolExpr(B)
    set B=null
    set r=null
    set aux=null
    set aux2=null
    call TriggerRegisterPlayerUnitEvent( t, Player(12), EVENT_PLAYER_UNIT_DEATH,null )
    call TriggerAddAction( t, function RespawnCreepCamp )
    return t
endfunction

 

[SD_Ryoko]

I am not sure which trigger should be called to kick it off, but you would use

Custom script:

Then type in the blank

call StartCreepCampRespawn() (or whichever it is)

 

[Malice-]

Well, I'll try that. I am fine with using triggers, but completly oblivious to JASS. This is my first JASS code used in a map. If what you just gave me doesn't work I am not sure I will be able to find what does, lol. Where do I look in the code to find this?

 

[Darg]

if you don't know what it does, why are you using it? or are you just curious? It could very well require certain units be created and setup in the object editor, and unless you have that information already you might not be able to get the trigger to work.

It's strange code that, the trigger gets registered at the bottom of the function...

hmm...this might be over even my head...

 

[Malice-]

Ok well... I know what the code does. All the creep camps in your map will respawn automatically after a set amount of seconds, The function detects the creepcamps so all the members of a creep camp respawn at the same time.

But anways, the calling function, that Ryoko mentioned is right. Its just that it makes no sense to me. How would that tiny line work, when that whole code that i just showed you isnt even in the map anywhere? Is there somewhere in the editor that allows me to put that entire code into the map?

 

[SD_Ryoko]

Okay.

You take all of vexorians stuff.

Create a blank trigger. Convert it to custom, and paste his stuff in. NOW its in your map.

Then from your map init, do the call function I showed you.

All functions are loaded when the map loads, so it knows where to find them.

// when you save your map, world editor builds the 'load list'.

Darg: World edit is like that, for whatever reason it puts all the children functions and condition functions in front of the main beef. Dunno why. Order is irrelevant though, because it loads them all when the map is loaded.

 

[Malice-]

Okay... I got the function into the map, but I'm still getting the same error. It comes up and says this:

 

[Malice-]

Can anyone help me out?

 

[Rinpun]

Hey, malice. I pointed this out in AIM, but the error is in this line:

call GroupEnumUnitsInRange(aux2,GetUnitX(u),GetUnitY(u),CreepRespawn_CampLe ngth(),B)

I wonder why Vex had this hole in his code and why others did not have trouble. I suppose they figured out the same

It, obviously, is just a simple spelling error. Apparently there is something strange about typing this in the thing because it has the same spelling error even when I fix it

Hole in the computer too.

Well, just look for where I put the asterisks and backspace those two spaces between Le and ngth. Then it will work.

--------------

It has come to my conclusion this is just a stupid wrapping of all forum code pretty much that ruins this

Anyway, this will solve the problem.