Need some JASS help =/

[Matemeo]

I took Chocobo's damage system, and rewrote it in JASS, to suit the needs of my map, however, I came across an odd error/bug =/ Here's the trigger.

function Trig_Show_Damages_Actions takes nothing returns nothing
local real DamageDone
local real RandomChance
local real ExtraDamage
set udg_loc = GetUnitLoc(GetTriggerUnit())

    set DamageDone = (GetEventDamage())
if UnitHasBuffBJ(GetEventDamageSource(),'B000') == true then
    set RandomChance = GetRandomInt(1,100)
        if RandomChance <= 15 then
            set ExtraDamage = (GetEventDamage())
            set DamageDone = (GetEventDamage() * 1.5) 
            set ExtraDamage = (DamageDone - ExtraDamage)  
        else
            set DamageDone = (GetEventDamage())
        endif
endif
 call SetUnitLifeBJ( GetTriggerUnit(), GetUnitStateSwap(UNIT_STATE_LIFE, GetTriggerUnit()) - ExtraDamage )
if RandomChance <= 15 then
    call CreateTextTagLocBJ(( I2S(R2I(DamageDone))  ), udg_loc, 0, 15, 100, 0, 0, 0 )
else
    call CreateTextTagLocBJ((I2S(R2I(DamageDone))), udg_loc,0,10,100,100,100,0)
endif
    call SetTextTagPermanentBJ( GetLastCreatedTextTag(), false )
    call SetTextTagVelocityBJ( GetLastCreatedTextTag(), 15.00, 90 )
    call SetTextTagLifespanBJ( GetLastCreatedTextTag(), 3.00 )
    call SetTextTagFadepointBJ( GetLastCreatedTextTag(), 1.00 )
endfunction

//===========================================================================
function InitTrig_Show_Damages takes nothing returns nothing
    set gg_trg_Show_Damages = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Show_Damages, function Trig_Show_Damages_Actions )
endfunction

What the trigger does is simple. After a unit gets damaged, its supposed to store that damage in a variable called DamageDone, then, if the damaging unit has a buff called 'arcane energy' then it rolls from 1-100, and stores the number in a variable called RandomChance. If the variable is equal to or less ten 15 then, it'll 'crit'. (15%chance) If it doesn't land between 1-15 then it'll just carry through to displaying the damage done. If it does crit, then it finds the difference between the original damage, and the extra damage, storing it in a variable called extra damage. Later it lowers enemy hp by extra damage, iin case it crits. However, for some reason, the text tag only appears when I crit, if I dont crit, then it won't show up.

I thought I had it written out right, but it seems I don't, if anyone can offer some insight, thanks in advance.

PS (Dont yell at me about my terrible programming style ) Thanks.

-matemeo

 

[Pyrogasm]

It would be nice to remove all those BJ's, but try adding this in at the end of the trigger:

call SetTextTagVisibility(GetLastCreatedTextTag(), true)

Really... Remove the BJs and set the TextTag to a variable.

 

[Matemeo]

Was gonna make it work first, then figure out what to use besides the BJ's. If you could tell me which functions to use, then I'd be grateful

..And checking to see if that worked.

EDIT: Still not working this is making me mad @_@.

 

[Pyrogasm]

Here's what you should change:

• Convert all locations to X/Y values (locations are crap; X/Ys are much faster and versatile):
  

  local real X
  local real Y

• Store the Triggering Unit and Damage Source to variables:
  

  local unit DamageTarget = GetTriggerUnit()
  local unit DamageSource = GetEventDamageSource()

• Change UnitHasBuffBJ(...) to GetUnitAbilityLevel(DamageSource, 'B000') > 0; When a unit has a buff, it has an ability with the same rawcode as that buff. Additionally, you shouldn't have to compare a boolean to true/false in an if/then; it's essentially saying "if true == true" instead of "if true".
• Declare the damage done variable and set its value immediately as well as rework how you get the extra damage; there's no need to calculated the damage done minus extra damage/whatnot. Simply multiply the damage done by 0.50 to get the extra damage:
  

  local unit DamageTarget = GetTriggerUnit()
  local unit DamageSource = GetEventDamageSource()
  local real DamageDone = GetEventDamage()
  local real RandomChance = GetRandomInt(1, 100)
  local real ExtraDamage = 0.00
  local real X = GetUnitX(DamageTarget)
  local real Y = GetUnitY(DamageTarget)
  
  if (GetUnitAbilityLevel(DamageSource, 'B000') > 0) and (RandomChance <= 15) then
      set ExtraDamage = (DamageDone*0.50)  
  endif

• Instead of setting the unit's life, we need to have the attacking unit damage the attacked unit; we use Chaos attack and Universal damage to assure that the damage won't be affected by armor, else it might be:
  

  call UnitDamageTarget(DamageSource, DamageTarget, ExtraDamage, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNIVERSAL, WEAPON_TYPE_WHOKNOWS)

• Now we need to fix up that floating text; here's what it looks like after removing all those BJs and adding a local texttag variable:
  

  local texttag DamageText = CreateTextTag()
  
  call SetTextTagPos(DamageText, X, Y, 0.00)
      if ExtraDamage > 0.00 then
          call SetTextTagText(DamageText, I2S(R2I(DamageDone+ExtraDamage))+"!", TextTagSize2Height(10.00))
          call SetTextTagColor(DamageText, 255, 0, 0, 255)
      else
          call SetTextTagText(DamageText, I2S(R2I(DamageDone)), TextTagSize2Height(10.00))
          call SetTextTagColor(DamageText, 255, 0, 0, 255)
      endif
  call SetTextTagVelocity(DamageText, 0, 0.04)
  call SetTextTagPermanent(DamageText, false)
  call SetTextTagLifespan(DamageText, 5.00)
  call SetTextTagFadepoint(DamageText, 2.00)
  call SetTextTagVisibility(DamageText, true)

• Nullify your variables:
  

  set DamageSource = null
  set DamageTarget = null
  set DamageText = null

• All put together, it should look like this:
  

  function Trig_Show_Damages_Actions takes nothing returns nothing
  local unit DamageTarget = GetTriggerUnit()
  local unit DamageSource = GetEventDamageSource()
  local real DamageDone = GetEventDamage()
  local real RandomChance = GetRandomInt(1, 100)
  local real ExtraDamage = 0.00
  local real X = GetUnitX(DamageTarget)
  local real Y = GetUnitY(DamageTarget)
  local texttag DamageText = CreateTextTag()
  
  if (GetUnitAbilityLevel(DamageSource, 'B000') > 0) and (RandomChance <= 15) then
      set ExtraDamage = (DamageDone*0.50)  
  endif
  call UnitDamageTarget(DamageSource, DamageTarget, ExtraDamage, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_UNIVERSAL, WEAPON_TYPE_WHOKNOWS)
  
  call SetTextTagPos(DamageText, X, Y, 0.00)
      if ExtraDamage > 0.00 then
          call SetTextTagText(DamageText, I2S(R2I(DamageDone+ExtraDamage))+"!", TextTagSize2Height(10.00))
          call SetTextTagColor(DamageText, 255, 0, 0, 255)
      else
          call SetTextTagText(DamageText, I2S(R2I(DamageDone)), TextTagSize2Height(10.00))
          call SetTextTagColor(DamageText, 255, 0, 0, 255)
      endif
  call SetTextTagVelocity(DamageText, 0, 0.04)
  call SetTextTagPermanent(DamageText, false)
  call SetTextTagLifespan(DamageText, 5.00)
  call SetTextTagFadepoint(DamageText, 2.00)
  call SetTextTagVisibility(DamageText, true)
  
  set DamageSource = null
  set DamageTarget = null
  set DamageText = null
  endfunction
  
  //===========================================================================
  function InitTrig_Show_Damages takes nothing returns nothing
      set gg_trg_Show_Damages = CreateTrigger(  )
      call TriggerAddAction( gg_trg_Show_Damages, function Trig_Show_Damages_Actions )
  endfunction

 

[Matemeo]

Just to clarify, the weirdest part, is that when it 'crits' it works fine, its just when it doesn't, I don't see any reason why it wouldn't show up

<--Eagerly anticipating suggested changes

 

[Pyrogasm]

Maybe it was because you changed the text size?

 

[Matemeo]

So, yeah, its 4:30, I'm tired, so...I put all the code in, blah blah. I run the map, I attack a unit, and warcraft crashes GG, I gotta go to sleep, lol. Thanks for the help though. =/

 

[Arkan]

Maybe it's a never-ending loop, try disable the trigger before UnitDamageTarget and then re-enable it.

 

[Matemeo]

Crap, I think it is a never-ending loop, because, the trigger runs when a unit is damaged, lol just realized that. I'll try something else....dunno what to use though.

 

[Gotham]

Disable the trigger just before the UnitDamageTarget function (or whatever you are using to damage your target), then enable the trigger.

 

[Matemeo]

Ok, so, that was the problem, when it damages a target, it goes through the trigger again, an infinite amount of times... :/ Is there a different event I could use? Or a different way to damage target effectively?

 

[Pyrogasm]

Add "call DisableTrigger(gg_trg_Show_Damages)" before the UnitDamageTarget(...) line and "call EnableTrigger(gg_trg_Show_Damages) after the UnitDamagetTarget call.

 

[Matemeo]

Already did, thanks for all the help