Prevent units from sliding against the wall when being knocked back

[Leazy]

Hello!

I made a simple knock back system:

• Knockback
  • Events
    • Time - Every 0.03 seconds of game time
  • Conditions
  • Actions
    • Unit Group - Pick every unit in Knockback_Group and do (Actions)
      • Loop - Actions
        • Set Caster = (Picked unit)
        • Set Point[1] = (Position of Caster)
        • Set Point[2] = (Point[1] offset by KNOCKBACK_Power[(Custom value of Caster)] towards KNOCKBACK_Angle[(Custom value of Caster)] degrees)
        • Unit - Move Caster instantly to Point[2]
        • Special Effect - Create a special effect attached to the origin of Caster using Abilities\Weapons\AncientProtectorMissile\AncientProtectorMissile.mdl
        • Special Effect - Destroy (Last created special effect)
        • Set KNOCKBACK_Duration[(Custom value of Caster)] = (KNOCKBACK_Duration[(Custom value of Caster)] - 0.03)
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • KNOCKBACK_Duration[(Custom value of Caster)] Less than or equal to 0.00
          • Then - Actions
            • Unit Group - Remove Caster from Knockback_Group
          • Else - Actions
        • Custom script: call RemoveLocation (udg_Point[1])
        • Custom script: call RemoveLocation (udg_Point[2])

The problem is that units slide against walls and other obstacles when being knocked back, how can I prevent this? I want that they should either stop being knocked back when reaching an obstacle, or just keep being knocked against it. Is this possible?

 

[OMGOMGOMG]

You could try to detect if there is something in the way (behind the knocked back unit) and order the knocked back unit to stop, although I don't think its possible to detect if something is in the way

 

[dianamod27]

I guess you could check the distance between Point[1] and Point[2], i.e., if the unit actually arrived where it's supposed to.

 

[Mabaet.Baet]

You can try searching for knockback systems and see how they do it. You can even look at Blizzard's Azure Grand Prix (The Racing Game) and see how they prevent cars from passing through unpathable.

Here's how I detect unpathables. Actually, I snag a part of Silvenon's knockback system... the part where it detects if a location is pathable.
Here I made a snippet from it. It uses an item. The item is moved to the location where you check if pathable, if the item is not there, then the location is not pathable. So this detects also blocking doodads(like trees or something) or terrain cliff edges.

library IsXYPathable initializer Init
    globals
        private item I
    endglobals

    private function CheckPathabilityTrickGet takes nothing returns nothing
        set bj_rescueChangeColorUnit = bj_rescueChangeColorUnit or GetEnumItem() != I
    endfunction

    private function CheckPathabilityTrick takes real x, real y returns boolean
        local integer i = 30
        local real X
        local real Y
        local rect r
        call SetItemPosition(I, x, y)
        set X = GetItemX(I) - x
        set Y = GetItemY(I) - y
        if X * X + Y * Y <= 100 then
            return true
        endif
        set r = Rect(x - i, y - i, x + i, y + i)
        set bj_rescueChangeColorUnit = false
        call EnumItemsInRect(r, null, function CheckPathabilityTrickGet)
        call RemoveRect(r)
        set r = null
        return bj_rescueChangeColorUnit
    endfunction

    function CheckPathability takes real x, real y returns boolean
        local boolean b = CheckPathabilityTrick(x, y)
        call SetItemVisible(I, false)
        return b
    endfunction

    private function Init takes nothing returns nothing
        set I = CreateItem('ciri',.0,.0)
        call SetItemVisible(I, false)
    endfunction
endlibrary

To use it in GUI:

• Set booleanVar = (CheckPathability(GetLocationX(udg_PointVarName),GetLocationY(udg_PointVarName)))

So yeah, basically... if it returns true, then the location is pathable, else not.
Note: Requires NewGen

And last-- you should USE THIS to prevent units from getting knocked OUT of the map boundaries... the will cause Fatal Error crashing the game.
Edit: Hey, if you want the knockback to destroy trees when unit collided with it, tell me. I'll post here how.