Hero Revive and Death Clock Error

[Kayoss666]

i am just getting the hang of Jass but this code is just not working at all but jasshelper finds no problems with it. So i am assuming i inserted something right but not for what i want. i commented to the three spots i think the error could be but i don't know Jass good enough to tell.

function Trig_ReviveHero_Conditions takes nothing returns boolean
    if ( not ( IsUnitType(GetDyingUnit(), UNIT_TYPE_HERO) == true ) ) then
        return false    //^^error might be here not sure if IsUnitType was set up right
    endif
    return true
endfunction
 
function Trig_ReviveHero_Actions takes nothing returns nothing
    if ( Trig_ReviveHero_Conditions() and GetLocalPlayer()==GetOwningPlayer(GetDyingUnit()) ) then //also this if state might be the cause
        set udg_deathtollwindow[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))] = CreateTimerDialog(udg_deathtoll[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))]) 
        call TimerDialogDisplay(udg_deathtollwindow[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))], true)
        call TimerDialogSetTitle(udg_deathtollwindow[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))], "Revive") 
        call TimerStart( udg_deathtoll[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))], 40.00, false, null)
        call TriggerSleepAction( 40.00 )
        call PanCameraToTimedLocForPlayer( GetOwningPlayer(GetDyingUnit()), udg_Restart_point[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))], 0 )
        call ReviveHeroLoc( GetDyingUnit(), udg_Restart_point[(GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit())))], false )
        call DestroyTimerDialog(udg_deathtollwindow[GetConvertedPlayerId(GetOwningPlayer(GetDyingUnit()))])
    else
        call DoNothing( )
    endif
endfunction
 
//===========================================================================
function InitTrig_ReviveHero takes nothing returns nothing
    set gg_trg_ReviveHero = CreateTrigger(  )
    //The error might be in the player part on next line but i believe it should work.vv
    call TriggerRegisterPlayerUnitEvent(gg_trg_ReviveHero, GetOwningPlayer(GetDyingUnit()), EVENT_PLAYER_UNIT_DEATH, null)
    call TriggerAddAction( gg_trg_ReviveHero, function Trig_ReviveHero_Actions )
endfunction

 

[PurgeandFire]

In the register event line:

call TriggerRegisterPlayerUnitEvent(gg_trg_ReviveHero, GetOwningPlayer(GetDyingUnit()), EVENT_PLAYER_UNIT_DEATH, null)

GetDyingUnit() is null (at least at that point in time). The InitTrig functions are called on map initialization, but they don't actually correspond to the events that are being registered. For example, if you made an event for a unit being summoned, you cannot register it like this:

call TriggerRegisterUnitEvent(t, GetSummonedUnit(), EVENT_UNIT_SUMMONED)

It expects a particular unit. Since InitTrig functions are simply called on initialization, rather than in response to some event, GetSummonedUnit() will simply return null.

The fix would be to either manually loop through all players to register it, or simply use this function for it:

call TriggerRegisterAnyUnitEventBJ(gg_trg_ReviveHero, EVENT_PLAYER_UNIT_DEATH)

I haven't checked the rest of the code though, but hopefully that'll get you started.

 

[Kayoss666]

Thank you I now have it working and i think this will help on some of my other problems so double thanks.

 

[DrEvil]

To add some further help with learning jass we should try to understand the generated condition.

function Trig_ReviveHero_Conditions takes nothing returns boolean
    if ( not ( IsUnitType(GetDyingUnit(), UNIT_TYPE_HERO) == true ) ) then
        return false    //^^error might be here not sure if IsUnitType was set up right
    endif
    return true
endfunction

Why Blizzard decided to generate conditions this way is beyond my understanding but it makes it pretty useless to learn from when you are just starting.

So what happens if a unit is a hero?
E.g. IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO) returns true, because the unit is a hero.

if( not ( true == true ))then
      return false
endif
return true
 
if( not (true))then
    return false
endif
return true
 
if( false == true)then  
// not is basically comparing it to false
//not(false) === true
//(false == false) ===true
    return false
endif
return true

If a unit type is of hero the if statement returns false and ends, then returns true.
But if a unit type is not a hero, the if statement will be true and return false.

But we already know that IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO) will give a true value if a unit is a hero, or false if the unit is non-hero.
The return type of the function is boolean (true/false) so you can just return the value of the IsUnitType function

function Trig_ReviveHero_Conditions takes nothing returns boolean
     return IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO)
endfunction
 
// or if you wanted to only add units if they were non-heroes you could return the inverse of the function 
 
return not(IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO))
return !(IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO))
return IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO)==false
return  false==IsUnitType(GetDyingUnit(),UNIT_TYPE_HERO)
// these four returns all do the same thing
// 1. is a function call, but one function call is really nothing to worry about performance wise
// 2. is shorthand for changing the sign (comparing to false)
// 3 & 4. it doesn't matter which way you compare false to