Locals Per Function

[Prometheus]

Do locals work per function or per trigger?

 

[SFilip]

per function.

 

[Prometheus]

function Trig_Increase_Damage_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A004' ) ) then
        return false
    endif
    return true
endfunction

function Trig_Increase_Damage_Func002C takes nothing returns boolean
    if ( not ( IsUnitType(udg_increaseDamageU, UNIT_TYPE_HERO) == true ) ) then
        return false
    endif
    return true
endfunction

function Trig_Increase_Damage_Actions takes nothing returns nothing
    local unit DU
    set DU = GetSpellTargetUnit()
    if ( Trig_Increase_Damage_Func002C() ) then
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_ADD, 3 )
        call TriggerSleepAction( 60.00 )
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_SUB, 3 )
    else
        call SetUnitExplodedBJ( DU, true )
    endif
endfunction

//===========================================================================
function InitTrig_Increase_Damage takes nothing returns nothing
    set gg_trg_Increase_Damage = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Increase_Damage, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Increase_Damage, Condition( function Trig_Increase_Damage_Conditions ) )
    call TriggerAddAction( gg_trg_Increase_Damage, function Trig_Increase_Damage_Actions )
endfunction

Do I need to use a global to get this to work right? It was GUI with globals but then I wanted to convert it to JASS and use locals.

 

[SFilip]

one of the main advantages of jass is the possibility of cleaning stuff like this.

    if ( Trig_Increase_Damage_Func002C() ) then

change it intro

    if ( ( IsUnitType(DU, UNIT_TYPE_HERO) == true ) then

and there you have it. now you can remove Trig_Increase_Damage_Func002C since you are not using it anymore.

you can simplify this too:

function Trig_Increase_Damage_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A004' ) ) then
        return false
    endif
    return true
endfunction

intro

function Trig_Increase_Damage_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A004'
endfunction

dont forget the remove the local handle leak in the end.

    set DU = null

 

[Prometheus]

This look right?

function Trig_Increase_Damage_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A004'
endfunction


function Trig_Increase_Damage_Actions takes nothing returns nothing
    local unit DU
    set DU = GetSpellTargetUnit()
    if ( ( IsUnitType(DU, UNIT_TYPE_HERO) == true ) then
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_ADD, 3 )
        call TriggerSleepAction( 60.00 )
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_SUB, 3 )
        set DU = null
    else
        call SetUnitExplodedBJ( DU, true )
        set DU = null
    endif
endfunction

//===========================================================================
function InitTrig_Increase_Damage takes nothing returns nothing
    set gg_trg_Increase_Damage = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Increase_Damage, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Increase_Damage, Condition( function Trig_Increase_Damage_Conditions ) )
    call TriggerAddAction( gg_trg_Increase_Damage, function Trig_Increase_Damage_Actions )
endfunction

 

[SFilip]

yeah
though you could move that nulling action to save space...and set it in the same line where you defined

function Trig_Increase_Damage_Actions takes nothing returns nothing
    [B]local unit DU = GetSpellTargetUnit()[/B]
    if ( ( IsUnitType(DU, UNIT_TYPE_HERO) == true ) then
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_ADD, 3 )
        call TriggerSleepAction( 60.00 )
        call ModifyHeroStat( bj_HEROSTAT_STR, DU, bj_MODIFYMETHOD_SUB, 3 )
    else
        call SetUnitExplodedBJ( DU, true )
    endif
    [B]set DU = null[/B]
endfunction

 

[Prometheus]

This line gives me an error

    if ( ( IsUnitType(DU, UNIT_TYPE_HERO) == true ) then

 

[SFilip]

my bad, has an extra (

    if ( IsUnitType(DU, UNIT_TYPE_HERO) == true ) then

 

[Prometheus]

Thanks!