Spell Black Hole

[~GaLs~]

Black Hole..
The ultimate of the universe...
Came up on warcraft3...Yeah !! Thats me...i made it!!

Although this spell looks alike to dota Enigma's ultimate....but it is not...this is made by me by scratch.

Suck the nearby enemy (750 AOE) to the point being casted...
Dealing level of ability x 10 damage every second.



Jass Version:

scope BlackHoleJass

//===================================================================================
//                                      BlackHole                                 
//                                by kentchow75/~GaLs~
//===================================================================================
//
// Implemention Instruction
// 
//--------------------------------------------------------------------------------
// -Object Needed to be copied from Object Editor to your map.
//  [ Ability ]
//  1. Black Hole [E]
//
//--------------------------------------------------------------------------------
// -Trigger  
//  1. Copy this whole trigger to your map.
//  2. Copy ABC to your map if you don't have one.
//  3. Copy RealXY to your map if you don't have one.
//--------------------------------------------------------------------------------
// -Requirements
//  1. Jass NewGen WorldEditor from <a href="http://www.wc3campaigns.net" target="_blank" class="link link--external" rel="nofollow ugc noopener">www.wc3campaigns.net</a>. ( v4d and above )
//  2. ABC system.
//  3. RealXY library.
//--------------------------------------------------------------------------------
//===================================================================================
//  Implementation End                                 
//===================================================================================
globals
//*******************************************************************************************
//  Configuration  (This is where you need to edit to make the spell works in your map)
//*******************************************************************************************

//&lt;-------------------- Rawcode --------------------&gt;//
    private constant integer SPELL_ID = &#039;A003&#039; //Rawcode of the Ability
//&lt;-------------------- Rawcode End --------------------&gt;//

//&lt;-------------------- Radius --------------------&gt;//
    private constant real RADIUS = 750. //How far will this spell sucks enemy from the point being casted
//&lt;-------------------- Radius End --------------------&gt;//

//&lt;-------------------- Period --------------------&gt;//
    private constant real PERIOD = 0.05  //How fast will the unit being suck (The lesser, the faster)
//&lt;-------------------- Period End --------------------&gt;//

//&lt;-------------------- Effect String --------------------&gt;//
    private constant string UNIT_EFFECT = &quot;Abilities\\Spells\\Other\\Incinerate\\IncinerateBuff.mdl&quot;
    //The effect that will be shown on the unit when the unit is being suck
    
    private constant string LOC_EFFECT = &quot;Abilities\\Spells\\Human\\FlameStrike\\FlameStrikeTarget.mdl&quot;
    //The effect that will shown in the target ground (Advise not to change it)
//&lt;-------------------- Effect String --------------------&gt;//
endglobals

//&lt;-------------------- Damage Per Second --------------------&gt;//
private constant function DPS takes integer level returns real 
    return 10. * level //The formula for counting how much damage to deal to the unit being suck per second
endfunction
//&lt;-------------------- Damage Per Second End --------------------&gt;//

//*******************************************************************************************
//  Configuration End
//*******************************************************************************************

// -----------------------&gt; Do not edit anything below this line. &lt;-----------------------//
// -----------------------&gt; Do not edit anything below this line. &lt;-----------------------//
// -----------------------&gt; Do not edit anything below this line. &lt;-----------------------//

globals
    private unit Caster
endglobals

private function GetDamageMiliSec takes real DamagePerSec returns real
    return DamagePerSec * PERIOD
endfunction

struct BlackHole
unit caster
real cx
real cy
real tx
real ty
real DamagePerSecond
group victims = CreateGroup()
timer t = CreateTimer()
timer Efft = CreateTimer()
    
    static method VictimsCond takes nothing returns boolean
    local unit fil = GetFilterUnit()
    local boolean b1 = GetUnitState(fil,UNIT_STATE_LIFE) &gt; 0
    local boolean b2 = IsUnitType(fil, UNIT_TYPE_STRUCTURE) == false
    local boolean b3 = IsUnitType(fil, UNIT_TYPE_MAGIC_IMMUNE) == false
    local boolean b4 = IsUnitAlly(fil,GetOwningPlayer(Caster)) == false
    
    set fil = null
    return b1 and b2 and b3 and b4
    endmethod
    
    static method tCallBack takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local BlackHole bh = GetTimerStructA(t)
    local unit enum 
    local real ex
    local real ey
    local real AngleToHole
    local real movex
    local real movey
    local real range
    
    if GetUnitCurrentOrder(bh.caster) == 852600 then 
        call GroupEnumUnitsInRange(bh.victims,bh.tx,bh.ty,RADIUS,Condition(function BlackHole.VictimsCond))
        
        set enum = FirstOfGroup(bh.victims)
        loop
        exitwhen enum == null
            set ex = GetWidgetX(enum)
            set ey = GetWidgetY(enum)
            set AngleToHole = AngleBetweenXY(ex,ey,bh.tx,bh.ty)
            set range = DistanceBetweenXY(ex,ey,bh.tx,bh.ty)
            set movex = OffsetX(ex,5+((RADIUS-(range))/25),AngleToHole)
            set movey = OffsetY(ey,5+((RADIUS-(range))/25),AngleToHole)
        
            call IssueImmediateOrder(enum,&quot;stop&quot;)
            if not IsTerrainPathable(movex, movey, PATHING_TYPE_WALKABILITY) then
                call SetUnitX(enum,movex)
                call SetUnitY(enum,movey)
            endif
            call UnitDamageTarget(bh.caster,enum,GetDamageMiliSec(bh.DamagePerSecond),true,false,ATTACK_TYPE_NORMAL,DAMAGE_TYPE_MAGIC,null)
            
            call DestroyEffect(AddSpecialEffectTarget(UNIT_EFFECT,enum,&quot;origin&quot;))
            
            call GroupRemoveUnit(bh.victims,enum)
            set enum = FirstOfGroup(bh.victims)
        endloop
    elseif GetUnitCurrentOrder(bh.caster) != 852600 then
        call bh.destroy()
    endif
    set t = null
    endmethod
    
    static method EffCallBack takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local BlackHole bh = GetTimerStructA(t)
    
    call DestroyEffect(AddSpecialEffect(LOC_EFFECT,bh.tx,bh.ty))
    
    set t = null
    endmethod

    static method create takes unit cast, real tarx, real tary returns BlackHole
    local BlackHole bh = BlackHole.allocate()
    set bh.caster = cast
    set bh.cx = GetWidgetX(cast)
    set bh.cy = GetWidgetY(cast)
    set bh.tx = tarx
    set bh.ty = tary
    set bh.DamagePerSecond = DPS(GetUnitAbilityLevel(cast,SPELL_ID))
    set Caster = cast
    
    call SetTimerStructA(bh.t,bh)
    call TimerStart(bh.t,PERIOD,true,function BlackHole.tCallBack)
    
    call SetTimerStructA(bh.Efft,bh)
    call TimerStart(bh.Efft,0.4,true,function BlackHole.EffCallBack)

    return bh
    endmethod

    method onDestroy takes nothing returns nothing
    call ClearTimerStructA(.t)
    call ClearTimerStructA(.Efft)
    
    call PauseTimer(.t)
    call PauseTimer(.Efft)
    call DestroyTimer(.t)
    call DestroyTimer(.Efft)
    
    call DestroyGroup(.victims)
    
    endmethod
endstruct

private function Cond takes nothing returns boolean
    return GetSpellAbilityId() == SPELL_ID
endfunction

private function Act takes nothing returns nothing
local location loc = GetSpellTargetLoc()
local BlackHole bh = BlackHole.create(GetSpellAbilityUnit(),GetLocationX(loc),GetLocationY(loc)) 
call RemoveLocation(loc)
set loc = null
endfunction

//===========================================================================
function InitTrig_BlackHoleJass takes nothing returns nothing
local trigger t = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t,Condition(function Cond))
    call TriggerAddAction( t, function Act)
endfunction

endscope
//===========================================================================

*It is advise to use the Jass version as it is much more realistic because the speed of sliding in is not constant.
It depends on how far the enemy from the casted point, the nearer, sucks faster.

Download Here:
View attachment Black Hole.w3x
View attachment Black Hole +Jass v1.1.w3x

 

[Dimaspy]

Good job!
Nice spell, too bad I'm not able to use it in any of my maps. they are too realistic..

 

[~GaLs~]

You meant my spell too realistic or...your map too realistic -.-?
___________________________
I know this is a bad idea...but rep me..?Haha..
Dont -rep me please

 

[Sim]

> Every 0.25 seconds of game-time

Doesn't look smooth enough. Lower that number.

You should also add a condition check that deals with magic immune units. It works on golems - and it shouldn't, in my opinion.

 

[~GaLs~]

erm...i will do it to lowered the event time intersection...
And...do you think this spell should be nth to magic immune unit??

Edit: The new map is uploaded...this should manage to fix the thingy mentioned by dex

 

[martix]

Black hole as in simple movement towards the center like "dota Enigma's ultimate" OR does it have nice gravitational effects and stuff?

 

[~GaLs~]

it has a nice effect of sucking effect in it

 

[Sim]

Black hole as in simple movement towards the center like "dota Enigma's ultimate" OR does it have nice gravitational effects and stuff?

It is like in DotA.

It's still not smooth enough Gals. Simply set the periodic to 0.04 and the distance moved to 10 or 5, instead of 50:

Set fvloc[4] = (fvloc[3] offset by 50.00 towards (Angle from fvloc[3] to fvloc[1]) degrees)

Should be

Set fvloc[4] = (fvloc[3] offset by 10.00 towards (Angle from fvloc[3] to fvloc[1]) degrees)

 

[martix]

As a challange - make a realistic version of the spell too.
Otherwise I could do it.
Ever seen some starcraft 2 trailers - there's a demo...

 

[~GaLs~]

what means by a ''realistic'' version?

**I posted the ''smoothen'' map on the header**

 

[Sim]

Looks good.

Approved.

 

[~GaLs~]

thanks ya dexy @@

 

[Psiblade94122]

a realistic version could be done by setting the distance moved variable into a math equation where it checks how far awat a unit is from the center

it would look something like this

Set Temp_UG = Units within 750 of Black hole
Unit Group - Pick every unit in Temp_UG
Set L = Position of Black hole
Set L2 = Position of picked unit
Set Temp_Real = Math - ((distance between L and L2 - 750 )/ 10)
Set L3 = L with an offset of Temp_Real towards (Math - Angle between L and L2 <or the other way around, not sure)
Unit - Move (instantly) picked unit to L3

srry, i only know gui atm and school starts tomorrow, but this is what a " realistic" black hole trigger would look like <i used one thats like this on my orbiting battle map)

btw ~Gals~ gj on the spell ^_^ +rep

 

[RedSword]

Could it be possible to makes unit under the effect of black hole to be sucked as in a spiral ? (I guess that's what they wanna say by "realistic")

 

[~GaLs~]

>>Could it be possible to makes unit under the effect of black hole to be sucked as in a spiral ?
We can do that...just by adjusting the picked unit group's matching condition...

>>it would look something like this
i'm bad in maths...cant understand...

 

[Psiblade94122]

lol srry, in a nutshell, the closer your unit is to the black hole, the more the unit will be "sucked" in.

Basically it works something like this

How far away your unit is from the black hole, subtracted from the AoE of the black hole then divided by 10 to make the animation smooth

 

[~GaLs~]

Update!

I am using this spell for my project, and GUI doesn't really fit it, so I remake it into a Jass version. I decided to upload it here too.

 

[benj_war3]

Is this the Enigma spell? Sorry for asking or maybe something better!! Good job!

 

[~GaLs~]

It is something alot alot better.

 

[Uberplayer]

You know, the configuration menu doesn't have to be filled with comment lines, because it makes it look so messy.

For an example:

//<-------------------- Rawcode -------------------->//
    private constant integer SPELL_ID = 'A003' //Rawcode of the Ability
//<-------------------- Rawcode End -------------------->//

We can understand what value that is, without the comments line on top and bottom:

//Rawcode of the Ability
private constant integer SPELL_ID = 'A003'

By using that kind of method to the whole configuration menu:

//*******************************************************************************************
//  Configuration  (This is where you need to edit to make the spell works in your map)
//*******************************************************************************************

globals
    //Rawcode of the Ability
    private constant integer SPELL_ID = 'A003'
    
    //How far will this spell sucks enemy from the point being casted
    private constant real RADIUS = 750.

    //How fast will the unit being suck (The lesser, the faster)
    private constant real PERIOD = 0.05

    //The effect that will be shown on the unit when the unit is being suck
    private constant string UNIT_EFFECT = "Abilities\\Spells\\Other\\Incinerate\\IncinerateBuff.mdl"
    
    //The effect that will shown in the target ground (Advise not to change it)
    private constant string LOC_EFFECT = "Abilities\\Spells\\Human\\FlameStrike\\FlameStrikeTarget.mdl"
endglobals

private constant function DPS takes integer level returns real 
    return 10. * level //The formula for counting how much damage to deal to the unit being suck per second
endfunction

//*******************************************************************************************
//  Configuration End
//*******************************************************************************************