Basic code problems...

[darth-yoda]

Im trying to make a pretty simple ability, all it is basically supposed to do is create a line of dummy units and have them cast a modified warstomp. The dummy units are made but nothing after that works, the ability is never added and the units never die...Here is the code...

constant function Geysers_id takes nothing returns integer
    return 'A002'
endfunction

constant function Geysers_dummyspell takes nothing returns integer
    return 'A003'
endfunction

constant function Geysers_dummy takes nothing returns integer
    return 'h000'
endfunction
    
constant function Geysers_height takes nothing returns real
    return 38.50
endfunction

function Geysers_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A002'
endfunction

function Geysers_water takes location cast returns boolean
    return GetLocationZ(cast) < Geysers_height()
endfunction

function Geysers_hp takes unit caster returns boolean
    return GetUnitState(caster,UNIT_STATE_LIFE) > GetUnitAbilityLevel(caster,Geysers_id()) * 10
endfunction

function Geysers_Actions takes nothing returns nothing
    local unit caster = GetTriggerUnit()
    local unit dummy
    local location cast = GetUnitLoc(caster)
    local location targ
    local integer a = 1
    local integer b = 5
    if ( Geysers_water(cast)) then
        loop
        exitwhen a > b
        set targ = PolarProjectionBJ(cast, 150.00, GetUnitFacing(caster))
        set cast = targ
        call CreateUnitAtLoc(GetOwningPlayer(caster),Geysers_dummy(),targ,90)
        set dummy = GetLastCreatedUnit()
        call UnitApplyTimedLife(dummy,'BTLF',1.00)
        call UnitAddAbility(dummy,Geysers_dummyspell())
        call SetUnitAbilityLevel(dummy,Geysers_dummyspell (),GetUnitAbilityLevel(caster,Geysers_id()))
        call IssueImmediateOrder(dummy,"stomp")
        set a = a + 1
        call PolledWait(0.20)
        endloop
    else
        loop
        exitwhen a > b
        if (Geysers_hp(caster)) then
            call UnitDamageTarget(caster,caster,GetUnitAbilityLevel(caster,Geysers_id()) * 10,true,false,ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNIVERSAL, WEAPON_TYPE_WHOKNOWS)
            set targ = PolarProjectionBJ(cast, 150.00, GetUnitFacing(caster))
            set cast = targ
            call CreateUnitAtLoc(GetOwningPlayer(caster),Geysers_dummy(),targ,90)
            set dummy = GetLastCreatedUnit()
            call UnitApplyTimedLife(dummy,'BTLF',1.00)
            call UnitAddAbility(dummy,Geysers_dummyspell())
            call SetUnitAbilityLevel(dummy,Geysers_dummyspell(),GetUnitAbilityLevel(caster,Geysers_id()))
            call IssueImmediateOrder(dummy,"stomp")
            set a = a + 1
            call PolledWait(0.20)
        else
        set a = a + 1
        endif
        endloop
    endif
endfunction

//===========================================================================
function InitTrig_Geysers takes nothing returns nothing
    set gg_trg_Geysers = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Geysers, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( gg_trg_Geysers, function Geysers_Actions )
    call TriggerAddCondition( gg_trg_Geysers, Condition( function Geysers_Conditions ) )
endfunction

As far as I can tell the dummy unit is never being assigned to the variable and I dont know why.:banghead:

 

[substance]

            call CreateUnitAtLoc(GetOwningPlayer(caster),Geysers_dummy(),targ,90)
            set dummy = GetLastCreatedUnit()

can be

set dummy = CreateUnitAtLoc(GetOwningPlayer(caster),Geysers_dummy(),targ,90)

Just glancing over i dont see what the problem is, but there are a ton of other things you can fix:

You have a few BJ's you can get rid of, as well as using coordinates instead of locations. You have leaks etc. You can use globals instead of constant function calls.

I would make sure you dummy unit has mana, make sure he has enough time to cast and make sure his ability level isnt being set to 0. I've never used IssueImmidiateOrder on a dumym unit so that may be your problem.

Use debug messages to find out exatly what's happening. You can also give your dummy unit a model temporarly to make sure he's being created and is attemping to cast.

 

[TheDamien]

GetLastCreatedUnit() doesn't work when you are creating the unit using a native.

function GetLastCreatedUnit takes nothing returns unit
    return bj_lastCreatedUnit
endfunction

 

[darth-yoda]

well you fixed it All I did was change to this...

set dummy = CreateUnitAtLoc(GetOwningPlayer(caster),Geysers_dummy(),targ,90)

And now it works perfectly. Im still really confused as to why it wasnt working for me, but w/e, it works now and thats all that matters.
Also I know it leaks. I just like to have a spell actually working before I worrie about those. And the constant function are just for easy editing, I dont actually need them at all.

Thanks for you help +rep

Diddnt see TheDamiens post. Thanks for the info.