Jass Script Problem

[The_Prophet]

ok basically i have this trigger call a function that creates all the spawns and stuff. now line *1* works perfectly fine. Line *2* only works if i make line 1 a comment or i call it using a completly different trigger. Why can't i get line 1 and 2 to work right after each other as listed? I listed below a slim down version of my trigger, just containing all the lines that i though might cuase the problem.

set udg_Counter = udg_Counter + 1
if udg_Counter == 1 or udg_Counter == 3 or udg_Counter == 5 or udg_Counter == 7 then
*1* call Create_Spawn('h005','h008', 'h007', 'u001', "Abilities\\Spells\\Demon\\DarkPortal\\DarkPortalTarget.mdl", Player(13))
*2* call Create_Spawn('h005','h000', 'h002', 'u00E', "Abilities\\Spells\\Undead\\AnimateDead\\AnimateDeadTarget.mdl", Player(14))
endif
if udg_Counter == 8 then
set udg_Counter = 0
endif

 

[Persen]

First, there is no Player(14). If you want the player with id 14, use ConvertedPlayer(14)

 

[Heptameron]

First, there is no Player(14). If you want the player with id 14, use ConvertedPlayer(14)

Player(14) is Neutral Extra.

Without seeing the code for Create_Spawn, I don't think anyone can help you.

 

[Vexorian]

My bet is that Create_Spawn either tries to use an unitialized variable, has heavy amount of calls or a division by 0 causing the thread to halt and unable to do the same thing on line 2

 

[The_Prophet]

ok well i've decided just to post the entire trigger. And yea Vexorian its actually called 4 times within that trigger so i wouldnt doubt somthing along that lines is the problem. Everything except the bolded line works.

function Create_Spawn takes integer b, integer u_1, integer u_2, integer u_3, string s, player p returns nothing
local location l
local group base
local unit pickedunit
local integer i = 1
set base = GetUnitsOfPlayerAndTypeId(p, b)
loop
exitwhen CountUnitsInGroup(base) == 0
set pickedunit = FirstOfGroup(base)
set l = GetUnitLoc(pickedunit)
call GroupRemoveUnit(base,pickedunit)
call CreateNUnitsAtLoc( 4, u_1, p, l, 0.0 )
call CreateNUnitsAtLoc( 1, u_2, p, l, 0.0 )
if udg_Counter == 8 then
call CreateNUnitsAtLoc( 1, u_3, p, l, 0.0 )
endif
loop
exitwhen i > 6
call AddSpecialEffectLoc(s, OffsetLocation(l, GetRandomReal(-250.00, 250.00), GetRandomReal(-250.00, 250.00)))
set i = i + 1
endloop
set i = 0
endloop
set pickedunit = null
call DestroyGroup(base)
call RemoveLocation(l)
endfunction

function Trig_Create_Spawn_Actions takes nothing returns nothing
set udg_Counter = udg_Counter + 1
call Create_Spawn('h00C','h008', 'h007', 'u001', "Abilities\\Spells\\Demon\\DarkPortal\\DarkPortalTarget.mdl", Player(13))
call Create_Spawn('h00H','h000', 'h002', 'u00E', "Abilities\\Spells\\Undead\\AnimateDead\\AnimateDeadTarget.mdl", Player(14))
if udg_Counter == 1 or udg_Counter == 3 or udg_Counter == 5 or udg_Counter == 7 then
call Create_Spawn('h005','h008', 'h007', 'u001', "Abilities\\Spells\\Demon\\DarkPortal\\DarkPortalTarget.mdl", Player(13))
call Create_Spawn('h005','h000', 'h002', 'u00E', "Abilities\\Spells\\Undead\\AnimateDead\\AnimateDeadTarget.mdl", Player(14))
endif
if udg_Counter == 8 then
set udg_Counter = 0
endif
endfunction
//===========================================================================
function InitTrig_Create_Spawn takes nothing returns nothing
set gg_trg_Create_Spawn = CreateTrigger( )
call TriggerRegisterTimerEventPeriodic( gg_trg_Create_Spawn, 35.00 )
call TriggerAddAction( gg_trg_Create_Spawn, function Trig_Create_Spawn_Actions )
endfunction

 

[Sanitarium]

Debug Message

Well, I can't say I have an answer for you, but if Line 2 isn't working, you should use inside the function you think isn't working.

call BJDebugMsg( " Message Here " )

to help locate more precisely where the problem lies. Much easier to find the bug in a line or two than in a whole function ^^

 

[The_Prophet]

ok im sorry but what exactly does the debug message do? Im positive the problem lies in that somthing having to do with line 1 doesnt finish/work properly and cuases a halt to the trigger since disabling line 1 or calling line 2 from another trigger both work perfectly fine.

 

[Sanitarium]

BJDebugMsg

Ah, well, the code:

call BJDebugMsg(" Message ")

will display Message on the screen, its a simple version of DisplayTextToForce(). Its a handy way of locating where the thread stops. For example, you might want to insert DebugMsgs as below:

function Create_Spawn takes integer b, integer u_1, integer u_2, integer u_3, string s, player p returns nothing
  local location l
  local group base
  local unit pickedunit
  local integer i = 1
  set base = GetUnitsOfPlayerAndTypeId(p, b)
  loop
    [B]call BJDebugMsg(I2S(CountUnitsInGroup(base))+" units in Group")[/B]
    exitwhen CountUnitsInGroup(base) == 0
    set pickedunit = FirstOfGroup(base)
    set l = GetUnitLoc(pickedunit)
    call GroupRemoveUnit(base,pickedunit)
    call CreateNUnitsAtLoc( 4, u_1, p, l, 0.0 )
    call CreateNUnitsAtLoc( 1, u_2, p, l, 0.0 ) 
    if udg_Counter == 8 then
      call CreateNUnitsAtLoc( 1, u_3, p, l, 0.0 )
    endif
    loop
      exitwhen i > 6
      call AddSpecialEffectLoc(s, OffsetLocation(l, GetRandomReal(-250.00, 250.00), GetRandomReal(-250.00, 250.00)))
      [B]call BJDebugMsg("Effect "+I2S(i)+" created")[/B]
      set i = i + 1
    endloop
    set i = 0
  endloop
  [B]call BJDebugMsg("Function End")[/B]
  set pickedunit = null
  call DestroyGroup(base)
  call RemoveLocation(l)
endfunction

For example, if you only see the "..Units in Group" message once, you know that the loop is only going around once.

As a side note, indentation helps to organize your code, makes it more readable ^^

 

[Vexorian]

that function is way too heav


For starters you are leaking some special effects, and the location returned by OffSetLocation.

Using OffSetLocation is a clear sign that you shouldn't be using locations at all and just use coordinates.

But the real problem is that you call CountUnitsInGroup everytime, that loops through all the units, you are also looping through all the units already, so you loop is used (n(n+1))/2 times when n is the number of units OWNED by the player and of that type, which is alot.

function Create_Spawn takes integer b, integer u_1, integer u_2, integer u_3, string s, player p returns nothing
 local location l
 local group base
 local unit pickedunit 
 local integer i = 1
    set base = GetUnitsOfPlayerAndTypeId(p, b)
    loop
        set pickedunit = FirstOfGroup(base)
        exitwhen pickedunit == null
        set l = GetUnitLoc(pickedunit)
        call GroupRemoveUnit(base,pickedunit)
        call CreateNUnitsAtLoc( 4, u_1, p, l, 0.0 ) 
        call CreateNUnitsAtLoc( 1, u_2, p, l, 0.0 ) 
        if udg_Counter == 8 then
            call CreateNUnitsAtLoc( 1, u_3, p, l, 0.0 )
        endif
        loop
            exitwhen i > 6
            call AddSpecialEffect(s, GetLocationX(l)+GetRandomReal(-250.00, 250.00),  GetLocationY(l)+GetRandomReal(-250.00, 250.00) )
            // Is it intentional to do not destroy the fx and do not save it either?
            // Is it supposed to stay in the map all the time?
            set i = i + 1
        endloop
        set i = 0
    endloop
    set pickedunit = null
    call DestroyGroup(base)
    call RemoveLocation(l)
endfunction

 

[The_Prophet]

ok thanks so much vexorian, yea after following your advice, using the exit when pickedunit = null and just getting rid of a few leaks like the special effects and such it seems to work now. Thanks so much