Spell Summer Storm

cr4xzZz

Also known as azwraith_ftL.
Reaction score
51
Summer Storm
btnleshlightstormqi0.gif


A spell from my map - Mini Ashenvale Arena.

GUI/JASS/vJASS? vJASS.
MUI? Yes.
Leakless? Yes.
Lagless? Yes.
Follows JESP? It should.
Requires?
- ABCT v2.0
- JASS NewGen Pack v1.5a

Description:
Creates a violent summer storm at a target location, causing lightning bolts to fall from the sky, purging and damaging all nearby enemies upon impact. Damaging, AoE of the ability and AoE of the lightning bolts increases per level, as well as the frequency of the bolts and the chance to purge.

Code:
JASS:
scope SummerStorm

//===========================================================================
// Summer Storm by cr4xzZz (also known as azwraith_ftL)
// Date: August 04, 2008
// Version: 1[1].1
//===========================================================================
// C O N F I G U R A T I O N     M E N U
//===========================================================================
globals
// Raw code of the Summer Storm ability.
    private constant integer AID_SUMMER_STORM = 'A000'
// Raw code of the Purge ability (the custom created one).
    private constant integer AID_PURGE = 'A001'
// Raw code of the [Dummy] Cloud unit.
    private constant integer UID_CLOUD = 'u000'
// Raw code of the Dummy Unit.
    private constant integer UID_DUMMY = 'u001'
// Ability string for casting the purge ability
    private constant string SID_PURGE = "purge"

// Lightning bolt special effect.
    private constant string SFX_BOLT = "Abilities\\Spells\\Other\\Monsoon\\MonsoonBoltTarget.mdl"
// Thunder clap (for impact) special effect.
    private constant string SFX_IMPACT = "Abilities\\Spells\\Human\\ThunderClap\\ThunderClapCaster.mdl"
// The Moonsoon ability effect (rain and fog)
    private constant string SFX_EFFECT = "Abilities\\Spells\\Other\\Monsoon\\MonsoonRain.mdl"
endglobals
// I have included the caster below because someone might want to base values on his attributes.
// Duration of the ability.
    private function DURATION takes unit cast, integer lvl returns real
        return 10. + (5. * lvl)
    endfunction
// Period between lightning bolt impacts.
    private function PERIOD takes unit cast, integer lvl returns real
        return 0.9 - (0.1 * lvl)
    endfunction
// Damage of each lightning bolt.
    private function DAMAGE takes unit cast, integer lvl returns real
        return 20. * lvl
    endfunction
// Attack type of the damaging.
    private function ATTACKTYPE takes unit cast, integer lvl returns attacktype
        return ATTACK_TYPE_MAGIC
    endfunction
// Damage type of the damaging.
    private function DAMAGETYPE takes unit cast, integer lvl returns damagetype
        return DAMAGE_TYPE_MAGIC
    endfunction
// Chance to cast Purge on units hit by a bolt.
    private function CHANCE takes unit cast, integer lvl returns real
        // Make sure it's in range of 1-100 !
        return 20. * lvl
    endfunction
// Area of effect of the spell.
    private function SPELL_AOE takes unit cast, integer lvl returns real
        return 300. + (25. * lvl)
    endfunction
// Area of effect of each bolt.
    private function BOLT_AOE takes unit cast, integer lvl returns real
        return 60. + (40. * lvl)
    endfunction
//===========================================================================
// E N D     O F     C O N F I G U R A T I O N     M E N U
//===========================================================================

private struct Data
    unit cast
    unit cloud
    integer lvl
    location targ
    effect rain
endstruct

private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == AID_SUMMER_STORM
endfunction

//===========================================================================
// Don't know who the creator of this snippet is.
// Anyway, he gets credits...
private function RandomPointCircle takes real x, real y, real d returns location
    local real xadd
    set d = d * SquareRoot(GetRandomReal(0, 1))
    set xadd= d * Cos(GetRandomReal(0, 2) * bj_PI)
    return Location(x + xadd, y + SquareRoot(d * d - xadd * xadd))
endfunction
//===========================================================================

private function Enum takes nothing returns boolean
    return IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false and IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) == false
endfunction

private function Callback takes nothing returns boolean
    local Data d = ABCT_GetData()
    local location loc = RandomPointCircle(GetLocationX(d.targ), GetLocationY(d.targ), SPELL_AOE(d.cast, d.lvl))
    local group gr = CreateGroup()
    local integer chance = GetRandomInt(1, 100)
    local unit first
    call DestroyEffect(AddSpecialEffectLoc(SFX_BOLT, loc))
    call DestroyEffect(AddSpecialEffectLoc(SFX_IMPACT, loc))
    call GroupEnumUnitsInRangeOfLoc(gr, loc, BOLT_AOE(d.cast, d.lvl), Condition(function Enum))
    loop
        set first = FirstOfGroup(gr)
        exitwhen first == null
        if IsUnitEnemy(first, GetOwningPlayer(d.cast)) then
            call UnitDamageTarget(d.cast, first, DAMAGE(d.cast, d.lvl), true, true, ATTACKTYPE(d.cast, d.lvl), DAMAGETYPE(d.cast, d.lvl), null)
            if chance <= CHANCE(d.cast, d.lvl) then
                set bj_lastCreatedUnit = CreateUnit(GetOwningPlayer(d.cast), UID_DUMMY, 0., 0., 0.)
                call UnitAddAbility(bj_lastCreatedUnit, AID_PURGE)
                call SetUnitAbilityLevel(bj_lastCreatedUnit, AID_PURGE, d.lvl)
                call IssueTargetOrder(bj_lastCreatedUnit, SID_PURGE, first)
                call UnitApplyTimedLife(bj_lastCreatedUnit, 'BTLF', 1.)
            endif
        endif
        call GroupRemoveUnit(gr, first)
    endloop
    call DestroyGroup(gr)
    call RemoveLocation(loc)
    set first = null
    set gr = null
    set loc = null
    if GetWidgetLife(d.cloud) < 0.405 then
        call DestroyEffect(d.rain)
        call RemoveLocation(d.targ)
        call d.destroy()
        return true
    endif
    return false
endfunction
                
private function Actions takes nothing returns nothing
    local Data d = Data.create()
    set d.cast = GetTriggerUnit()
    set d.targ = GetSpellTargetLoc()
    set d.cloud = CreateUnitAtLoc(GetOwningPlayer(d.cast), UID_CLOUD, d.targ, GetUnitFacing(d.cast))
    set d.rain = AddSpecialEffectLoc(SFX_EFFECT, d.targ)
    set d.lvl = GetUnitAbilityLevel(d.cast, AID_SUMMER_STORM)
    call UnitApplyTimedLife(d.cloud, 'BTLF', DURATION(d.cast, d.lvl))
    call ABCT_Start(function Callback, d, PERIOD(d.cast, d.lvl))
endfunction

function InitTrig_SummerStorm takes nothing returns nothing
    local trigger trig = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(trig, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(trig, Condition(function Conditions))
    call TriggerAddAction(trig, function Actions)
    
    call Preload(SFX_BOLT)
    call Preload(SFX_IMPACT)
    call Preload(SFX_EFFECT)
endfunction

endscope

Screenshot:
summerstormrn4.jpg

Changes:
JASS:
v1.0 - Release
v1.1 - Effects are now properly preloaded. Added a string for the spell that is casted. Variables now have better names.. (were "omg", "wtf", etc.)


Credits to Cohadar for ABCT and Tinki3 for the Test Map Template.
 

Attachments

  • Summer Storm v1[1].1.w3x
    54.5 KB · Views: 222
Reaction score
456
Preload the constant strings instead:
JASS:
function InitTrig_SummerStorm takes nothing returns nothing
    local trigger trig = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(trig, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(trig, Condition(function Conditions))
    call TriggerAddAction(trig, function Actions)
    
    call Preload(SFX_BOLT)
    call Preload(SFX_IMPACT)
    call Preload(SFX_EFFECT)
endfunction


Some other names for the locals than "omg", "lolcat", "cheezburger", please. That helps reading the code.

I'd like it more if you used static method create and method onDestroy.
 

cr4xzZz

Also known as azwraith_ftL.
Reaction score
51
> Preload the constant strings instead:
Will do.

> I'd like it more if you used static method create and method onDestroy.
Absolutely no need for this simple spell..

> Some other names for the locals
It's about 10 lines with these names.. It's not like having 100 lines with them. But I will edit them anyway.
 
Reaction score
456
> Absolutely no need in this simple spell..
In my opinion, it's a thing that gives points to readability.
 

Flare

Stops copies me!
Reaction score
662
Looks pretty cool from the screenshot :)

In my opinion, it's a thing that gives points to readability.
Well, the create method doesn't really add a whole pile to readability (since it's only about 7 lines in a obviously-named function) but the onDestroy would help

Also, might be a good idea to store the dummy caster's order string in a constant, if people ever felt the need to make the spell stun rather than purge (or something like that)

And the var names... why would you even think of calling a variable 'omg' or 'wtf'???
 

cr4xzZz

Also known as azwraith_ftL.
Reaction score
51
> it's a thing that gives points to readability
Well, it doesn't give me readability to me... I have to stare at the struct and then scroll back to the actions to check if I did everything right. :)

> Also, might be a good idea to store the dummy caster's order string in a constant
I knew I've forgotten something. Thanks for reminding me ^^

> And the var names... why would you even think of calling a variable 'omg' or 'wtf'???
Dunno. It was an outburst of silly nonsense.

> onDestroy would help
Ah, why the hell should I add two lines more? It's pointless to use it in such a short code. I agree onDestroy is good, but not in such a spell.

Fixing.

EDIT:
Fixed.
 

cr4xzZz

Also known as azwraith_ftL.
Reaction score
51
> Your are returning a location here...
Yes, I am. Locations are faster.

> How about breaking this function into 2, using X and Y?
No need, really. I use the snippet the way it is, and there's no problem even if it returns a location. ^^
 

Kazuga

Let the game begin...
Reaction score
110
Nice spell, you sure do code a lot different than me.^^

Hmmm... Wondering why this isn't approved yet...
Well there are spells that has been pending a lot longer than this one. For instance my spellpack has been pending since June 19.
 

Igor_Z

You can change this now in User CP.
Reaction score
61
Suggestion: Create some dummes at the upper point of the clowd.. Add a spell to the dummy with different effect(Chain Lightning for Example), to look like the lightning is coming from the clowd. U can do that, its gonna look cooler
 
General chit-chat
Help Users
  • No one is chatting at the moment.

      The Helper Discord

      Staff online

      Members online

      Affiliates

      Hive Workshop NUON Dome World Editor Tutorials

      Network Sponsors

      Apex Steel Pipe - Buys and sells Steel Pipe.
      Top