Weird execution problem

[Darius34]

I'm having this really weird problem with a trigger. I've debugged extensively and yet I can't find a solution.

For some reason, the execution of a particular bit of code in that trigger stops at one point. Stops, just like that. I'm using a local trigger with a periodic event, and after that aforementioned point, it runs normally.

A simple example to illustrate the circumstances:

local trigger t = GetTriggeringTrigger()
local unit UnitA = (something)
local unit UnitB

call Function1()
call Damage(UnitA)
loop
  exitwhen (some conditions)
  If (some conditions) then // Block 1
    set UnitB = (something)
  endif
endloop
set UnitA = UnitB // Line in question
if UnitA == null then
  call DestroyTrigger(t)
endif

My spell works by damaging a fixed number of unique units one after another, and the part labelled Block 1 has some priority conditions for picking targets. If there are insufficient targets in the AoE, UnitB and UnitA both are set to null.

If, for instance, there are 3 targets and the spell targets on 5, UnitA and UnitB would be nulled after the third time the trigger runs, since UnitA and UnitB cannot be damaged again. That's where the problem is: at "Line in question", the execution stops. Everything after that line is bypassed, but yet the trigger runs normally after that and continuously damages UnitA. No new target is picked.

I'll clarify if you don't understand the problem. It seems to have something to do with UnitA and UnitB being null at that point. I've added all sorts of code before and after the line in question, and concluded that execution just stops there.

I remember this happening with the functions SetUnitX() and SetUnitY(), some time back. To correct the problem then, I replaced both with SetUnitPosition(); I've yet to find out why the latter worked.

I've spent a few days cracking my head over this and am incredibly frustrated. Any help at all would be appreciated.

 

[~GaLs~]

Add a TriggerSleepAction(0.1) inside your loop. Your loop is hitting OP.

 

[Darius34]

Add a TriggerSleepAction(0.1) inside your loop. Your loop is hitting OP.

OP? What's OP? And how would the wait help? It'd cause visible delay I don't want, in this case; my spell moves a projectile like that of Moon Glaive.

 

[AceHart]

Operation limit.
You're loop will not run forever.
Sooner or later, the game will just stop it... around 12000+ (or somewhat more, don't remember) actions.

Adding a wait will reset that limit.

 

[Darius34]

Operation limit.
You're loop will not run forever.
Sooner or later, the game will just stop it... around 12000+ (or somewhat more, don't remember) actions.

Adding a wait will reset that limit.

Hmm. I added the wait (tried various values, from 0 to 0.1) and didn't seem to have any effect; the spell still doesn't work. My code can't possibly be executing over 200 times, even. Could this problem still be caused exclusively by this operation limit?

 

[Terrabull]

Can we see the full trigger? Maybe it's something you didn't think of w/ conditions, or actions that were mistaken. With that bit of psuedo code we can't tell those.

 

[Darius34]

Okay, here's the part where there are problems. The rest of it isn't too relevant, so I omitted it. Suffice to say that upon damage being detected by a damage event attached to a trigger with an attack event, the function MoonGlaiveHitActions() executes, and that in turn calls MoonGlaiveMovement() periodically to move the glaive.

function MoonGlaiveMovement takes nothing returns nothing
    local trigger movementtrig = GetTriggeringTrigger()
    local unit source = GetHandleUnit(movementtrig, "source")
    local unit dummy = GetHandleUnit(movementtrig, "dummy")
    local real damage = GetHandleReal(movementtrig, "damage") * .35
    local integer bouncesleft = GetHandleInt(movementtrig, "bouncesleft")
    local unit nexttarget = GetHandleUnit(movementtrig, "nexttarget")
    local group alreadyhit = GetHandleGroup(movementtrig, "alreadyhit")
    local group targets = CreateGroup()
    local group temptargets = CreateGroup()
    local unit picked
    local unit temppicked
    local real prevdist = 99999.
    local real dist
    local real dx = GetUnitX(nexttarget) - GetUnitX(dummy)
    local real dy = GetUnitY(nexttarget) - GetUnitY(dummy)
    local real angle = Atan2(dy, dx)
    local real x = GetUnitX(dummy) + 18 * Cos(angle)
    local real y = GetUnitY(dummy) + 18 * Sin(angle)

    if SquareRoot(dx * dx + dy * dy) > 18. then
        call SetUnitPosition(dummy, x, y)
    else
        call UnitDamageTarget(source, nexttarget, damage, true, true, ATTACK_TYPE_HERO, DAMAGE_TYPE_NORMAL, WEAPON_TYPE_WHOKNOWS)
        call GroupEnumUnitsInRange(targets, GetUnitX(nexttarget), GetUnitY(nexttarget), 500., Condition(function MoonGlaiveBounceTargetConditions))

        call GroupAddGroup(targets, temptargets)
        loop
            set picked = FirstOfGroup(temptargets)
            exitwhen picked == null
            set dx = GetUnitX(picked) - GetUnitX(nexttarget)
            set dy = GetUnitY(picked) - GetUnitY(nexttarget)
            set dist = SquareRoot(dx * dx + dy * dy)

            if dist < prevdist then
                set prevdist = dist
                set temppicked = picked
            endif
            call GroupRemoveUnit(temptargets, picked)
            call TriggerSleepAction(.1)
        endloop
        set nexttarget = temppicked // The line in question
        set bouncesleft = bouncesleft - 1

        if bouncesleft < 1 or CountUnitsInGroup(targets) < 1 or nexttarget == null then
            call DisableTrigger(movementtrig)
            call KillUnit(dummy)
            call DestroyGroup(alreadyhit)
            call FlushHandleLocals(movementtrig)
            call DestroyTrigger(movementtrig)
        else        
            call GroupAddUnit(alreadyhit, nexttarget)
            call SetHandleReal(movementtrig, "damage", damage)
            call SetHandleInt(movementtrig, "bouncesleft", bouncesleft)
            call SetHandleHandle(movementtrig, "nexttarget", nexttarget)
        endif
    endif
    set movementtrig = null
    set source = null
    set dummy = null
    set nexttarget = null
    set picked = null
    set temppicked = null
    set alreadyhit = null
    call DestroyGroup(targets)
    set targets = null
    call DestroyGroup(temptargets)
    set temptargets = null
endfunction

function MoonGlaiveHitActions takes nothing returns nothing
    local trigger t = GetTriggeringTrigger()
    local unit target
    local unit source = GetEventDamageSource()
    local trigger movementtrig
    local unit dummy
    local group alreadyhit
    local group targets
    local unit nexttarget

    if GetTriggerEventId() != EVENT_UNIT_DAMAGED then
        call DisableTrigger(t)
        call FlushHandleLocals(t)
        call DestroyTrigger(t)
    elseif GetTriggerEventId() == EVENT_UNIT_DAMAGED and source == GetHandleUnit(t, "source") then
        call DisableTrigger(t)
        call FlushHandleLocals(t)
        call DestroyTrigger(t)

        set target = GetTriggerUnit()
        set movementtrig = CreateTrigger()
        set dummy = CreateUnit(GetOwningPlayer(source), 'e000', GetUnitX(target), GetUnitY(target), 0.)
        set targets = CreateGroup()
        set alreadyhit = CreateGroup()
        
        call GroupAddUnit(alreadyhit, target)
        call GroupEnumUnitsInRange(targets, GetUnitX(target), GetUnitY(target), 500., Condition(function MoonGlaiveTargetConditions))
        set nexttarget = GroupPickClosestUnit(targets, GetUnitX(target), GetUnitY(target))
        call SetHandleHandle(movementtrig, "nexttarget", nexttarget)
        call GroupAddUnit(alreadyhit, nexttarget)
        
        call SetHandleHandle(movementtrig, "alreadyhit", alreadyhit)
        call SetHandleHandle(movementtrig, "dummy", dummy)
        call SetHandleHandle(movementtrig, "source", source)
        call SetHandleInt(movementtrig, "bouncesleft", GetUnitAbilityLevel(source, MoonGlaiveId()))
        call SetHandleReal(movementtrig, "damage", GetEventDamage())
        call TriggerRegisterTimerEvent(movementtrig, 0.02, true)
        call TriggerAddAction(movementtrig, function MoonGlaiveMovement)        
        
        set target = null
        set movementtrig = null
        set dummy = null
        call DestroyGroup(targets)
        set targets = null
        set alreadyhit = null
    endif

    set t = null
    set source = null
endfunction

Haven't gotten round to learning about structs, so I'm still using old-school methods. Point out any bugs if you see any, please; that would be appreciated too.

 

[Darius34]

Bump. Apologies, but I still haven't managed to figure anything out.

 

[phyrex1an]

temppicked have a chance to being uninitialized at that line, and then it will end the thread at that line. Better set temppicked to null at the declaration.

 

[Darius34]

Oh, wow, I never would have thought of that. It worked like a charm. Thanks a lot, phyrex1an.