Diablo 2 Custom Abilities (Help me make them!)

[thevoden]

I am making this request thread to assist me on how to make these spells. Normally I would make a spell for hours making it as complicated as it can ever be when there are other easier alternatives that could be done in 5 minutes. This thread is about the help i will need on how to make certain spells.
Thanks!

Red: Needs help
Green: Completed

1) Concentration
Spell Type: Aura
Effect: Gives all party members affected by an aura +% damage bonus and a % chance to dodge an attack.
Basically I want an aura based off command aura but gives off evasion to all member affected by the aura.

2) Sanctuary
Spell Type: Aura
Effect: An aura that damages nearby enemy undead units per second (kind of like immolation) and knocks them back away from the hero 150 distance.

P.s. how do i make an aura that gives +50% damage to yourself and +25% to all allies? Its something about the spellbook, but how exaclty does hiding a spellbook work?

3) Prayer
Spell Type: Aura
Effect: Heals allies affected by aura for x hp a second.

4) Redemption
Spell Type: Self Aura
Effect: has a x% chance to gain hp / mana from a corpse.

5) Charge
Spell Type: Target Abilitiy
Effect: Charges a target dealing x% of your strength and knocking the target back. The hero casting this ability has the "blur" effect of speed. Just watch the video below of how charge works.
http://youtube.com/watch?v=lJBaVOnnoDY

6) Bash
Spell Type: Target
Effect: When used, it knocks back the target an x distance (similar to Dota's Spiritbreaker's Greater Bash skill) and acts like a stun kind of.

7) Nerubian Weaver's Double Attack "Gemini AttacK"
Spell Type: Passive
Effect: Spell can be used once every 4 seconds. The attacker hero unit who has this spell can attack twice in over a second.


Thats it for now. I will be posting more but I want to do this one at a time.

 

[FroznYoghurt]

All those spells are relatively easy to make, prayer for an instance can be done by giving immolation negative values and setting targets to allies.

For Sanctuary use a loop that picks all nearby unit every second and knocks them back, you can find tutorial on how to do knockback on this forum.

Spellbook is disabled by the disable ability action

-player: disable [spellbook ability] for player

Just add the two aura abilities to the spellbook

For the redemtion use

E - A unit dies
C - 
A -
set group = units in 600 having buff [Aura]
Ifthenelse
if number of units in group > 0
pick all in group and
set man of picked to mana of picked + 100
else
call DestroyGroup(udg_group)

Charge is a little bit trickier but I can make it for ya if you want :>

 

[Flare]

1) This should make it easy for you. All you need is NewGen World Editor and the rawcode of the aura, the aura buff, and the evasion skill which you are adding

2) Frozn explained it

For the P.S., just add another ability (not sure if there is any single-unit ability that improves damage by a percent) to the aura user

3) Unholy Aura? Alternatively, use the system in the link above and add Item Life Regeneration Bonus

4) Frozn explained it

5) That'd be a pain in the ass to make, especially in GUI (more-so if you want MUI)

 

[Draphoelix]

1) Concentration
Spell Type: Aura
Effect: Gives all party members affected by an aura +% damage bonus and a % chance to dodge an attack.
Basically I want an aura based off command aura but gives off evasion to all member affected by the aura.
Search for Evasion Aura, I'm sure there's one.
Or else you can do something like:
Every 1 sec
Condition
Pick every unit in Playable Area
Picked unit has buff Concentration
Add evasion to Picked Unit
wait 1 second
Removed evasion to picked unit


3) Prayer
Spell Type: Aura
Effect: Heals allies affected by aura for x hp a second.
Unholy Aura but with not Self, only targets allowed no Allies?

 

[jig7c]

the concentration you have to use triggers... no such aura that gives evasion to all the units within x range.

try this link
http://www.thehelper.net/forums/showthread.php?t=61485

this map uses spellbook/triggers to create evasion aura, you can add command aura with the triggers, and you should be able to do it....

 

[Tom_Kazansky]

@thevoden, the Charge ability, the video isn't clear enough, but do you mean something like this:

 

[thevoden]

Tom, yes thats exactly it.

 

[Tom_Kazansky]

Tom, yes thats exactly it.

ok, I will give you that spell.
Here is the code:

I use ABCT of Cohadar

Spoiler

scope D2Charge
globals
    private integer ChargeRawId = 'A000' // raw id of Charge ability
    private integer ChargeSpeedId = 'A001' // raw id of Charge Speed ability
    private integer ChargeBuff = 'B000' //raw id of the Charge buff
    private integer CasterRunAniIndex = 2 //walk animation index of the caster's model, currently, model Spirit Walker's walk animation index is 2
    private real CasterRunSpeed = 180. //Art - Animation - Run Speed of the caster -> this is used for the animation of the illusion (make it more "real")
    private integer DummyId = 'n000' //raw id of the dummy unit, used to cast stun
    private integer ChargeIllusionId = 'n002' //raw id of the dummy unit which is used for the illusion
    private integer ChargeStun = 'A002' //raw id of the stun ability
endglobals
//=================================
private struct data
    unit caster = null
    unit target = null
    unit d1 = null
    unit d2 = null
    integer tick = 0
    real casterx = 0.
    real castery = 0.
endstruct

function ChargeInterrupted takes unit u, unit a returns boolean
    if GetWidgetLife(u) == 0 then
        return true
    elseif GetWidgetLife(a) == 0 then
        return true
    elseif IsUnitType(u,UNIT_TYPE_ETHEREAL) then
        return true
    elseif IsUnitType(u,UNIT_TYPE_POLYMORPHED )  then
        return true
    elseif IsUnitType(u,UNIT_TYPE_STUNNED ) then
        return true
    elseif IsUnitType(u,UNIT_TYPE_SNARED ) then
        return true
    elseif  IsUnitInvisible(a, GetOwningPlayer(u))  then
        return true
    elseif OrderId2String( GetUnitCurrentOrder(u) ) != "attack" then
        return true
    elseif GetUnitAbilityLevel(u,ChargeBuff) == 0 then
        return true
    endif
    set u = null
    set a = null
    return false
endfunction

function ChargeM takes nothing returns boolean
    local data d = ABCT_GetData()
    local real x = GetUnitX(d.caster)
    local real y = GetUnitY(d.caster)
    local real fa = GetUnitFacing(d.caster)
    local real ang
    local real mx
    local real my
    set mx = TJGetPPX(x,-40, fa)
    set my = TJGetPPY(y,-40, fa)
    call SetUnitPosition(d.d1, mx, my )
    call SetUnitFacing(d.d1, fa )
    
    set mx = TJGetPPX(x,-80, fa)
    set my = TJGetPPY(y,-80, fa)
    call SetUnitPosition(d.d2, mx, my)
    call SetUnitFacing(d.d2, fa )
    
    if ChargeInterrupted(d.caster,d.target) then
        call UnitRemoveAbility(d.caster,ChargeSpeedId)
        call UnitRemoveAbility(d.caster,ChargeBuff)
        call RemoveUnit(d.d1)
        call RemoveUnit(d.d2)
        call SetUnitPathing(d.caster,true)
        call data.destroy(d)
        return true
    endif
    
    set d.casterx = x
    set d.castery = y
    return false
endfunction

function ChargeIllusion takes nothing returns boolean
    local data d = ABCT_GetData()
    local real cx = GetUnitX(d.caster)
    local real cy = GetUnitY(d.caster)
    local real fa = GetUnitFacing(d.caster)
    local real mx
    local real my
    if d.tick >= 15 then 
        call data.destroy(d)
        return true
    elseif cx == d.casterx and cy == d.castery and d.tick < 15 then
        set d.tick  = d.tick  + 1
        return false
    endif
    call SetUnitPathing(d.caster,false)
    set mx = TJGetPPX(cx,-40,fa)
    set my = TJGetPPY(cy,-40,fa)
    set d.d1 = CreateUnit( GetOwningPlayer(d.caster), ChargeIllusionId, mx, my, fa )
    call SetUnitVertexColor( d.d1,255,255,255,170)
    call SetUnitTimeScale( d.d1,522 / CasterRunSpeed )
    call PauseUnit(d.d1,true)
    call SetUnitPathing(d.d1,false)
    call SetUnitAnimationByIndex(d.d1, CasterRunAniIndex )
    call SetUnitMoveSpeed(d.d1,522)
    call SetUnitPosition(d.d1,cx,cy)
    call SetUnitColor(d.d1,ConvertPlayerColor(GetPlayerId(GetOwningPlayer(d.caster))))

    set mx = TJGetPPX(cx,-80,fa)
    set my = TJGetPPY(cy,-80,fa)
    set d.d2 = CreateUnit( GetOwningPlayer(d.caster), ChargeIllusionId,mx, my,fa )
    call SetUnitVertexColor(d.d2,255,255,255, 85 )
    call SetUnitTimeScale(d.d2,522/CasterRunSpeed)
    call PauseUnit(d.d1,true)
    call SetUnitPathing(d.d2,false)
    call SetUnitAnimationByIndex(d.d2, CasterRunAniIndex )
    call SetUnitMoveSpeed(d.d2,522)
    call SetUnitPosition(d.d2,cx,cy)
    call SetUnitColor(d.d2,ConvertPlayerColor(GetPlayerId(GetOwningPlayer(d.caster))))
    
    call ABCT_Start( function ChargeM, d, 0.02)
    return true
endfunction


//===============================================================================
private function Action takes nothing returns nothing
    local unit c
    local unit a
    local unit dumb
    local integer lvl
    local eventid EID = GetTriggerEventId()
    local data d
    if EID == EVENT_PLAYER_UNIT_SPELL_EFFECT and GetSpellAbilityId() == ChargeRawId then
        call PolledWait(0.1)
        set c = GetSpellAbilityUnit()
        set a = GetSpellTargetUnit()
        set lvl = GetUnitAbilityLevel(c, ChargeRawId)
        set d = data.create()
        set d.caster = c
        set d.target = a
        set d.casterx = GetUnitX(c)
        set d.castery = GetUnitY(c)
        call ABCT_Start( function ChargeIllusion , d, 0.02 )
        call UnitAddAbility(c, ChargeSpeedId )
        call IssueTargetOrder(c,"attack",a)
    else
        set c = GetAttacker()
        set a = GetTriggerUnit()
        set lvl = GetUnitAbilityLevel(c, ChargeRawId)
        if GetUnitAbilityLevel( c, ChargeBuff ) > 0 then
            set dumb = CreateUnit( Player(15), DummyId , GetUnitX(a), GetUnitY(a), 0 )
            call UnitAddAbility( dumb , ChargeStun )
            call SetUnitAbilityLevel( dumb, ChargeStun , lvl )
            call IssueTargetOrder(dumb, "firebolt", a )
            call UnitApplyTimedLife(dumb,'BTLF', 1. )
            set dumb = null
            
            call UnitRemoveAbility(c,ChargeSpeedId)
            call UnitRemoveAbility(c,ChargeBuff)
        endif
    endif
    set c = null
    set a = null
endfunction
//===================================================================================================
function InitTrig_D2Charge takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerAddAction(t, function Action)
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ATTACKED )
endfunction

endscope

How to import:
- Copy the Charge, Charge Speed, Charge Stun ability
- Copy 2 dummy unit
- Copy TT, ABCT and the D2Charge trigger
- Change the RawId of abilities and units in the globals of D2Charge

I have attached the demo map below.
If you find any bugs or you want to modify more, pm me :thup:

EDIT: You can modify the Charge Stun ability for damage and stun duration when impact.

 

[thevoden]

Hey thanks guys! I still need help on the sanctuary aura.

The list in green is completed and the list in red still needs help on, thanks!

 

[vypur85]

7. Searing Arrow added into Orb of Lightning. No triggering.

 

[thevoden]

7. Searing Arrow added into Orb of Lightning. No triggering.

Can you explain how this would work?

 

[Tiber]

P.s. how do i make an aura that gives +50% damage to yourself and +25% to all allies? Its something about the spellbook, but how exaclty does hiding a spellbook work?

If you don't want to use the spellbook you can create a dummy who has the 25% aura and is moved every second at the position of your hero. In the meantime your hero will have the 50% aura (note that the 50% will have to be 25% because he will also be affected by the dummy 25% aura).

Read this guide for the nice slide effect you want to use in Bash: http://world-editor-tutorials.thehelper.net/cat_usersubmit.php?view=22135

I'm also making an Assassin from D2 in one of my maps.