Spell Overload

[NetherHawk]

Every time the hero attacks, he stores up lightning charges. When he reaches his limit, he unleashes the charges which slows the AS and MS of units in an area near the attacked unit.

requires 8/7/6/5 attacks,
deals 30/45/60/75 damage.

globals
endglobals

//*******************************************************************************************
//  Configuration  (This is where you need to edit to make the spell works in your map)
//*******************************************************************************************
//
//  <-------------------- Rawcode -------------------->
//
constant function AbilityID takes nothing returns  integer
    return 'A001'
endfunction
//  The raw of the ability, Overload
constant function DAbilityID takes nothing returns integer
    return 'A000'
endfunction
//  The raw of the dummy ability Overload Effect
constant function DummyID takes nothing returns integer
    return 'h000'
endfunction 
//  The raw of the dummy unit, Overload Dummy
//
//  <------------------ Rawcode End ------------------>
//
//  <----------------- Configuration ----------------->
//
// Changing the number of hits before the thunderclap is released
// Scroll down and find the function, Overload_Charge
// you would see this :
//                      local integer cx = 9 - i  
// i = the level of Overload of the hero
// cx determines the number of attacks before the thunderclap is released
// adjust it to what you want
// for eg: 10 - 2i would mean 8 on level 1, 6 on level 2, 4 on level 3 and 
//         2 on level 4.
// any further questions, you may post at the thread. Have fun, cheers!  
//
constant function FX takes nothing returns string
    return "Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl"
endfunction
// this is the special effect added to the hands of the hero
// if you want to change this, create a new trigger, select the special effect
// you want and create an action invovling that effect
// Convert the trigger to custom text under edit and see the name of the
// special effect, it should be something like above, "....."
// Replace the name above to change the effects
//
//  <--------------- Configuration End --------------->//

//*******************************************************************************************
//  Configuration End
//*******************************************************************************************

// -----------------------> Do not edit anything below this line. <-----------------------//
// -----------------------> Do not edit anything below this line. <-----------------------//
// -----------------------> Do not edit anything below this line. <-----------------------//

function Overload_Jass_Conditions takes nothing returns boolean
    return GetLearnedSkill() == 'A001'
endfunction  

function Overload_Filter takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"caster")
    return GetAttacker() == u and IsUnitEnemy(GetTriggerUnit(),GetOwningPlayer(u)) == true
endfunction

function Overload_Check takes nothing returns boolean
    local trigger tx = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tx,"caster")
    return GetEventDamageSource() == u
endfunction

function Overload_Recount takes nothing returns nothing
    local trigger tx = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tx,"caster")
    local unit ux = GetTriggerUnit()
    local integer i = GetUnitAbilityLevel(u,AbilityID())
    local integer c = GetHandleInt(u,"counter")
    local effect fx = GetHandleFX(u,"effectx")
    local effect fy = GetHandleFX(u,"effecty")
    local unit d

    set c = c - 1  
    call SetHandleInt(u,"counter",c)
    if c == 1 then
        set fx =  AddSpecialEffectTarget(FX(),u,"right + hand")
        set fy =  AddSpecialEffectTarget(FX(),u,"left + hand")
        call SetHandleHandle(u,"effectx",fx)
        call SetHandleHandle(u,"effecty",fy)
    else
        if c == 0 then
            call DestroyEffect(fx)
            call DestroyEffect(fy)
            set d = CreateUnit(GetOwningPlayer(u),DummyID(),GetUnitX(ux),GetUnitY(ux),bj_UNIT_FACING)
            call SetUnitAbilityLevel(d,DAbilityID(),i)
            call UnitApplyTimedLife(d,'BTLF',1)
            call IssueImmediateOrder(d,"thunderclap")
            set fx = null
            set fy = null
            set d = null
        endif
    endif

    call DisableTrigger(tx)
    call DestroyTrigger(tx)
    set tx = null
endfunction
        
function Overload_Charge takes nothing returns nothing
    local trigger tx = CreateTrigger()
    local trigger tr = GetTriggeringTrigger()
    local unit ux = GetTriggerUnit()
    local unit u = GetHandleUnit(tr,"caster")
    local integer i = GetUnitAbilityLevel(u,AbilityID())
    local integer cx = 9 - i
    local integer c = GetHandleInt(u,"counter")

    if c == 0 then
        set c = cx
    endif 
    call SetHandleInt(u,"counter",c)
    call SetHandleHandle(tx,"caster",u)
    call TriggerRegisterUnitEvent(tx,ux,EVENT_UNIT_DAMAGED)
    call TriggerAddCondition(tx, Condition(function Overload_Check)) 
    call TriggerAddAction(tx, function Overload_Recount) 

    set u = null
    set ux = null  
endfunction    
    

function Overload_Jass_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local integer i = GetUnitAbilityLevel(u,AbilityID())    
    local trigger tr 
                  
    if i == 1 then
        set tr = CreateTrigger()
        call SetHandleHandle(tr,"caster",u)                 
        call TriggerRegisterAnyUnitEventBJ(tr,EVENT_PLAYER_UNIT_ATTACKED)
        call TriggerAddCondition(tr, Condition(function Overload_Filter)) 
        call TriggerAddAction(tr, function Overload_Charge)  
    endif   
    set u = null
endfunction

//===========================================================================
function InitTrig_Overload_Jass takes nothing returns nothing
    set gg_trg_Overload_Jass = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Overload_Jass, EVENT_PLAYER_HERO_SKILL )
    call TriggerAddCondition( gg_trg_Overload_Jass, Condition( function Overload_Jass_Conditions ) )
    call TriggerAddAction( gg_trg_Overload_Jass, function Overload_Jass_Actions )
endfunction

thx Daxtreme for helping =]

charged mountain king ready to unleash the lightning

 

[cr4xzZz]

Really nice I don't see any BJs/leaks in ur code.

/ Why do you use this in your code:

globals
endglobals

and I've seen you put things like local unit caster, local location pos, etc. Is this something that's needed for the Handle Variables? /

 

[warroom99]

is this mui?

 

[~GaLs~]

I bugged your spell by just abusing the "stop" bug.

 

[NetherHawk]

hmm, mui bit im not too sure.

cr4xzZz.. er no thats just like naming the locals.
handle vars allow you to attach variables to units.

for exmaple in overload_charge, i attach the integer variable c to the unit u
by SetHandleInt(u,"counter",c)
in the next function, function recount
i can obtain that variable by defining u again and then
local integer c = GetHandleInt(u,"counter")

hope this helps you understand abit.

Gals~:iMPOSSIBLE GALS. ARE YOU SURE?>
i used a unit takes damage event!!!

edit@ it bugs, but after it bugs once the trigger fails completely? why does this still happen even though im using event unit damaged? i might as well have not gone through the trouble....

 

[~GaLs~]

>>iMPOSSIBLE GALS. ARE YOU SURE?>
Go and test your map.
When Mountain King is attacking... keep press S to not allow it to deal damage to the target. Do this several times, the spell won't get fire now.

 

[NetherHawk]

ya i know, iedited my post ontop. why does this happen ....

 

[waaaks!]

cool...is this spell similar to dota's one?
i think this is...my bad

 

[~GaLs~]

>>why does this happen ....
Dont use EVENT_PLAYER_UNIT_ATTACKED...
Use EVENT_UNIT_DAMAGED. Or simply use Emjlr3's On_Attack_template.

 

[NetherHawk]

gals, if you look at my code, i use even unit damaged ....

@waaaks, i made it from what i remember, cant be bothered to go play dota and be as specific.

 

[chovynz]

function Overload_Charge takes nothing returns nothing
...
    call TriggerRegisterUnitEvent(tx,ux,EVENT_UNIT_DAMAGED)
...
endfunction    

function Overload_Jass_Actions takes nothing returns nothing
...        
        call TriggerRegisterAnyUnitEventBJ(tr,EVENT_PLAYER_UNIT_ATTACKED)
...
endfunction

 

[NetherHawk]

gals, i use local handle vars, on attack template is caster system i think.. i cant put them together right?

 

[~GaLs~]

>>gals, i use local handle vars, on attack template is caster system i think.. i cant put them together right?
False, on attack template is not a function in caster system.
It is a template/system made by Emjlr3. The big hulk~

 

[Hero]

I bugged your spell by just abusing the "stop" bug.

Thats because he doesn't use the attack detection method properly...for this you should use the orb one made by Vexorian or Emjlr3

Not this

call TriggerRegisterAnyUnitEventBJ(tr,EVENT_PLAYER_UNIT_ATTACKED)
        call TriggerAddCondition(tr, Condition(function Overload_Filter)) 
        call TriggerAddAction(tr, function Overload_Charge)

 

[0zaru]

Comments: Well you added constant functions... but you aren't using them (at least he ability one =P)


Example:
In this line
return GetLearnedSkill() == 'A001' -> Notice the 'A001' it must be replaced by the constant function,.. AbilityID()

In Overload recount you aren't nulling the units u,ux and d either the effects (As i say, you always need to null them, not only when the spell finish). I don't find other no nulling but i checked quickly =P

Also EVENT_PLAYER_UNIT_ATTACKED is a very bad event, please use a AttackDetectSystem

 

[NetherHawk]

i know i used attack, but, i link it to event unit damaged? or should i just go straight to event unit damaged.

 

[shawtybaby]

I got two bugs with this spell, and it occurs no matter what I do.

1) Sometimes when the game starts and I pick a hero that uses this Overload spell, it doesn't work at all. This only happens sometimes. And by that I mean; it works the first few minutes of the game, then it stop working for the rest of the game.

2) No matter what special effect I use whatsoever, it doesn't show the special effect. Any way to fix this? I've tried any effect, still doesn't work.

thx.

 

[Flare]

2) Have you got the string correct? Are you separating each part of the string with \\ (e.g. Abilities\\Humans\\And so on)

 

[shawtybaby]

2) Have you got the string correct? Are you separating each part of the string with \\ (e.g. Abilities\\Humans\\And so on)

yes. still bugs.

 

[shawtybaby]

GG.. it still bugs a lot. I have done everything right. But after 20-30 minutes in the game, it bugs and won't work again...