Special effect problem

[Kazuga]

Hm ok, I have the HAIL system now. For what I have seen earlier, the system is to be in it's own trigger right? Question now is what to do next to make it mui... I don't really have any idea at all how HAIL works either (did read through it at wc3 campaigns but I didn't really understand what they ment really...)

I'm sorry but I don't quite get your post either that explains how to use HAIL, for what I can see I need a library function and then somehow call upon the HAIL system in the main function?

 

[Flare]

1) Copy the HAIL trigger into your map.

2) There's a number of ways you can initialize HAIL. You can make a generic, global initializer OR you can make specific initializers for each trigger that is needed.

For a global initializer just do

library HAILInit requires HAIL
//! runtextmacro HAIL_CreateProperty ("Data", "integer", "")
endlibrary

That will generate 3 functios

• SetData (yourhandle, yourinteger)
• GetData (yourhandle)
• ResetData (yourhandle)

For specific initializers, just put your textmacro line into a scope/library, and make the third argument "private" i.e.

//! runtextmacro HAIL_CreateProperty ("Data", "integer", "private")

//Structs are integers, so second argument will be "integer" unless you are attaching something else
//Beware of name conflicts if you made a more generally named initializing textmacro, like the first example

4) Now you make a struct

struct MyStruct
unit caster
unit target
unit dummy
real damage
//Any other stuff that needs to be moved between functions can be added here.
//Also, if you assign any struct member an array it must be done like so
real array numbers[numberofarrays]
//Using arrays can severely limit MUI potential of your stuff though, since you can only declare 8192/(highest array limit) instances of the struct
//e.g. if numberofarrays was 100, you can only have 81 instances of MyStruct at any one time (.destroy will free up space for new structs though)
endstruct

5) Declare your struct

function PrimaryFunc takes nothing returns nothing
local MyStruct data = MyStruct.create ()
//Declare your other locals
set data.caster = GetTriggerUnit () //To use struct members, you must use the identifier you gave them (in this case, data) followed by . and finally the name of your struct member
endfunction

6) Assign your struct to a handle (e.g. timer)

function PrimaryFunc takes nothing returns nothing
local MyStruct data = MyStruct.create ()
local timer t = CreateTimer ()
//First argument = Handle to which you are attaching
//Second argument = Data which you are attaching to first argument
call SetData (t, data)
call TimerStart (t, mytimerduration, false, function TimerCallback)
set t = null
endfunction

7) In your timer callback, retrieve your struct data

function TimerCallback takes nothing returns nothing
local timer t = GetExpiredTimer ()
local MyStruct data = GetData (t)
//Do something with your struct, e.g.
call BJDebugMsg (GetUnitName (data.caster))
//Now, we can destroy this timer since it isn't periodic.
//First, destroy the struct instance
call data.destroy ()
//Next, clear the attachment
call ResetData (t)
//Finally, destroy our timer and null the handle
call DestroyTimer (t)
set t = null

Hopefully I explained it well enough
If there is any part you are unsure of, let me know exactly which part Makes it so much easier to solve any problems

 

[Kazuga]

At the third point, should I put the library at the top of the code? Also what should be inside of it? Don't quite get what you mean with set data, get data, reset data.. It's here the global should be?

 

[Flare]

At the third point, should I put the library at the top of the code?

It can be anywhere, as long as its in a library (assuming you want a general, global set of functions that every trigger can use), and has the 'requires HAIL' part after library name (if you put it into the HAIL library itself, you wont need the 'requires HAIL' bit)

Also what should be inside of it?

What's 'it'? The textmacro?

Don't quite get what you mean with set data, get data, reset data

SetData attaches the given data to a given handle (which you can recall from another function)
GetData retrieves the attached data from a given handle
ResetData clears the attachment from the handle (this part is necessary to keep the system working effectively)

It's here the global should be?

What global? Did I say anything about a global?

 

[Kazuga]

Still a little confused, the set-get and resetdata should be spread around at the places you need them or should they be in that order within the library? What I ment with the globals was that the dummy variable is global, wich makes it un mui, wich is why I need this system, wich is why I wonder if I need the globals inside the system/library?

scope Lightnings initializer Lightning
globals
private constant integer raw = 'AHtb'
unit dummy
unit caster
unit target
real tx
real ty
endglobals
library HAILInit requires HAIL
//What do I write here?
endlibrary

 

[Flare]

You won't be needing globals. You just make a struct (like I showed you in earlier post) and give it a few members. Then, you can pass that struct between functions, and refer to that unit. No globals needed (unless you are using a ForGroup).

You should look up a struct tutorial, there's one made by AndrewGosu and DuckieKing IIRC. They will probably be able to inform you of what structs are and how to use them better than I can

library HAILInit requires HAIL
//! runtextmacro HAIL_CreateProperty ("Data", "integer", "")
endlibrary

scope Lightnings initializer Lightning
globals
private constant integer raw = 'AHtb'
unit dummy
unit caster
unit target
real tx
real ty
endglobals

//More stuff
endscope

 

[Kazuga]

Something like this...?

library HAILInit requires HAIL
//! runtextmacro HAIL_CreateProperty ("Data", "integer", "private")

endlibrary
struct MyStruct
unit dummy
unit caster
unit target
real tx
real ty

endstruct
function PrimaryFunc takes nothing returns nothing
local MyStruct data = MyStruct.create ()
set data.caster = GetTriggerUnit ()
endfunction
function PrimaryFunc takes nothing returns nothing
local MyStruct data = MyStruct.create ()
local timer t = CreateTimer ()
call SetData (t,data)
call TimerStart (t, mytimerduration, false, function TimerCallback)
set t = null
endfunction
function TimerCallback takes nothing returns nothing
local timer t = GetExpiredTimer ()
local MyStruct data = GetData (t)
call BJDebugMsg (GetUnitName (data.caster))
call data.destroy ()
call DestroyTimer (t)
set t = null
endfunction 

scope Lightnings initializer Lightning

globals
private constant integer raw = 'AHtb'
endglobals

private function Conditions takes nothing returns boolean
return GetSpellAbilityId() == raw
endfunction

private function Slide takes nothing returns nothing
local real x = GetUnitX(dummy)
local real y = GetUnitY(dummy)
local real newX
local real newY
local real angle

set tx    = GetUnitX(target)
set ty    = GetUnitY(target)
set angle = Atan2(ty-y,tx-x)
set newX  = x + 50 *Cos(angle)
set newY  = y + 50 *Sin(angle)


call SetUnitPosition(dummy,newX,newY)
endfunction
private function Actions takes nothing returns nothing
local timer SlideTimer = CreateTimer()
local unit Unit                    = GetTriggerUnit()
local real real1                   = GetUnitFacing(Unit)

local real x = GetUnitX(GetTriggerUnit())
local real y = GetUnitY(GetTriggerUnit())

local real x2 = x + 300 * Cos((real1+145)*bj_DEGTORAD)
local real y2 = x + 300 * Sin((real1+145)*bj_DEGTORAD)

local real x3 = x + 300 * Cos((real1+180)*bj_DEGTORAD)
local real y3 = x + 300 * Sin((real1+180)*bj_DEGTORAD)

local real x4 = x + 300 * Cos((real1+215)*bj_DEGTORAD)
local real y4 = x + 300 * Sin((real1+215)*bj_DEGTORAD)


call TriggerSleepAction(1)
set target = (GetSpellTargetUnit())
call BJDebugMsg ("This part works")
call TriggerSleepAction (0.1)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x2,y2)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x3,y3)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x4,y4)
//call PauseUnit (Unit, true)
call AddLightning ("CLPB",true, x,y,x2,y2)
call AddLightning ("CLPB",true, x,y,x3,y3)
call AddLightning ("CLPB",true, x,y,x4,y4)
call TriggerSleepAction (1)
set dummy = CreateUnit (GetOwningPlayer(Unit),'h000',x,y,0)
//call PauseUnit (Unit, false)
call TimerStart (SlideTimer,0.1,true, function Slide)

//set t    = null
set Unit = null
endfunction


//===========================================================================

private function SafeFilt takes nothing returns boolean
return true
endfunction
private function Lightning takes nothing returns nothing
 local trigger trig = CreateTrigger()
local integer i = 0
loop
    exitwhen i > 15
    call TriggerRegisterPlayerUnitEvent(trig,Player(i),EVENT_PLAYER_UNIT_SPELL_EFFECT,Condition(function SafeFilt))
    set i = i + 1
endloop
 call TriggerAddCondition (trig, Condition (function Conditions ) )
 call TriggerAddAction (trig, function Actions )
 set trig = null
 endfunction

endscope

 

[Trollvottel]

no. the private will make it unusable for your scope. (which you forgot to declare)

 

[Kazuga]

? The scope is just moved a bit down cause of the struct etc?

 

[Flare]

put everything except the HAILInit library in the scope. and change the "private" in third argument of HAIL textmacro to ""

If you are still having trouble with it tommorow, I can make out a few samples for you. (don't have time now unfortunately). I'll do a very simple one (basically, passing a single unit to another function using a struct) and something a little more complicated (such as a slide)

 

[Kazuga]

Would be great, these structs etc are real hard to understand... I read through Andregosus tutorial about structs but I must say I did not understand alot of it...

 

[PurgeandFire]

Since you can use public/private values inside libraries, you would put "private" if you want the function for that independent library.

Since you need to use it outside of the library, you would simply use "" as it is null. I think, that is how HSAS works.

 

[Flare]

Since you need to use it outside of the library, you would simply use "" as it is null. I think, that is how HSAS works.

Ye

Or, make it public, and call <libraryname>_<functionname> but what Purge said will work fine


EDIT: Here's the first sample anyway. Basically, it'll create a unit, and 5 seconds later, it will display the name of that unit.

scope Test initializer TestInit
//Our HAIL initializer function
//! runtextmacro HAIL_CreateProperty ("TestData", "integer", "private")

//Our three functions are:
// call SetTestData (whichHandle, whichInteger)
// call GetTestData (whichHandle)
// call ResetTestData (whichHandle)

//We can only use SetTestData, GetTestData and ResetTestData -WITHIN- this particular scope since the third argument is private

private struct TestStruct
unit testunit
//I'll use a struct timer instead of a local timer.
timer testtimer
endstruct

private function TimerCallback takes nothing returns nothing
    local timer t = GetExpiredTimer () //Assign a variable to expiring timer
    local TestStruct data = GetTestData (t) //Retrieving the data from the timer
    call BJDebugMsg (GetUnitName (data.testunit)) //Let's display the name of our struct unit
    call PauseTimer (t) //Pause the timer before destroying it
    call data.destroy () //Destroy our struct instance
    call ResetTestData (t) //Clear the data from the timer
    call DestroyTimer (t) //Destroy the timer
    set t = null //Null the local timer
endfunction

private function TestFunc takes nothing returns nothing
    local TestStruct data = TestStruct.create () //Declaring our struct as "local (struct name) (identifier)"
    set data.testunit = CreateUnit (GetTriggerPlayer (), 'hpea', 0, 0, 270) //Creating a unit and assigning it to testunit
    set data.testtimer = CreateTimer () //Creating the timer
    call SetTestData (data.testtimer, data) //Assigning the struct to testtimer
    call TimerStart (data.testtimer, 5, false, function TimerCallback)
endfunction

//===========================================================================
private function TestInit takes nothing returns nothing
    local trigger t = CreateTrigger ()
    call TriggerRegisterPlayerEvent (t, Player (0), EVENT_PLAYER_END_CINEMATIC)
    call TriggerAddAction( t, function TestFunc )
endfunction

endscope

EDIT: Wait, that's not working, lemme fix it
EDIT: Fixed

 

[Kazuga]

Hm making Jass into mui is even harder then making gui into mui^^ (Atleast now the first time)
So eh, I think I got the most part right but the programm says otherwise^^ It can't find the declarations of the structed variables...

library HAILInit requires HAIL
//! runtextmacro HAIL_CreateProperty ("Data", "integer", "")
endlibrary
scope Lightnings initializer Lightning
globals
private constant integer raw = 'AHtb'
endglobals
private struct TestStruct
unit dummy
unit caster
unit target
real tx
real ty
timer SlideTimer
endstruct

private function Conditions takes nothing returns boolean
return GetSpellAbilityId() == raw
endfunction

private function Slide takes nothing returns nothing
local real x = GetUnitX(dummy)               //Error
local real y = GetUnitY(dummy)               //Error
local real newX
local real newY
local real angle
local real distance

set tx    = GetUnitX(target)                    //Error
set ty    = GetUnitY(target)                    //Error
set angle = Atan2(ty-y,tx-x)
set newX  = x + 50 *Cos(angle)
set newY  = y + 50 *Sin(angle)

call SetUnitPosition(dummy,newX,newY)


endfunction
private function Actions takes nothing returns nothing
local TestStruct data = TestStruct.create ()
local unit Unit                    = GetTriggerUnit()
local real real1                   = GetUnitFacing(Unit)

local real x = GetUnitX(GetTriggerUnit())
local real y = GetUnitY(GetTriggerUnit())

local real x2 = x + 300 * Cos((real1+145)*bj_DEGTORAD)
local real y2 = x + 300 * Sin((real1+145)*bj_DEGTORAD)

local real x3 = x + 300 * Cos((real1+180)*bj_DEGTORAD)
local real y3 = x + 300 * Sin((real1+180)*bj_DEGTORAD)

local real x4 = x + 300 * Cos((real1+215)*bj_DEGTORAD)
local real y4 = x + 300 * Sin((real1+215)*bj_DEGTORAD)

set data.SlideTimer = CreateTimer()
call TriggerSleepAction(1)
set data.target = (GetSpellTargetUnit())
call BJDebugMsg ("This part works")
call TriggerSleepAction (0.1)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x2,y2)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x3,y3)
call AddSpecialEffect("Abilities\\Weapons\\Bolt\\BoltImpact.mdl",x4,y4)
//call PauseUnit (Unit, true)
call AddLightning ("CLPB",true, x,y,x2,y2)
call AddLightning ("CLPB",true, x,y,x3,y3)
call AddLightning ("CLPB",true, x,y,x4,y4)
call TriggerSleepAction (1)
set data.dummy = CreateUnit (GetOwningPlayer(Unit),'h000',x,y,0)
//call PauseUnit (Unit, false)
call TimerStart (SlideTimer,0.1,true, function Slide)             //Error

set Unit = null
endfunction


//===========================================================================

private function SafeFilt takes nothing returns boolean
return true
endfunction
private function Lightning takes nothing returns nothing
 local trigger trig = CreateTrigger()
local integer i = 0
loop
    exitwhen i > 15
    call TriggerRegisterPlayerUnitEvent(trig,Player(i),EVENT_PLAYER_UNIT_SPELL_EFFECT,Condition(function SafeFilt))
    set i = i + 1
endloop
 call TriggerAddCondition (trig, Condition (function Conditions ) )
 call TriggerAddAction (trig, function Actions )
 set trig = null
 endfunction

endscope

 

[AdamGriffith]

Don't you have to end the library at the end of the script?
(Never used it before mind.)

 

[Flare]

Look at my example. Struct members must be refered to using <identifier>.<structmember>, you are referring to them as if they were normal variables.

call TimerStart (SlideTimer,0.1,true, function Slide)

Should be

call TimerStart (data.SlideTimer,0.1,true, function Slide)

You never attached the struct data. At some point in that trigger (after you create the timer) add this line

call SetData (data.SlideTimer, data)

You never retrieved the struct in Slide

local TestStruct data = GetData (GetExpiredTimer ())
//then refer to your struct members like i said above i.e.
local real x = GetUnitX(data.dummy)               
local real y = GetUnitY(data.dummy)

Also, you aren't destroying your lightning effects. You can use this to deal with the lightning effects easily (since the system does all the work of movement etc), all you need to do is call the appropriate function

Don't you have to end the library at the end of the script?

Nope. Everything within a library is sent to map header anyway, so it doesn't make alot of difference where you place it

 

[Kazuga]

Ah nice! Thanks:thup:
About your lightning system, it says that I need TT?

 

[Flare]

About your lightning system, it says that I need TT?

Ye. Just copy the TT and TimedLightning 'triggers' into your map and it's good to go.

 

[Kazuga]

Ok triggers added. Shall I replace

call AddLightning ("CLPB",true, x,y,x2,y2)
call AddLightning ("CLPB",true, x,y,x3,y3)
call AddLightning ("CLPB",true, x,y,x4,y4)

with

call TimedLightningUnit (lightid_string, source_unit, target_unit, duration, fade_on, init_fade, end_fade)
call TimedLighningLoc (lightid_string, loc1, loc2, duration, fade_on, init_fade, end_fade)
call TimedLightning (lightid_string, x1, y1, z1, x2, y2, z2, duration, fade_on, init_fade, end_fade)

and edit the locations?

 

[Flare]

Ok triggers added. Shall I replace

call AddLightning ("CLPB",true, x,y,x2,y2)
call AddLightning ("CLPB",true, x,y,x3,y3)
call AddLightning ("CLPB",true, x,y,x4,y4)

with

call TimedLightningUnit (lightid_string, source_unit, target_unit, duration, fade_on, init_fade, end_fade)
call TimedLighningLoc (lightid_string, loc1, loc2, duration, fade_on, init_fade, end_fade)
call TimedLightning (lightid_string, x1, y1, z1, x2, y2, z2, duration, fade_on, init_fade, end_fade)

and edit the locations?

In that case, you will be using this one

call TimedLightning (lightid_string, x1, y1, z1, x2, y2, z2, duration, fade_on, init_fade, end_fade)

And this is what it should look like in your script

call TimedLightning ("CLPB", x, y, 0, x2, y2, 0, duration, fade_on, init_fade, end_fade)
//Change those 0's to something else if you want the lightning to float above/below default ground height

And repeat with the other 2 lightnings
(since I don't know the values you want for duration, fade enabled, initial fade, and end fade, I can't substitute them in )