Jass Script Problems

[Sanitarium]

Edit: "Effect not appearing" Problem Solved-Improper Model File Path
Edit: "No damage dealt" Problem Solved-Misunderstanding of Damage Tables and UnitDamageTarget

Thanks for all the help.

 

[mems]

try to use this codes

AddSpecialEffectTarget(<String model path>, <Target Unit>, <String attachment> )

and

UnitDamageTarget(<Source unit>,<target>,<demage>,false,false,null,null,null)

also your model may not have an attachment point on its origin if you have imported it.

 

[Sanitarium]

Effect Problem Fixed, Damage Still Doesn't Work

Ok, I've replaced my damage line with yours...still doesn't work. The UnitDamageTarget now returns true but no damage is dealt...

First code bit pulled off the JASS Manual, the second bit is yours. I was wondering if you could explain what the purpose of the fields you set to false/null was and why it should work when they were set to false/null

native UnitDamageTarget (unit whichUnit, widget target, real amount, boolean attack, boolean ranged, attacktype attackType, damagetype damageType, weapontype weaponType) returns boolean
UnitDamageTarget(<Source unit>,<target>,<demage>,false,false,null,null,null)

In a bit if unrelated expirementing, I somehow fixed the Effect Problem, thanks for the help anyway

 

[mems]

may be you cannot take the Caster or Target from game cache(get attached stuff) take a look at your codes if you make a mistake while attaching the caster or target couse i use this demage function and it works form me really fine

 

[Sanitarium]

About those fields...

Ok, I will check GetAttached..'s again.

But I would still like to know about those fields, it seems like you would need something other than null in the damage/attack type fields...

 

[mems]

boolean attack: If you make it true your unit tries to attak the target this will reset all animations that you have given to your unit and tries to play attack animation.
boolean ranged: Again it defines if the attack is ranged for other definations
attacktype attackType: I dont care about this couse i demage the unit even i typed null there. However it is for the physical attacks or a full demage according to armor type off target
damagetype damageType: same as below
weapontype weaponType: That may for the attack sound... or may be firing a missle for ranged attacks i never tried it

 

[Sanitarium]

Here's the Code

Firstly, thanks for the explaination, that clears things up. It should be noted that I use altered damage tables(gameplay constants), do you know if the null for attack/damage type will sidestep these modifiers?

Well, I can't find the problem, I'll keep looking. Meanwhile, here is the code, maybe you can figure it out:

function CollisionCheck takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local unit m = GetAttachedUnit(t,"Unit")
    local location p = GetUnitLoc(m)
    local group g =  CreateGroup()
    local unit a = GetAttachedUnit(m,"Attacker")
    local unit u = null
    local integer s = 0
    local boolean c = false

    set g = GetUnitsInRangeOfLocAll (25, p)
    call GroupRemoveUnit(g,a)
    call GroupRemoveUnit(g,m)

    if CountUnitsInGroup(g) != 0 then
      set u = GroupPickRandomUnit(g)
      if UnitDamageTarget(a,u,I2R(GetAttachedInt(m,"Damage")),false,false,null,null,null) then
        call BJDebugMsg( "Target Damaged For: "+I2S(GetAttachedInt(m,"Damage")) )
      endif
      set c = true
    endif

    if not c then
      set s = GetAttachedInt(t,"StepsRemaining")
      if s == 0 then
        set c = true
      else
        call AttachInt(t,"StepsRemaining",s-1)
      endif
    endif

    if c then
      call CleanAttachedVars(t)
      call DestroyTimer(t)
      call DestroyEffect(GetAttachedEffect(m,"Effect"))
      call CleanAttachedVars(m)
      call ExplodeUnitBJ(m)
    endif

    call DestroyGroup(g)
    call RemoveLocation(p)
    set g = null
    set t = null
    set m = null
    set u = null
    set p = null
endfunction

function Trig_On_Attacks_Actions takes nothing returns nothing
  local unit a = GetAttacker()
  local location p = GetUnitLoc(GetAttackedUnitBJ())
  local location o = GetUnitLoc(a)
  local integer ut = GetUnitTypeId(a)
  local integer bd = UT_GetAttachedInt(ut,"BaseDamage")
  local integer nd = UT_GetAttachedInt(ut,"NumDice")
  local integer ds = UT_GetAttachedInt(ut,"DiceSides")
  local string pa  = UT_GetAttachedString(ut,"ProjectileArt")
  local real ps = UT_GetAttachedReal(ut,"ProjectileSpeed")
  local unit m = CreateUnitAtLoc( GetOwningPlayer(a),'e000',o, 0 )
  local effect fx = AddSpecialEffectTarget("Abilities\\Weapons\\SerpentWardMissile\\SerpentWardMissile.mdl", m, "origin" )
  local timer t = CreateTimer()
  local integer i = 1
  call SetUnitMoveSpeed(m, ps)
  call SetUnitPathing(m, false)
  call IssuePointOrder(m,"move",GetLocationX(p), GetLocationY(p))
 
  loop
    exitwhen i>nd
    set bd =  bd + GetRandomInt(1,ds)
    set i = i + 1
  endloop
  
  call AttachInt(m, "Damage",bd)
  call AttachObject(m,"Effect",fx)
  call AttachObject(m,"Attacker",a)
  call AttachObject(t,"Unit",m)
  call AttachInt(t,"StepsRemaining",40)
  call TimerStart (t, .05, true, function CollisionCheck)

endfunction

I know it leaks like crazy, just tryin to get it to work first. UT_Attach...'s are basically like Attach... functions except you attach to Unit Types(intgers)

 

[Vexorian]

the return values with damage functions seem to have nothing to do with the fact the unit was damaged or not

boolean attack: If you make it true your unit tries to attak the target this will reset all animations that you have given to your unit and tries to play attack animation.

Didn't know that.

boolean ranged: Again it defines if the attack is ranged for other definations

Like what?

attacktype attackType: I dont care about this couse i demage the unit even
i typed null there. However it is for the physical attacks or a full demage according to armor type off target

If you use null there it is chaos damage. It is better to use NORMAL there so it is spell damage. Attack type only involves damage done to different armor types

damagetype damageType: same as below

Far from the same, damagetype determines the damage type of the spell, if it is magical, phisical, universal. null and unknown here are extremly weird, they will damage the unit no mather the circunstances they will even damage invulnerable units

weapontype weaponType: That may for the attack sound... or may be firing a missle for ranged attacks i never tried it

Just sound, completelly worthless actually. Blizzard shouldn't have added this argument at all

When you attach plenty of stuff to the same handle it is better to use the Table functions and GetAttachmentTable there, it is faster

 

[mems]

Like what?

I really dont sure about it but i may to determine if the attack is ranged may be for some spells which is effecting ranged attacks such as true shot aura ect..

Far from the same, damagetype determines the damage type of the spell, if it is magical, phisical, universal. null and unknown here are extremly weird, they will damage the unit no mather the circunstances they will even damage invulnerable units

I was meaning that just cannot expressed it well

 

[Sanitarium]

Damage type: do you know where I could find out how each damage type effects the damage( if such a resource even exists)?

Tables: Yeah, I just recently got an updated caster system, haven't spent the time to see how you did the tables, once I do there will probably be a conversion

In regaurds to the original problem...the answer must be out there, if only I could find it.

 

[Heptameron]

Damage type: do you know where I could find out how each damage type effects the damage( if such a resource even exists)?

AFAIK, all it does is determine if the damage is magical, physical, or universal. Unless you meant attack type...

 

[Sanitarium]

No, I did meant damage type, there are other options besides those Vex listed such as Sonic, Acid, and Plant. I was wondering if anyone knew what effects these had. Perhaps they are just extentions of physical, universal, and magical?

Anyrate...

Still stumped on the UnitDamageTarget, it now works in other triggers, just not this one.

 

[Heptameron]

Perhaps they are just extentions of physical, universal, and magical?

Yes, basically.

 

[Vexorian]

There are no actual differences between Fire and Cold , for example they are both magical.

I have a table in the Caster System's readme in the section about damage options

 

[Sanitarium]

It works!

Well, I've found the problem, my game constants for damage had effectively disabled spell damage. This should not have been a problem because, according to Vexorian, null is chaos damage.

If you use null there it is chaos damage. It is better to use NORMAL there so it is spell damage. Attack type only involves damage done to different armor types

Interestingly enough, a value of null in the damagetype uses spell damage, not chaos. I enabled spell damage and disabled chaos damage and it now works.

Thanks for all the help.