Trying to disable unit orders in a region - Trigger doesn't work

[AlicanC]

I have a triger called "Hero Select Orders". It's a part of my double-click-hero-selection system. It has to disable all orders issued to that unit. (I remove 'Aatk' and 'Amov', but they still can use abilities.)
I made this trigger, but when I enable this all triggers gets disabled somehow.

function Trig_Hero_Select_Orders_Actions takes nothing returns nothing
    //Locals
    local unit triggerUnit= GetTriggerUnit()
    
    //Pause, order to stop and resume unit
    call PauseUnit(triggerUnit, true)
    call IssueImmediateOrder(triggerUnit, "stop")
    call PauseUnit(triggerUnit, false)
    
    //Nullify
    set triggerUnit= null
endfunction

//===========================================================================
function InitTrig_Hero_Select_Orders takes nothing returns nothing
    //Locals
    local group heroes= CreateGroup()
    local unit current
    
    //Create trigger
    set gg_trg_Hero_Select_Orders= CreateTrigger()
    //Get units in Hero Selection
    call GroupEnumUnitsInRect(heroes, gg_rct_Hero_Selection, null)
    //Register events
    loop
        set current= FirstOfGroup(heroes)
        exitwhen current==null
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_TARGET_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_ORDER)
    endloop
    //Add actions
    call TriggerAddAction(gg_trg_Hero_Select_Orders, function Trig_Hero_Select_Orders_Actions)
    
    //Nullify
    call DestroyGroup(heroes)
    set heroes= null
endfunction

Where is the problem?

 

[phyrex1an]

    loop
        set current= FirstOfGroup(heroes)
        exitwhen current==null
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_TARGET_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_ORDER)
    endloop

Should be

    loop
        set current= FirstOfGroup(heroes)
        exitwhen current==null
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_TARGET_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_ORDER)
        call GroupRemoveUnit(heroes, current)
    endloop

Your code results in an infinite loop that halts the execution of that thread. Since all triggers are created in the same thread every trigger that is uninitialized when InitTrig_Hero_Select_Orders runs will continue to be uninitialized.

I almost forgot to add the usual ForGroup rant I have when answering questions related to FirstOfGroup loop:
[rant]Rant about how ForGroup solves all problems known to man[/rant]

 

[AlicanC]

Thanks for your help.
--
I am using enumerators in C++ and "foreach" loops in PHP. I feel like I am doing something wrong when I use a seperate function. Also I don't want to use globals to pass information.

Edit:
It doesn't work. Other triggers work fine, but WC3 disappears after 6-7 seconds when I enable this:

function Trig_Hero_Select_Orders_Actions takes nothing returns nothing
    //Locals
    local unit triggerUnit= GetTriggerUnit()
    
    //Pause, order to stop and resume unit
    call PauseUnit(triggerUnit, true)
    call IssueImmediateOrder(triggerUnit, "stop")
    call PauseUnit(triggerUnit, false)
    
    //Nullify
    set triggerUnit= null
endfunction

//===========================================================================
function InitTrig_Hero_Select_Orders takes nothing returns nothing
    //Locals
    local group heroes= CreateGroup()
    local unit current
    
    //Create trigger
    set gg_trg_Hero_Select_Orders= CreateTrigger()
    //Get units in Hero Selection
    call GroupEnumUnitsInRect(heroes, gg_rct_Hero_Selection, null)
    //Register events
    loop
        set current= FirstOfGroup(heroes)
        exitwhen current==null
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_TARGET_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_ORDER)
        call GroupRemoveUnit(heroes, current)
    endloop
    //Add actions
    call TriggerAddAction(gg_trg_Hero_Select_Orders, function Trig_Hero_Select_Orders_Actions)
    
    //Nullify
    call DestroyGroup(heroes)
    set heroes= null
endfunction

Edit 2:
My game starts after host types "-start". When I quickly type "-start" and select a hero before that 6-7 seconds, WC3 disappears again. The problem is I don't have any trigger that runs after 6-7 seconds. Actually nothing happens before the host types "-start".

Edit 3:
I added this condition and solved my problem:

function Trig_Hero_Select_Orders_Conditions takes nothing returns boolean
    if GetIssuedOrderId()==OrderId("stop") then
        return false
    else
        return true
    endif
endfunction

Now heroes can't use abilities, but some abilites make heroes lose mana and shows casting animation.

 

[phyrex1an]

I have no idea why it crashes after 6-7 seconds but the second crash is because you yet again get an infinite loop.

In the trigger, that fires when a hero is issued an order, you order the hero to stop and thus the trigger fires again, and again, and ...

Use DisableTrigger and EnableTrigger before and after you issue the order.

 

[AlicanC]

Yes I solved that problem. Now heroes can't use abilities, but some abilites make heroes lose mana and shows casting animation. (Bladestorm, Divine Shield, ...)

Edit:
This is the trigger:

function Trig_Hero_Select_Orders_Conditions takes nothing returns boolean
    if GetIssuedOrderId()==OrderId("stop") then
        return false
    else
        return true
    endif
endfunction

function Trig_Hero_Select_Orders_Actions takes nothing returns nothing
    //Locals
    local unit triggerUnit= GetTriggerUnit()
    
    //Pause, order to stop and resume unit
    call PauseUnit(triggerUnit, true)
    call IssueImmediateOrder(triggerUnit, "stop")
    call PauseUnit(triggerUnit, false)
    
    //Set mana to 100%
    call SetUnitState(triggerUnit, UNIT_STATE_MANA, GetUnitState(triggerUnit, UNIT_STATE_MAX_MANA))
    
    //Nullify
    set triggerUnit= null
endfunction

//===========================================================================
function InitTrig_Hero_Select_Orders takes nothing returns nothing
    //Locals
    local group heroes= CreateGroup()
    local unit current
    
    //Create trigger
    set gg_trg_Hero_Select_Orders= CreateTrigger()
    //Get units in Hero Selection
    call GroupEnumUnitsInRect(heroes, gg_rct_Hero_Selection, null)
    //Register events
    loop
        set current= FirstOfGroup(heroes)
        exitwhen current==null
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_TARGET_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_POINT_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_ISSUED_ORDER)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_SPELL_CAST)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_SPELL_CHANNEL)
        call TriggerRegisterUnitEvent(gg_trg_Hero_Select_Orders, current, EVENT_UNIT_HERO_SKILL)
        call GroupRemoveUnit(heroes, current)
    endloop
    //Add conditions
    call TriggerAddCondition(gg_trg_Hero_Select_Orders, Condition(function Trig_Hero_Select_Orders_Conditions))
    //Add actions
    call TriggerAddAction(gg_trg_Hero_Select_Orders, function Trig_Hero_Select_Orders_Actions)
    
    //Nullify
    call DestroyGroup(heroes)
    set heroes= null
endfunction