Demo Map GetBounty

[Hellohihi]

GetBounty
v1.2

Requires VJASS

What is GetBounty?
GetBounty enables you to get the bounty value of a specific unit


Why did i make this?
I made this because I badly needed a GetBounty script for my Vampirism Speed map, and i could not find one anywhere at all.
I needed it to display the amount of gold that was fed to the opposing team.
And furthermore, all the bounty value in my map does not have dices.

Alternative 1 (Best):
Requires: Damage
Credits: Jesus4Lyf

library DyingBounty initializer OnInit uses Damage
    globals
        private integer array LastGold
        private player TempPlayer
    endglobals
    private function OnDamage takes nothing returns boolean
        set TempPlayer=GetOwningPlayer(GetEventDamageSource())
        set LastGold[GetPlayerId(TempPlayer)]=GetPlayerState(TempPlayer,PLAYER_STATE_RESOURCE_GOLD)
        return false
    endfunction
    private function OnInit takes nothing returns nothing
        local trigger t=CreateTrigger()
        call TriggerAddCondition(t,Filter(function OnDamage))
        call Damage_RegisterEvent(t)
    endfunction
    function GetDyingBounty takes nothing returns integer
        set TempPlayer=GetOwningPlayer(GetKillingUnit())
        return GetPlayerState(TempPlayer,PLAYER_STATE_RESOURCE_GOLD)-LastGold[GetPlayerId(TempPlayer)]
    endfunction
endlibrary

Example use:

• Untitled Trigger 002
  • Events
    • Unit - A unit Dies
  • Conditions
  • Actions
    • Custom script: call BJDebugMsg("Bounty on death: "+I2S(GetDyingBounty()))

Alternative 2:
Requires: Damage
Credits: Jesus4Lyf

library DyingBounty initializer OnInit uses Damage, AIDS
    private struct GoldStore extends array
        integer gold
        
        static method init takes nothing returns nothing
            local trigger t=CreateTrigger()
            call TriggerAddCondition(t,Filter(function thistype.onDamage))
            call Damage_RegisterEvent(t)
            set t=null // Personal habit. Aaand a good one.
        endmethod
        //! runtextmacro AIDS()
        private static method onDamage takes nothing returns boolean
            set GoldStore[GetTriggerUnit()].gold=GetPlayerState(GetOwningPlayer(GetEventDamageSource()),PLAYER_STATE_RESOURCE_GOLD)
            return false
        endmethod
    endstruct
    private function OnInit takes nothing returns nothing
        // Because those init functions on structs fire way too early.
        call GoldStore.init()
    endfunction
    
    globals
        private unit TempUnit
    endglobals
    function GetDyingBounty takes nothing returns integer
        set TempUnit=GetKillingUnit()
        
        if TempUnit==null then
            // Killed with triggers or whatever.
            return 0
        endif
        
        return GetPlayerState(GetOwningPlayer(TempUnit),PLAYER_STATE_RESOURCE_GOLD)-GoldStore[GetDyingUnit()].gold
    endfunction
endlibrary

Alternative 3:
Requires no other system
Example usage:

call DisplayTimedTextToPlayer(player, 0. , 0., 5. , "The bounty of the last killed unit is " + I2S(GetBounty(GetUnitTypeId(GetDyingUnit() ))) )

Trigger:

//////////////////////Get BOUNTY v2///////////////////////////////////////////////////////////////////////////////////
// How to use:
// 1. Copy and paste this trigger into your map
// 2. set the integer variable DUMMY_ID to a dummy unit ID in your map
// 3. (Optional) Set real X and Y to the coordinates that you desire
//// For real X and Y, they determined where the dummy units will be created, this does not really matters because the dummy units cannot be seen in game.
// 4. (Optional) Set BOUNTY_ACCURACY to an integer number that you desire.
//// For BOUNTY_ACCURACY, a higher number will produce a more accurate average result but will be slower, vice versa.
//// For BOUNTY_ACCURACY, you can set it to 1 if your map uses non-diced bounty.
/////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
//Pros:
// 1. Does not leak, as far as i can tell
// 2. Easy implementation
// 3. Does NOT mess up the alliance between neutral hostile and victim
// 4. Does NOT mess up the gold of neutral hostile
// 5. The entire operation of the script is -Hidden- in game, the players in game will NOT see anything being created at all.
// 6. 100% accurate for non-diced bounty
// 7. You can set the BOUNTY_ACCURACY, so that it will give a rough average of diced bounty in your map.
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
//Cons:
// 1. Inaccurate for diced bounty
//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////


library GetBounty
/////////////////////////////////////////////////////////
//You may edit the values below//////////////////////////
globals
private constant integer DUMMY_ID = 'n000'
private constant real X = 0.
private constant real Y = 0.
private constant integer BOUNTY_ACCURACY = 3
endglobals
//////////////////////////////////////////////////////////
//Editing of options ends here, all that is below here is the script
/////////////////////////////////////////////////////////

function GetBounty takes integer unit_id returns integer
local integer loops = 0
local integer bounty = 0
local integer originalgold = GetPlayerState(Player(PLAYER_NEUTRAL_AGGRESSIVE), PLAYER_STATE_RESOURCE_GOLD)
local unit dummyattacker = CreateUnit( Player(PLAYER_NEUTRAL_AGGRESSIVE) , DUMMY_ID, X, Y , 0. )
local unit dummyattacked

    call SetPlayerState(Player(bj_PLAYER_NEUTRAL_VICTIM) , PLAYER_STATE_GIVES_BOUNTY , 1)
        call SetPlayerAllianceStateBJ( Player(PLAYER_NEUTRAL_AGGRESSIVE), Player(bj_PLAYER_NEUTRAL_VICTIM), bj_ALLIANCE_UNALLIED )

loop
    exitwhen loops == BOUNTY_ACCURACY
    set dummyattacked = CreateUnit( Player(bj_PLAYER_NEUTRAL_VICTIM) , unit_id , X, Y , 0. ) 
    call ShowUnit(dummyattacked, false)
    call UnitDamageTarget(dummyattacker,dummyattacked,1000000000.,false,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_ENHANCED,null)
    call RemoveUnit(dummyattacked)
    set bounty = bounty + GetPlayerState(Player(PLAYER_NEUTRAL_AGGRESSIVE), PLAYER_STATE_RESOURCE_GOLD) - originalgold
    call SetPlayerState( Player(PLAYER_NEUTRAL_AGGRESSIVE), PLAYER_STATE_RESOURCE_GOLD, originalgold  )
        set loops = loops + 1
endloop

    call SetPlayerAllianceStateBJ( Player(PLAYER_NEUTRAL_AGGRESSIVE), Player(bj_PLAYER_NEUTRAL_VICTIM), bj_ALLIANCE_ALLIED )
        call SetPlayerState(Player(bj_PLAYER_NEUTRAL_VICTIM) , PLAYER_STATE_GIVES_BOUNTY , 0)
        
call RemoveUnit(dummyattacker)
set dummyattacker = null
set dummyattacked = null

set bounty = bounty / BOUNTY_ACCURACY
return bounty
endfunction
endlibrary

Changelog:
v1.2
1. No longer shows gold coin animation
2. Options to easily set for users
3. Average diced bounty
4. Neutral hostile gold no longer need to be at a constant 0
5. Neutral hostile and neutral victim does not need to be permanent enemies

 

[Komaqtion]

Requires VJASS

Well, nope vJASS is not needed for this... It's normal JASS

 

[Sevion]

How's this better than Gcsn?

Gcsn does more and is more accuate.

 

[Jesus4Lyf]

How's this better than Gcsn?

It doesn't have a useless name, and this documents its cons.
Gosh, if that system had a good name...

2. Requires you to set neutral hostile and neutral victim to be enemies, and turn on bounty for neutral victim.
3. Requires neutral hostile's gold to be at a constant 0.
4. At the location where your dummy units is created, there will be the bounty gold coins animation shown. You can avoid this by setting it in custom game interface - Model - Bounty Art - Gold Credit.

All these can be removed. Try harder. :thup:

 

[Sevion]

I fail to see how the name degrades it.

And I can't think of a con off the top of my head.

My statement stands.

How is this system better than Gcsn.

 

[Hellohihi]

How's this better than Gcsn?

Gcsn does more and is more accuate.

I never knew Gcsn existed.

Gcsn does more of other stuffs like item cost, unit cost and such.
Mine is a single solo function.

So, its up to people to take their pick.

Also, Gcsn getbounty is also not 100% accurate for the diced bounty.
It just gives an average.

I will improve mine tomorrow when i wake up, so that average bounty is more accurate.
And i will also add a GUI version of it, so that it will also be GUI friendly.

Thanks for your reply.

 

[Sevion]

I said more accurate

Getting an average is much better than just any random integer from a kill.

 

[Hellohihi]

I said more accurate

Getting an average is much better than just any random integer from a kill.

I skimmed through the Gscn system.

I suppose it uses 3 results to get an average, so i'll maybe use more?
And i'll also add an option so that people can choose how many results they want to average from.

 

[Sevion]

Yeh, but remember, more results == more time unless you do them simultaneously.

 

[Jesus4Lyf]

What's this madness about taking an average?

>And I can't think of a con off the top of my head.
It returns an average, so it's useless for giving a bounty on kill?

If you call GetBounty on a unit that has a bounty involving dice, in my opinion the result had better be random! If I want to find how much bounty I should assign for a unit kill, it must take into account the random factors of the dice. As in, the result must be generated in real-time, at the moment, not be precached and it must not be some average.

And i'll also add an option so that people can choose how many results they want to average from.

Spend your time on what I said first. But this is a good idea for people who -want- an average, maybe.

Over engineering does not constitute accuracy.
And if you doubted that the name takes away from it, here's your proof:

I made this because I badly needed a GetBounty script for my Vampirism Speed map, and i could not find one anywhere at all.

>Yeh, but remember, more results == more time unless you do them simultaneously.
You can't do anything actually "simultaneously" in JASS.

@Sevion:
Gcsn also has most of the cons this has, but fails to document them.

 

[Nestharus]

Nice job Hellohihi : ).

I've been seeing a lot of systems being made for getting unit and item costs and getting bounty : O. Mine was actually the second to be made. Before mine, there was another, but it leaked : ).

Oh well, interesting stuff. The one made by MapperMalte takes up more memory and has more of a performance hit, but it can return a unit's cost + upgrades (not sure about items ^_^)

So I guess it's really up to people on what they want. There are lots of dif styles to do things, and they merit different results, so : o. However, this one is 99% the exact same as the one in Gcsn : ), and Gcsn has all of it merged because it does it all in one fell swoop for faster speeds.

 

[Jesus4Lyf]

Yep. I'm also happy to approve yours instead because it was submitted first and all, I guess...

And I expect you to breeze through fixing the cons. :thup:
(Store the player's gold and compare, turn bounty on for the duration of the func if it isn't, etc.)

But further Gcsn discussion belongs in Gcsn's thread.

As for this, I think this will probably be graveyarded (so long as Gcsn is updated appropriately).

 

[Hellohihi]

Updated.

All major cons are removed.

Does not show gold bounty animation at all for the dummy. (Good thing)

Added in easily customizable options for users.

Added in average result for diced bounty.

I fail to see how the name degrades it.

And I can't think of a con off the top of my head.

My statement stands.

How is this system better than Gcsn.

As for now, Gcsn get bounty shows the gold coin animation.

Mine does not.

And, mine sets the alliance and gold back to the original.

 

[BloodyMary]

You could use this.

OR

you can trigger bounty yourself. then call upon it when required.
which can easily be done in GUI if need be.

Edit: although this might be the quicker options for maps which aren't new. still i fail to see how this could be useful

i would like a scenario were this would come in handy.

 

[Hellohihi]

By the way, thanks for registering a brand new account, and replying with your first post here.

You could use this.

OR

you can trigger bounty yourself. then call upon it when required.
which can easily be done in GUI if need be.

Yes it can be easily done, but it can be very tedious if your map contains many different units and structures that has specific bounty values.

An example would be my map. It has many units and towers.
I did thought of making a table with all the bounty values, but it would end being very tedious to set up each and every single bounty value of the units and structures.

Edit: although this might be the quicker options for maps which aren't new. still i fail to see how this could be useful

i would like a scenario were this would come in handy.

A scenario where this would come in handy?

Take for example one of the very famous and widely hosted maps, vampirism fire.

In the map vampirism fire, they have a multiboard that shows how much a human has fed to the vampire in terms of unit bounty.

There you go, an example on a very famous map.

 

[Jesus4Lyf]

In the map vampirism fire, they have a multiboard that shows how much a human has fed to the vampire in terms of unit bounty.

There you go, an example on a very famous map.

!!

This is a terrible way to trigger that! You could have a global OnDamage trigger which saves the damage source's gold before the damage is dealt, and a trigger for on death which compares it against the player's new gold value...

Way better. And accurate.

Maybe this isn't useful. o.o

 

[Nestharus]

Balancing a game with unbalanced teams. Based on your team size, you'd get bonus bounty : ).

 

[Jesus4Lyf]

And in reply to Nestharus' statement, I say...

!!

This is a terrible way to trigger that! You could have a global OnDamage trigger which saves the damage source's gold before the damage is dealt, and a trigger for on death which compares it against the player's new gold value...

Way better. And accurate.

What the hell? These snippets are STILL a horrible way to do this.

I was thinking this was useful if the units DON'T give bounty (for that player) and you want to get the bounty they would give if the player gave bounty. So you can manually add it, or make the bounty give mana instead or something.

And that's it.

Question: Is this completely useless?

 

[Nestharus]

I dunno.. u just named an interesting use : )

I was thinking this was useful if the units DON'T give bounty (for that player) and you want to get the bounty they would give if the player gave bounty. So you can manually add it, or make the bounty give mana instead or something.

 

[Jesus4Lyf]

Actually, no. The only use of this is to modify the given bounty by disabling the bounty and using this to assign it - there's probably no other way to get the yellow +gold text to display correctly.

(Things like that mana suggestion should just be done with JASS and hashing the amount onto the unit type, really.)