Spellpack Hell Spells

[waaaks!]

MUI
JASS
LEAKLESS
JESP


Demon's Sanctum
Slams the ground, dealing initial damage, then stuns for 1 second, and creating pits from hell, that fires damaging rays, second sanctuary rays deals double the damage dealt by the first sanctuary.

Level 1 - 50 initial damage, first sanctuary deals 20 damage.
Level 2 - 100 initial damage, first sanctuary deals 40 damage.
Level 3 - 150 initial damage, first sanctuary deals 60 damage.

//*******************************************
//* Demon's Sanctum
//* by waaaks!
//*******************************************
//* Requires
//* -Demon Sanctum Spell
//* -First Sanctuary Spell
//* -Second Sanctuary Spell
//* -Sanctuary unit
//*******************************************
//* Object Editor Configuration             
//* -Demon's Sanctuary Damage and Stun      
//* -First Sanctuary Damage Range and Speed 
//* -Second Sanctuary Damage Range and Speed
//*******************************************

constant function DemonSpellId takes nothing returns integer
 return 'A000' // Demon's Sanctum Spell Id
endfunction

constant function DemonDummySpell1 takes nothing returns integer
 return 'A002' // First Sanctuary Spell Id
endfunction

constant function DemonDummySpell2 takes nothing returns integer
 return 'A001' // Second Sanctuary Spell Id
endfunction

constant function DummyId takes nothing returns integer
 return 'u000' // Sanctuary Dummy Id
endfunction

constant function DummySpellString takes nothing returns string
 return "carrionswarm" // Dummy Spells String Order
endfunction

constant function Range1 takes nothing returns real
 return 300.0 // First Sanctuary range from the caster
endfunction

constant function Range2 takes nothing returns real
 return 600.0 // Second Sanctuary range from the caster
endfunction

function Trig_DemonSanctum_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == DemonSpellId()
endfunction

function Trig_DemonSanctum_Actions takes nothing returns nothing
 local unit cast = GetTriggerUnit()
 local location loc = GetUnitLoc(cast)
 local location pol1 = null
 local location pol2 = null
 local unit first
 local unit second
 local integer n = 1
 local integer l = GetUnitAbilityLevel(cast, DemonSpellId())
 loop
   exitwhen n > 36
   set pol1 = PolarProjectionBJ(loc, Range1(), 10*n)
   set pol2 = PolarProjectionBJ(loc, Range2(), 10*n)
   set first = CreateUnitAtLoc(GetOwningPlayer(cast), DummyId(), pol1, 10*n)
   set second = CreateUnitAtLoc(GetOwningPlayer(cast), DummyId(), pol2, 10*n)
   call UnitApplyTimedLife(first, 'BTLF', 8.0)
   call UnitApplyTimedLife(second, 'BTLF', 8.0)
   call UnitAddAbility(first, DemonDummySpell1())
   call UnitAddAbility(second, DemonDummySpell2())
   call SetUnitAbilityLevel(first, DemonDummySpell1(), l)
   call SetUnitAbilityLevel(second, DemonDummySpell2(), l)
   call IssuePointOrder(first, DummySpellString(), GetUnitX(cast), GetUnitY(cast))
   call IssuePointOrder(second, DummySpellString(), GetUnitX(cast), GetUnitY(cast))
   call RemoveLocation(pol1)
   call RemoveLocation(pol2)
   set n = n + 1
 endloop
 call RemoveLocation(loc)
 set loc = null
 set pol1 = null
 set pol2 = null
 set first = null
 set second = null
endfunction

//===========================================================================
function InitTrig_DemonSanctum takes nothing returns nothing
    set gg_trg_DemonSanctum = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_DemonSanctum, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_DemonSanctum, Condition( function Trig_DemonSanctum_Conditions ) )
    call TriggerAddAction( gg_trg_DemonSanctum, function Trig_DemonSanctum_Actions )
endfunction

Nightmare
Sends out a vicous coil to the target location, dealing damage in a line, when the coil arrives, it creates a ring of death outward, that deals damage.

Level 1 - 100 line damage, 40 nova damage.
Level 2 - 150 line damage, 60 nova damage.
Level 3 - 200 line damage, 80 nova damage

//*******************************************
//* Nightmare
//* by waaaks!
//*******************************************
//* Requires
//* -Nightmare Spell
//* -Ring Of Death Spell
//* -A dummy unit
//*******************************************
//* Object Editor Configuration             
//* -Nightmare Damage Speed, and Max Range       
//* -Ring of Death Damage, Speed, Max Range
//*******************************************

constant function NightmareSpell takes nothing returns integer
 return 'A003' // Nightmare Spell
endfunction

constant function RingOfDeathSpell takes nothing returns integer
 return 'A004' // Ring Of Death Spell
endfunction

constant function DummyUnit takes nothing returns integer
 return 'u001' // Your Dummy Unit
endfunction

constant function NightmareSpeed takes nothing returns real
 return 600.0 // Nightmare Missile Speed
endfunction

constant function NightmareRange takes nothing returns real
 return 1000.0 // Nightmare Max Range
endfunction

constant function RingOfDeathOrder takes nothing returns string
 return "carrionswarm" // Ring Of Death String Order
endfunction

function Trig_Nightmare_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == NightmareSpell()
endfunction

function Trig_Nightmare_Actions takes nothing returns nothing
 local unit cast = GetTriggerUnit()
 local location loc = GetUnitLoc(cast)
 local location targ = GetSpellTargetLoc()
 local location loc2 = PolarProjectionBJ(loc, NightmareRange(), AngleBetweenPoints(loc, targ))
 local location pol = null
 local unit dummy
 local integer l = GetUnitAbilityLevel(cast, NightmareSpell())
 local integer n = 1
 local real wait = NightmareRange() / NightmareSpeed()
 call PolledWait(wait)
 loop
  exitwhen n > 36
  set pol = PolarProjectionBJ(loc, 10.0, 10*n)
  set dummy = CreateUnitAtLoc(GetOwningPlayer(cast), DummyUnit(), loc2, 10*n)
  call UnitApplyTimedLife(dummy, 'BTLF', 5.0)
  call UnitAddAbility(dummy, RingOfDeathSpell())
  call SetUnitAbilityLevel(dummy, RingOfDeathSpell(), l)
  call IssuePointOrderLoc(dummy, RingOfDeathOrder(), loc2)
  call RemoveLocation(pol)
  set n = n + 1
 endloop
 call RemoveLocation(loc)
 call RemoveLocation(loc2)
 call RemoveLocation(targ)
 set targ = null
 set loc = null
 set loc2 = null
 set pol = null
 set dummy = null
 set cast = null
endfunction

//===========================================================================
function InitTrig_Nightmare takes nothing returns nothing
    set gg_trg_Nightmare = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Nightmare, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Nightmare, Condition( function Trig_Nightmare_Conditions ) )
    call TriggerAddAction( gg_trg_Nightmare, function Trig_Nightmare_Actions )
endfunction

 

[cr4xzZz]

Looks scary Too bad I can't +rep you. Cool spells anyway

 

[Uberplayer]

Afterwards.. Use something else than circles.. people have gotten tired, because contest is full of circle spells ;D.. (I have one)

Good job anyway!

 

[Rheias]

Nice simple spells, lots of eye-candy. I think I told you before, it is much easier to read the codes when you put spaces.

 

[waaaks!]

ill try making spells other than circles

next time ill post codes. ill add spaces

thanks for feedbacks

 

[NetherHawk]

hey waaaaks, do you do the spell in gui first, convert to jass den change the globals to locals?

 

[~GaLs~]

This:

 local location pol1 = null //There is no need to nulling it once you declared it
 local location pol2 = null //Just leave it as local location pol1/pol2 will do, remove the =null

>>hey waaaaks, do you do the spell in gui first, convert to jass den change the globals to locals?
I don't really think so, people can write the whole code by scratch, and I don't see any swapped or BJ function call in his code too...

 

[NetherHawk]

thats amazing~ i cant do it

 

[waaaks!]

hey waaaaks, do you do the spell in gui first, convert to jass den change the globals to locals?

no i didnt converted it...

local location pol1 = null //There is no need to nulling it once you declared it
 local location pol2 = null //Just leave it as local location pol1/pol2 will do, remove the =null

i used newgen, and the spell wont work if it is not initialize, and when i tried to set it as a polar projection, it gives me leak, this is way better because it doesnt give me any error and/or any leaks

if it works for u guys, mine doesnt work, because when i tried it ingame, newgen will say, "2 locations not initialize in Trig_DAStart_Actions"

thats amazing~ i cant do it

you can do it easily, just make 2 circles that has far away distance from each other, and order that dummy unit to cast a spell targeting at the origin of the circle, and you will get that result

for the second spell, just wait until the carrion swarm missile reaches the destination, and then fire the nova on where it lands, just use the formula "Max Distance / Missile Speed" and use it as a wait for ur spell

 

[NetherHawk]

i dont mean the spell, i mean the jass scripting. writing it at a go, i need to do it in GUI and then convert >.> even so i always have those nasty BJs which im still laerning how to replace.

 

[waaaks!]

that can be easily avoided, go get jasscraft, and if u got those BJs then view the function in jasscraft and find its native, or the functions that compose that function

what do i need to do to make this spell approved?

 

[~GaLs~]

>>newgen will say, "2 locations not initialize in Trig_DAStart_Actions"
NewGen don't speak. Grimoire do.

>>go get jasscraft, and if u got those BJs then view the function in jasscraft and find its native, or the functions that compose that function
Use the latest NewGen WorldEditor. It is TESH added and those BJs are highlighted in red color.

 

[waaaks!]

yeah i love the new newgen...but just wondering how do i use the feature which will automatically create borders for tga, bmp, and jpeg?

 

[~GaLs~]

>>yeah i love the new newgen...but just wondering how do i use the feature which will automatically create borders for tga, bmp, and jpeg?
That's a feature of Grimex. Read the readme of Grimmoire included in the grimtext folder.

 

[waaaks!]

ah ok thx