Octagonal Area

[Joker(Div)]

How would you check if someone entered an octagonal area? I'm trying to avoid a high-frequency terrain check.

 

[kingkingyyk3]

I found Vexorian made "GroupEnumUnitInPolygon", try to find it. I think u may put 0.5 seconds checkup.

 

[Builder Bob]

Just create a function that outputs a region with an octagonal shape.

function CreateOctagonalRegion takes real centerX, real centerY, real radius returns region

RegionAddCell() will add 32x32 cells to the region. Some math is required here. Will you be alright?

Use this region with TriggerRegisterEnterRegion()

 

[Joker(Div)]

I don't know the math. If you could show me...

 

[Jimpy]

I'm unsure of the script, however you could run a check if a unit is within X-range of a hidden dummy unit, making yourself a circular area check.

 

[Builder Bob]

I did some research in an attempt to make a universal function for any regular polygon you could want added to a region. This is what I came up with. It does leave some spots open unfortunately.

As a workaround, you can reduce CELL to 16 to remove all spots. This will make the function half as fast though.

RegionAddPolygon:

library RegionFunctions

globals
	private constant real CELL = 32.
	private constant real HALF_CELL = 16.
endglobals

private function RegionAddGon takes region whichRegion, real x1, real y1, real apothem, real angle, real side returns nothing
	local real length = HALF_CELL
	local real width
	local real offset
	local real dx = Cos(angle)
	local real dy = Sin(angle)
	local real x
	local real y
	loop
		set width = side * length / apothem
		set offset = -.5 * width + HALF_CELL
		loop
			set x = x1 + length * dx - offset * dy
			set y = y1 + length * dy + offset * dx
			call RegionAddCell(whichRegion, x, y)
			exitwhen(offset >= .5 * width)
			set offset = offset + CELL
		endloop
		exitwhen(length >= apothem)
		set length = length + CELL
	endloop
endfunction

function RegionAddPolygon takes region whichRegion, real x, real y, real radius, integer polygons, real angle returns nothing
	local real apothem = radius * Cos(bj_PI / polygons)
	local real side = 2. * radius * Sin(bj_PI / polygons)
	local real arc = 2. * bj_PI / polygons
	loop
		exitwhen(polygons <= 0)
		call RegionAddGon(whichRegion, x, y, apothem, angle + arc / 2., side)
		set angle = angle + arc
		set polygons = polygons - 1
	endloop
endfunction

endlibrary

If anyone have any suggestions for improvement, I'd very much like your input.