Im new to Jass and I have some basic questions

[Idontknowyou]

I have just started learning (trying to learn) Jass and I have read a few of the tutorials in this forum; I have learned alot from the tutorials on this froum but there are alot of important things I do not understand (at all).
I know that a function can act as an event, action or condition; I understand how to make conditions and actions with a function, but I really have no clue how to make a function call another function after something happens (like a unit dying for example).
Also, I need to know where to find a glossary of Jass commands and a good program for writing Jass.

Please be patient with my lack of Jass knowledge, and TY in advance for the help.

 

[UndeadDragon]

Also, I need to know where to find a glossary of Jass commands and a good program for writing Jass.

Use Jass NewGen. It also has a function list, so you can easily find any functions that you can't remember.

Sorry, I'm too tired to help with the rest

 

[Komaqtion]

Well, 2 and 3, JASS Newgen is a really great "extension" to the normal World Editor.
Implemented in that tool, is a program called TESH, which has a collection of almost all functions and natives.
JASSCraft is also a really great tool for JASS writing, and it has an even better function/native collection

JASS Newgen can be found here:
http://www.wc3c.net/showthread.php?t=90999

And JASSCraft here:
http://www.wc3c.net/showthread.php?t=80051&highlight=Jasscraft

 

[Idontknowyou]

thanks for the help... can anyone help me with the events though?

 

[GooS]

To make a function into an event I guess, since I'm not a genius JASSer it requires a trigger, so make a function, within it create a local trigger, then add an event to the trigger and action upon the event, you got yourself something to fire off another function upon an event.

To go through it:

Create a function with a local trigger and create it.

function Init takes nothing returns nothing
        local trigger KillUnitTrig = CreateTrigger()
endfunction

Make it trigger upon an event, the following triggering upon the event of a unit casting a spell.

function Init takes nothing returns nothing
        local trigger KillUnitTrig = CreateTrigger()
        local integer index
        set index = 0
        loop
            call TriggerRegisterPlayerUnitEvent(KillUnitTrig, Player(index), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            set index = index + 1
            exitwhen index == bj_MAX_PLAYER_SLOTS
        endloop
endfunction

But I don't want it to trigger upon any spell so I have to add a condition
And as you know any calls to another function and the called function must be placed before the function calling it, so an event function will always be placed at the bottom of a trigger.

function KillUnitTrigConditions takes nothing returns boolean
        return GetSpellAbilityId() == 'AHtb'
    endfunction

function Init takes nothing returns nothing
        local trigger KillUnitTrig = CreateTrigger()
        local integer index
        set index = 0
        loop
            call TriggerRegisterPlayerUnitEvent(KillUnitTrig, Player(index), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            set index = index + 1
            exitwhen index == bj_MAX_PLAYER_SLOTS
        endloop
        call TriggerAddCondition( KillUnitTrig, Condition( function KillUnitTrigConditions ) ) // <----!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
endfunction

There we go, now it calls a condition, making it only run the actions of the trigger when the condition returns true, which it will when the spell cast is Storm Bolt.

So what to do when a Storm Bolt is cast, it has to have an action, which we also need to add to the trigger, here we go:

function KillUnitTrigConditions takes nothing returns boolean
        return GetSpellAbilityId() == 'AHtb'
endfunction

function KillUnitTrigActions takes nothing returns nothing
        call KillUnit(GetSpellTargetUnit())
endfunction

function StormboltKill takes nothing returns nothing
        local trigger KillUnitTrig = CreateTrigger()
        local integer index
        set index = 0
        loop
            call TriggerRegisterPlayerUnitEvent(KillUnitTrig, Player(index), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
            set index = index + 1
            exitwhen index == bj_MAX_PLAYER_SLOTS
        endloop
        call TriggerAddCondition( KillUnitTrig, Condition( function KillUnitTrigConditions ) )
        call TriggerAddAction( KillUnitTrig, function KillUnitTrigActions )// <---------!!!!!!!!!!!!!!!!!!!!!!!!!!!
endfunction

And there we have it, you have made a function fire off when at the generic event of a spellcast.

There are a great amount of events

EVENT_PLAYER_UNIT_SELL
EVENT_PLAYER_UNIT_SUMMON
EVENT_PLAYER_VICTORY
EVENT_UNIT_DESLECTED
EVENT_UNIT_LOADED
EVENT_DIALOG_CLICK

To name a few, and many more to be seen in the function list of NewGen if you select search for constants.

Don't know if this is what you want, but this is what I thought you wanted by your post.

//==GooS

 

[Tyrulan]

Here is something a little simpler to understand...

function UnitDies_Actions takes nothing returns nothing
    local unit myUnit = GetDyingUnit()
    call DisplayTextToForce(GetPlayersAll(), "The " + GetUnitName(myUnit)  + " is now dead!"
endfunction

//===========================================================================
function InitTrig_UnitDies takes nothing returns nothing
    set trigger UnitDies = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ (UnitDies, EVENT_PLAYER_UNIT_DEATH)
    call TriggerAddAction( UnitDies, function UnitDies_Actions )
endfunction

Figured I'd follow a little more typical format.

 

[Idontknowyou]

thanks very much, that helped alot plus rep to both of you!