Problem with distance toward facing

[Doom-Angel]

k so i have this function:

function Test takes location loc,real distance,real facing,integer position returns location
    local real x = GetLocationX(loc)
    local real y = GetLocationY(loc) 
    local real face = ModuloReal(360,facing)
    call RemoveLocation(loc)
    set face = face - ((position-1) * 120)
    set x = x + distance * Cos(Deg2Rad(face))
    set y = y + distance * Sin(Deg2Rad(face))
    return Location(x,y)
endfunction

this function supposed to take the arguments written (position is only 1,2 or 3)
and return location using the facing and the taken location so it's suppoed to be something like this:

red - wanted location
blue - unit facing

       [COLOR="Red"]O[/COLOR] 
       [COLOR="Blue"]|
       |[/COLOR]
       o
      / \
     /   \
    [COLOR="Red"]O[/COLOR]     [COLOR="Red"]O[/COLOR]

it didn't came out execly the way i wanted but anyway think the other two lines are exacly the same distance and are splited in 3 equal pieces (meaning there is 120 difference beetwen the facing angles of each.

anyway this points aren't working and they split all over on random spots depending on the facing and location.

i need someone to tell me what am i doing wrong here

thanks in advance :thup:

 

[Builder Bob]

I may be overlooking something here, but you shouldn't need to have to break down the angle to [0 < angle < 360] when you're using it with Cos and Sin anyway.

function Test takes location loc, real distance, real facing, integer position returns location
	local real x = GetLocationX(loc)
	local real y = GetLocationY(loc)
	call RemoveLocation(loc)
	set facing = bj_DEGTORAD * (facing + 120. * (position - 1.))
	set x = x + distance * Cos(facing)
	set y = y + distance * Sin(facing)
	return Location(x,y)
endfunction

It's freehand, but I am fairly sure this will give you the wanted results

 

[Doom-Angel]

i tried what u gave but it didn't work though....

 

[Builder Bob]

really?

Try this. The trigger must be named Test to make sure the InitTrig is run on map init.
Now just order any unit to stop to check if you get the correct positions.

function Test takes location loc, real distance, real facing, integer position returns location
	local real x = GetLocationX(loc)
	local real y = GetLocationY(loc)
	call RemoveLocation(loc)
	set facing = bj_DEGTORAD * (facing + 120. * (position - 1.))
	set x = x + distance * Cos(facing)
	set y = y + distance * Sin(facing)
	call BJDebugMsg(I2S(position))
	call DestroyEffect(AddSpecialEffect("Abilities\\Weapons\\ChimaeraLightningMissile\\ChimaeraLightningMissile.mdl", x, y))
	return Location(x,y)
endfunction

function StopOrder takes nothing returns boolean
	local unit u = GetTriggerUnit()
	local real x = GetUnitX(u)
	local real y = GetUnitY(u)
	local integer pos = GetRandomInt(1, 3)
	call Test(Location(x, y), 300., GetUnitFacing(u), pos)
	return false
endfunction

function InitTrig_Test takes nothing returns nothing
	local trigger trig = CreateTrigger()
	call TriggerRegisterAnyUnitEventBJ(trig, EVENT_PLAYER_UNIT_ISSUED_ORDER)
	call TriggerAddCondition(trig, Condition(function StopOrder))
endfunction

If this is not what you want, I must have misunderstood something.

 

[Doom-Angel]

this one worked but how?
it's the same function as above and that other one didn't work

edit:
after a few test i found out that it doesn't work for me only in case of loop - when i try to display all 3 positions in a row it's just getting messed up but alone it's working great....
any1 got a clue?

 

[Doom-Angel]

i found the problem finnaly
it turns out removing location of argument received actually removed the location of the variable which contained that location and made thing get messed up after it.

this thing means that when sending a variables value as argument it basically sends a pointer to the variable's address - could any1 confirm it though?

also thanks Bob for the help +Rep

 

[Builder Bob]

this thing means that when sending a variables value as argument it basically sends a pointer to the variable's address - could any1 confirm it though?

Actually, all variables are pointers to objects. Both of your variables point to the same object. If you destroy the content of either variable, both will be pointing to a destroyed object.

Edit: and I'm happy to help

 

[Doom-Angel]

i never figured out they are actually sending the pointers of the variables and that's the first time hear it (or finding it) - anyway thanks for confirming.