Respawn trigger not working properly?

[Corleone]

I've finished my spell for the spell contest ages ago, but when I tried to make a trigger that would make the mobs res after 45 seconds, it won't exactly work. I can't seem to figure out what's wrong.

function Trig_Unit_Death_Type takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) != GetUnitTypeId(udg_Blademaster)
endfunction

function Trig_Unit_Death_MUI_Actions takes nothing returns nothing
    local location DyingPosition
    local unit DeadUnit
    if ( Trig_Unit_Death_Type() ) then
        set DeadUnit = GetTriggerUnit()
        set DyingPosition = GetUnitLoc(DeadUnit)
        call TriggerSleepAction( 45.00 )
        call CreateNUnitsAtLoc( 1, GetUnitTypeId(DeadUnit), GetOwningPlayer(DeadUnit), DyingPosition, GetRandomDirectionDeg() )
        set DeadUnit = null
        call RemoveLocation ( DyingPosition )
    else
        set DeadUnit = udg_Blademaster
        set DyingPosition = GetRectCenter(GetPlayableMapRect())
        call ReviveHeroLoc( DeadUnit, DyingPosition, true )
        call RemoveLocation ( DyingPosition )
        set DeadUnit = null
    endif
endfunction

//===========================================================================
function InitTrig_Unit_Death_MUI takes nothing returns nothing
    set gg_trg_Unit_Death_MUI = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Unit_Death_MUI, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddAction( gg_trg_Unit_Death_MUI, function Trig_Unit_Death_MUI_Actions )
endfunction

The condition works, because it will res the Blademaster. However, it won't go past the 45 second wait. Any idea why?

 

[emjlr3]

what is the problem, looks like it should work from where im sitting

btw ur loc is not nulled

anywho, GetTriggerUnit() in taht function my not work, duno

i reccomend

set bj_ghoul[55] = GetTriggerUnit() , and use that in ur condition function

 

[Corleone]

what is the problem, looks like it should work from where im sitting

btw ur loc is not nulled

anywho, GetTriggerUnit() in taht function my not work, duno

i reccomend

set bj_ghoul[55] = GetTriggerUnit() , and use that in ur condition function

Well, AceHart couldn't find any problems either, but it still wouldn't work. Triggering Unit works great in GUI, so why exactly wouldn't it work here? Also, could you explain what the bj_ghoul[55] is?

 

[SFilip]

> what the bj_ghoul[55] is?
An unused global unit variable.
Actually the first couple of indexes are used somewhere at map init I think, but the rest isn't so you can always use it as a temporary variable if you need one.

 

[Corleone]

> what the bj_ghoul[55] is?
An unused global unit variable.
Actually the first couple of indexes are used somewhere at map init I think, but the rest isn't so you can always use it as a temporary variable if you need one.

Global variable? Wouldn't that mean that it'll only res one unit, because it's not MUI any more?

 

[AceHart]

> the first couple of indexes are used somewhere at map init I think

At most 12, and only if you run the default undead melee AI.

 

[emjlr3]

the boolexpr would be instant, so it would be done right after u set it, and rdy for another death event
the bj_ghoul is just to trasnfer ur unit to and from another function

 

[Corleone]

set bj_ghoul[55] = GetTriggerUnit() , and use that in ur condition function

Right, I set the "bj_ghoul[55] = GetTriggeringUnit()" at the start of the condition function, and replaced the "GetUnitTypeId(GetTriggeringUnit())" with "GetUnitTypeId(bj_ghoul[55])" and it made WE crash. I'm guessing I changed something I shouldn't have changed, or pasted the bj_ghoul[55] at the wrong place. Care to show me how it's done right? ( In the trigger I posted, preferably )

EDIT: I also pasted it in the Actions function, of course, but then it 'expected a name' at the GetUnitTypeId(bj_ghoul[55]) and gave me several errors like "expected endif" at a comment line..

 

[emjlr3]

y don't u post your most recent trigger

on second thought, try this

globals
    trigger gg_trg_Unit_Death_MUI
    unit udg_Blademaster
endglobals



function Trig_Unit_Death_MUI_Actions takes nothing returns nothing    
    local unit DeadUnit = GetTriggerUnit()
    local real x
    local real y
    
    if GetUnitTypeId(DeadUnit) != GetUnitTypeId(udg_Blademaster) then
        set x = GetUnitX(DeadUnit)
        set y = GetUnitY(DeadUnit)
        call PolledWait(45.)
        call CreateUnit(GetOwningPlayer(DeadUnit),GetUnitTypeId(DeadUnit),x,y,GetRandomReal(0,360))
    else
        call ReviveHero(DeadUnit,GetRectCenterX(bj_mapInitialPlayableArea),GetRectCenterY(bj_mapInitialPlayableArea),true)
    endif
    
    set DeadUnit = null
endfunction

//===========================================================================
function InitTrig_Unit_Death_MUI takes nothing returns nothing
    set gg_trg_Unit_Death_MUI = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Unit_Death_MUI, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddAction( gg_trg_Unit_Death_MUI, function Trig_Unit_Death_MUI_Actions )
endfunction

much easier then your, no?

note my changes and make sure you understand it all, before you go blindly pasting it into your map

btw, i am assuming all creeps are owned by the same person

so just putting in the player would be better then GetOwningPlayer

 

[Corleone]

y dont u post ur most recent trigger

It hasn't really changed. I didn't save the map when that trigger didn't work, so it's still the same one as in the first post.

 

[Sooda]

Because bj_ghoul is an arry shouldn' t there be:

unit arry bj_ghoul

then you can use that arry 55 or I' m wrong ?

 

[Tom Jones]

Because bj_ghoul is an arry shouldn' t there be:

unit arry bj_ghoul

then you can use that arry 55 or I' m wrong ?

That's a blizzard.j variable, so it's allready set and ready for use.

 

[leetslay]

it's not "GetTriggeringUnit()" in JASS, it's "GetTriggerUnit()"
I assume that's what caused your WE to crash.

 

[Corleone]

it's not "GetTriggeringUnit()" in JASS, it's "GetTriggerUnit()"
I assume that's what caused your WE to crash.

You're right. Silly typo...