Exclude dropped item from counting function

[LurkerAspect]

XXXX==--SOLVED--==XXXX

Hi again all I'm becoming a main source of rep for some of you

Anyway, my problem today is that I'm running a function every time a unit drops an item, however the function that follows it almost immediately is still counting the item the unit just dropped, which is messing with my other systems. Any tips on how to fix this?
Here's the code:

private function ElementalTally takes unit u returns integer //this is the function that gets run immediately from the actions; this is the function that is counting the dropped item
    local integer i = 1
    local boolean has_air = false
    local boolean has_dark = false
    local boolean has_earth = false
    local boolean has_fire = false
    local boolean has_light = false
    local boolean has_water = false
    local integer tally = 0
    loop
        exitwhen i > 6 
        if GetItemTypeId(UnitItemInSlot(u,i)) == AIR_ITEM and has_air == false then
            set has_air = true
            set tally = tally+32
        elseif GetItemTypeId(UnitItemInSlot(u,i)) == DARK_ITEM and has_dark == false then
            set has_dark = true
            set tally = tally+16
        elseif GetItemTypeId(UnitItemInSlot(u,i)) == EARTH_ITEM and has_earth == false then
            set has_earth = true
            set tally = tally+8
        elseif GetItemTypeId(UnitItemInSlot(u,i)) == FIRE_ITEM and has_fire == false then
            set has_fire = true
            set tally = tally+4
        elseif GetItemTypeId(UnitItemInSlot(u,i)) == LIGHT_ITEM and has_light == false then
            set has_light = true
            set tally = tally+2
        elseif GetItemTypeId(UnitItemInSlot(u,i)) == WATER_ITEM and has_water == false then
            set has_water = true
            set tally = tally+1
        endif
        set i = i+1
    endloop
    return tally
endfunction

//bla bla bla

private function Actions2 takes nothing returns nothing
    local unit u = GetTriggerUnit()
    call RemoveElementalPowers(u)
    call UnitAddAbility(u,ELEMENTAL_ABILITY[ElementalTally(u)])
    set u = null
endfunction

private function Conditions1 takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == 'h000' and not UnitHasItemAlready(GetTriggerUnit(),GetManipulatedItem()) and IsItemElemental(GetManipulatedItem())
endfunction

Don't worry about the other undefined functions and global variables, they don't affect the performance of the main tally function.

Any help is much appreciated

 

[Tyrulan]

It sounds like when an item is dropped it is still considered as 'Manipulated' and in the inventory. I would add a parameter to your tally function and do a not equals comparison to exclude it.

Let me know if this helps you with your problem. If not, I'll investigate further.

EDIT: Apologies, did not read the SOLVED tag at the front of the post. Could you post the solution please? Intellectual curiosity.

 

[LurkerAspect]

I modified the functions; ElementalTally now takes an item as well as a unit argument, and then checks if the current item in slot is the given item, and if it is, it's not counted. That way, I just input the GetManipulatedItem(), and it works perfectly . It was fairly simple actually. Basically, the function looks like this now:

function GetElementalTally takes unit u, item exception returns integer
    //exception is the item you DON'T want added to tally
    //use with 'Drop' functions so that the dropped element doesn't get counted
    local integer i = 0
    local boolean has_air = false
    local boolean has_dark = false
    local boolean has_earth = false
    local boolean has_fire = false
    local boolean has_light = false
    local boolean has_water = false
    local integer tally = 0
    set tally = 0
    loop
        exitwhen i > 6 
        if UnitItemInSlot(u,i) != exception then
            if GetItemTypeId(UnitItemInSlot(u,i)) == AIR_ITEM and has_air == false then
                set has_air = true
                set tally = tally+32
            elseif GetItemTypeId(UnitItemInSlot(u,i)) == DARK_ITEM and has_dark == false then
                set has_dark = true
                set tally = tally+16
            elseif GetItemTypeId(UnitItemInSlot(u,i)) == EARTH_ITEM and has_earth == false then
                set has_earth = true
                set tally = tally+8
            elseif GetItemTypeId(UnitItemInSlot(u,i)) == FIRE_ITEM and has_fire == false then
                set has_fire = true
                set tally = tally+4
            elseif GetItemTypeId(UnitItemInSlot(u,i)) == LIGHT_ITEM and has_light == false then
                set has_light = true
                set tally = tally+2
            elseif GetItemTypeId(UnitItemInSlot(u,i)) == WATER_ITEM and has_water == false then
                set has_water = true
                set tally = tally+1
            endif
        endif
        set i = i+1
    endloop
    //call BJDebugMsg("tally = "+I2S(tally))
    return tally
endfunction

 

[Tyrulan]

Awesome, that is the same method I was implying above. Well done!