What would I need to make a successfull damage over time function?

[shiFt]

Which systems would I need to make a Damage over time function, Im currently using Damage and T32 as my timer system and interval.

How can I make this MUI and MPI and so on, so that there are no glitches in multiplayer with multiple units being dealt damage over time with different amounts and durations?

As far as ive gotten

library DamOT requires T32, Damage
    
    private struct DamOT
    
    private static thistype data = 0
        unit Damager2
        widget Target2
        real Damage2
        attacktype AttackType2
        damagetype DamageType2
        effect Effect2
        integer tick2
        real Time2
        
        static method periodic takes nothing returns nothing
                local thistype this = thistype.data
                if tick2 >= T32_Tick then  
                    call DestroyEffect(Effect2)
                    call UnitDamageTargetEx(Damager2, Target2, Damage2, false, false, AttackType2, DamageType2, null)
                
                    if tick2 == T32_Tick or GetWidgetLife(Target2) < .405   then
                        call .stopPeriodic()
                        call DestroyEffect(Effect2)
                        call this.destroy()
                    endif
                endif
        endmethod
        
        implement T32x
     
        static method start takes unit Damager, widget Target, real Damage, real Time, attacktype AttackType, damagetype DamageType, string Effect, string EffectAttach returns nothing
                local thistype this = thistype.allocate()
                set Damager2    = Damager
                set Target2   = Target
                set AttackType2 = AttackType
                set DamageType2 = DamageType
                set Effect2     = AddSpecialEffectTarget(Effect, Target, EffectAttach)
                set Time2       = Time
                set Damage2     = Damage  * T32_PERIOD
                set tick2       = T32_Tick +  R2I(Time / T32_PERIOD)
                set thistype.data = this
                call .startPeriodic()
        endmethod
    
        method onDestroy takes nothing returns nothing
            set Damager2 = null
            set Target2 = null
            call DestroyEffect(Effect2)
        endmethod
    endstruct
        function DamageOT takes unit Damager, widget Target, real Damage, real Time, attacktype AttackType, damagetype DamageType, string Effect, string EffectAttach returns nothing
            call DamOT.start(Damager, Target, Damage, Time, AttackType, DamageType, Effect, EffectAttach)
        endfunction
endlibrary

 

[shiFt]

bump

 

[shiFt]

Basically what I need to know is, is this function MUI or will it bug in multiplayer if yes then what do I do to make it MUI?

 

[Solmyr]

Your function currently isn't MUI, but it will be if done properly. The way it is, I don't think it would even compile.

The [ljass]periodic[/ljass] method that is called by T32 isn't a static method, but a normal one, which means that it takes [ljass]this[/ljass] implicitly, so you won't need the [ljass]static thistype data[/ljass] member (and that member is what takes away the MUI-ness from your function).

Try this:

library DamOT requires T32, Damage
    
    private struct DamOT

        private unit Damager2
        private widget Target2
        private real Damage2
        private attacktype AttackType2
        private damagetype DamageType2
        private effect Effect2
        private integer tick2
        private real Time2

        private method onDestroy takes nothing returns nothing
            set Damager2 = null
            set Target2 = null
            call DestroyEffect(Effect2)
        endmethod
        
        method periodic takes nothing returns nothing
            if .tick2 >= T32_Tick then  
                call UnitDamageTargetEx(.Damager2, .Target2, .Damage2, false, false, .AttackType2, .DamageType2, null)
                
                if .tick2 == T32_Tick or GetWidgetLife(.Target2) < .405 then
                    call .stopPeriodic()
                    call .destroy()
                endif
            endif
        endmethod
        
        implement T32x
     
        static method start takes unit Damager, widget Target, real Damage, real Time, attacktype AttackType, damagetype DamageType, string Effect, string EffectAttach returns nothing
            local thistype this = thistype.allocate()
            set .Damager2    = Damager
            set .Target2     = Target
            set .AttackType2 = AttackType
            set .DamageType2 = DamageType
            set .Effect2     = AddSpecialEffectTarget(Effect, Target, EffectAttach)
            set .Time2       = Time
            set .Damage2     = Damage  * T32_PERIOD
            set .tick2       = T32_Tick +  R2I(Time / T32_PERIOD)
            call .startPeriodic()
        endmethod
    endstruct
    
    function DamageOT takes unit Damager, widget Target, real Damage, real Time, attacktype AttackType, damagetype DamageType, string Effect, string EffectAttach returns nothing
        call DamOT.start(Damager, Target, Damage, Time, AttackType, DamageType, Effect, EffectAttach)
    endfunction

endlibrary

However, to be honest, when coding such stuff, I prefer to use xedamage because it allows me to specify everything within the xedamage object (from attack/damage types to special effects) and instead of passing a shitload of arguments, I simply pass the xedamage object.

But since you're using Damage, that's pretty much the only way...

 

[shiFt]

Is the

thistype.data = this

supposed to be

.thistype.data = this

? It isnt compiling on this line??

 

[Solmyr]

It isnt compiling on this line??

Oh, silly me, that's not even supposed to be there. I even said it my post that you don't need that member, but yeah.

I edited my previous post accordingly.