ways to attach a struct and use it in a condition function?

[waaaks!]

I'm having problems on how to attach a struct to something and retrieve the struct in a condition function from a GroupEnum filter function

function filt takes nothing returns boolean
    local myStruct d = ?? // how will I retrieve myStruct?
    local unit u = GetFilterUnit()
    call UnitDamageTarget(d.c,u,40,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,null)
    return false //The Group will not be filled because the function returns false, instead this function will loop through the units
endfunction

function  bla takes nothing returns nothing
    local group g = NewGroup()
    local myStruct d = myStruct.create()
    local real x = 0.0
    local real y = 0.0
    set d.c = GetTriggerUnit()
    call GroupEnumUnitsInRange(g,x,y,500,Condition(function filt))
    //cleanups.....
endfunction

 

[kingkingyyk3]

Globals.

 

[Joker(Div)]

And yes, it is MUI.

 

[waaaks!]

so do you mean using globals still makes the spell MUI?

 

[Viikuna]

That is correct

edit. Example:

// in myStruct:
static myStruct temp 

//:
function filt takes nothing returns boolean
    local myStruct d = myStruct.temp
    local unit u = GetFilterUnit()
    call UnitDamageTarget(d.c,u,40,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,null)
    return false //The Group will not be filled because the function returns false, instead this function will loop through the units
endfunction

function  bla takes nothing returns nothing
    local real x = 0.0
    local real y = 0.0
    set myStruct.temp = myStruct.create()
    set myStruct.temp.c = GetTriggerUnit()
    call GroupEnumUnitsInRange(NewGroup(),x,y,500,Condition(function filt))
    //cleanups.....
endfunction

 

[Tom_Kazansky]

how about this:

globals
     integer TEMPINT
endglobals

function filt takes nothing returns boolean
    local myStruct d = TEMPINT // retrieve
    local unit u = GetFilterUnit()
    call UnitDamageTarget(d.c,u,40,true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_NORMAL,null)
    return false //The Group will not be filled because the function returns false, instead this function will loop through the units
endfunction

function  bla takes nothing returns nothing
    local group g = NewGroup()
    local myStruct d = myStruct.create()
    local real x = 0.0
    local real y = 0.0
    set d.c = GetTriggerUnit()
    set TEMPINT = d //for retrieving
    call GroupEnumUnitsInRange(g,x,y,500,Condition(function filt))
    //cleanups.....
endfunction

condition functions can never have wait so that TEMPINT using will not gonna screw anything up

 

[Jesus4Lyf]

Unless it is recursive. Enum functions can potentially call themselves (example: do for every unit in range of every unit in range). If you're passing a center unit or something, it will screw up for subsequently enumerated units after recursion occurs. In this case, you require a stack.