Manual of Mana?

[C0mput3r]

I've got a way to make a unit's max HP based on this formula.

{[(Strength of unit + Level of unit) / 10] + base life}

the trigger is like this:

HP Bonus LevelUP
    Events
        Unit - A unit Gains a level
    Conditions
        LevelUPskip[(Player number of (Triggering player))] Equal to False
    Actions
        Unit - Set life of (Triggering unit) to 100.00%
        Unit - Set mana of (Triggering unit) to 100.00%
        Set LevelUPIntConversion[(Player number of (Owner of (Triggering unit)))] = (Real((((Hero level of (Triggering unit)) + (Strength of Player_Heros[(Player number of (Owner of (Triggering unit)))] (Include bonuses))) / 10)))
        Set LevelUPInt[(Player number of (Owner of (Triggering unit)))] = (Integer(LevelUPIntConversion[(Player number of (Owner of (Triggering unit)))]))
        Hero - Drop the item from slot 1 of Player_Heros[(Player number of (Owner of (Triggering unit)))]
        Set TempItem[(Player number of (Owner of (Triggering unit)))] = (Last dropped item)
        For each (Integer A) from 1 to LevelUPInt[(Player number of (Owner of (Triggering unit)))], do (Actions)
            Loop - Actions
                Hero - Create HP Bonus and give it to (Triggering unit)
                Hero - Order Player_Heros[(Player number of (Owner of (Triggering unit)))] to use (Last created item)
        Hero - Give TempItem[(Player number of (Owner of (Triggering unit)))] to (Triggering unit)
        Set TempItem[(Player number of (Owner of (Triggering unit)))] = No item
        Set LevelUPInt[(Player number of (Owner of (Triggering unit)))] = 0
        Set LevelUPIntConversion[(Player number of (Owner of (Triggering unit)))] = 0.00

Now to get to the point. (I bet you're gonna kill me for giving other info 1st but I assure you it'll help you understand what i'm trying to do)

I used a Manual of Life that adds 1 life and a Loop-Actions to add it mutiple times. There's no ability for it and it doesn't take up inv space.

Now for the question. (I know, so long... i mean finally!!!)
Is there a Permenant Max Mana Increase?

Thanks in advance for helping, but most importantly for reading the whole thing, it IS very long...

 

[Ghan]

Not really....
There is a passive ability that increases maximum mana, but it doesn't work exactly the same way.

 

[FhelZone]

use a skill + mana any would do as long as it is a permanent mana bonus and for the item set it up like a power up. I'm not really sure of this but I do adding stats in triggers.

 

[AceHart]

You may want to have a look at post #9 here:
http://www.thehelper.net/forums/showthread.php?t=31327

 

[Pyrogasm]

If wc3campaigns.net was up I could link you to the resource, but I would suggest this simple script by Blade.dk

//**************************************************************************
//                        SetUnitMaxState System                           *
//**************************************************************************
constant function MaxStateModifierId takes unitstate u returns integer
    if u == UNIT_STATE_MAX_LIFE then
        return 'A000' // Rawcode of the Max Life Modifier ability.
    elseif u == UNIT_STATE_MAX_MANA then
        return 'A001' // Rawcode of the Max Mana Modifier ability.
    endif
    return 0
endfunction

function SetUnitMaxState takes unit whichUnit, unitstate whichUnitState, integer newVal returns boolean
    local integer c = newVal-R2I(GetUnitState(whichUnit, whichUnitState))
    local integer i = MaxStateModifierId(whichUnitState)
    if i == 0 then
        return false
    endif
    if c > 0 then
        loop
            exitwhen c == 0
            call UnitAddAbility(whichUnit, i)
            if c >= 100 then
                set c = c - 100
                call SetUnitAbilityLevel(whichUnit, i, 4)
            elseif c >= 10 then
                set c = c - 10
                call SetUnitAbilityLevel(whichUnit, i, 3)
            else
                set c = c - 1
                call SetUnitAbilityLevel(whichUnit, i, 2)
            endif
            call UnitRemoveAbility(whichUnit, i)
        endloop
    elseif c < 0 then
        set c = -c
        loop
            exitwhen c == 0
            call UnitAddAbility(whichUnit, i)
            if c >= 100 then
                set c = c - 100
                call SetUnitAbilityLevel(whichUnit, i, 7)
            elseif c >= 10 then
                set c = c - 10
                call SetUnitAbilityLevel(whichUnit, i, 6)
            else
                set c = c - 1
                call SetUnitAbilityLevel(whichUnit, i, 5)
            endif
            call UnitRemoveAbility(whichUnit, i)
        endloop
    endif
    return true
endfunction
//**************************************************************************
//                            End of System                                *
//**************************************************************************

To set this up, you'll need to create two abilities with 7 levels each. The first should be based off of the "Life Bonus (Item)" ability and should give bonuses of this amount for each level respectively: 0, -1, -10, -100, 1, 10, 100. (Yes, the first value is 0)

The second ability should be set up exactly the same way except it should be based off of the passive item mana bonus ability instead.

After you've done that, set up the configuration function with the spells' rawcodes and then use it like so:

    Set LevelUPIntConversion[(Player number of (Owner of (Triggering unit)))] = ((Max Life of (Triggering Unit)) + (Real((((Hero level of (Triggering unit)) + (Strength of Player_Heros[(Player number of (Owner of (Triggering unit)))] (Include bonuses))) / 10)))
    Set LevelUPInt[(Player number of (Owner of (Triggering unit)))] = (Integer(LevelUPIntConversion[(Player number of (Owner of (Triggering unit)))]))
    Custom script: call SetUnitMaxState(GetTriggerUnit(), udg_LevelUPInt[GetConvertedPlayerId(GetOwningPlayer(GetTriggerUnit()))]

And the same for mana, etc.