Spell Shakra Aura

[Sooda]

I have finished my first JASS ability ever ! It should be absolutely bug free (Atleast I thought through many cases.) First I started to do it because of somebodys help request in these forums and it evolved into perfectly working JASS triggered Aura. What it does ?
Specs.
Name:Shakra Aura
Description:Turns mana used by ability to health and heals nearby friendly units.
Level 1:Turns 25 % of mana used by ability to health and heals nearby friendly units. Can most heal 50 hp.
Level 2:Turns 50 % of mana used by ability to health and heals nearby friendly units. Can most heal 100 hp.
Level 3:Turns 75 % of mana used by ability to health and heals nearby friendly units. Can most heal 150 hp.
Screenshots:

Q: How to implement it ?
A:When you copy paste this trigger make sure your new trigger name is "ManaCheckAoE" (Without "" and watch out it' s case sensitive !)

// Replace raw data with your ability raw Id. Default is custom Shakra Aura.
// Replace raw data with your ability buff raw Id. Default is custom Shakra Aura.

Full JASS code ( You can just copy paste this to your map and change ability raw Id and buff Id and it works !):

function TempCS_H2I takes handle h returns integer
    // I recommend you to use real CSCache still.
    // This is for example only.
    return h
    return 0
endfunction


constant function abilityRawId takes nothing returns integer
    // Replace raw data with your ability raw Id. Default is custom Shakra Aura.
    return 'A000'
endfunction

constant function abilityBuffRawId takes nothing returns integer
    // Replace raw data with your ability buff raw Id. Default is custom Shakra Aura buff.
    return 'B000'
endfunction

constant function abilityEffect takes nothing returns string
    // Change this path to show different effect on units who gain Hp.
    // Effect should have death animation what can be seen by human eye. Otherwise you can' t see it.
    return "Abilities\\Spells\\Undead\\VampiricAura\\VampiricAuraTarget.mdl"
endfunction


constant function HealLimit takes nothing returns real
    // Limit per level is multiplied with level.
    return 50.
endfunction

function AbilityCon takes nothing returns boolean
    return GetUnitAbilityLevel(GetTriggerUnit(),abilityRawId())!= 0
endfunction

function MatchingUnit takes nothing returns boolean
    // Currently checks does unit is ally of caster and isn' t mechanical and has right buff.
    return IsUnitType(GetFilterUnit(),UNIT_TYPE_MECHANICAL) == false and IsUnitAlly(GetFilterUnit(),GetOwningPlayer(GetTriggerUnit())) == true and GetUnitAbilityLevel(GetFilterUnit(),abilityBuffRawId()) > 0
endfunction

function GettingManaBefore takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local string key=I2S(TempCS_H2I(u))

    // You will have to use now game cache to pull this off.
    // Use CSCache or KaTTana' s or whatever.
    call StoreReal(bj_lastCreatedGameCache,"manaBefore",key,GetUnitState(u,UNIT_STATE_MANA))

    set u=null
endfunction

function ConvertUsedManaToHealth takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local unit TempUnit
    
    local real currentHp=GetUnitState(u,UNIT_STATE_LIFE)
    local real currentMp=GetUnitState(u,UNIT_STATE_MANA)
    local real UnitX=GetUnitX(u)
    local real UnitY=GetUnitY(u)
    local real percent=.25 // Change this value to get higher, lower Mp to Hp conversion (1.00 is 100 %). Default is 0.25 what means 25 % grow per level.
    local real radius=900. // Change this value to get smaller, huger AoE. Default is 900.00 AoE.
    local real HpGain

    // Using H2I bug allows us to retrieve from cache each units mana before because it' s labled with unique Id what gives this bug.
    local string key=I2S(TempCS_H2I(u))
    local real manaBefore=GetStoredReal(bj_lastCreatedGameCache,"manaBefore",key)

    local integer level=GetUnitAbilityLevel(u,abilityRawId())
    local integer n=0
    
    local boolexpr b= Condition ( function MatchingUnit)
    local group g=CreateGroup()

    // Level Check
    loop
    exitwhen n>level
            if n==level then
                set percent=level*percent
            endif
    set n=n+1
    endloop    

    set HpGain=(manaBefore-currentMp)*percent
    // If unit has more mana than before end function or ability didn' t took mana.
    // There is potential enemy abuse when caster gets Mana Burn between effect of ability. That' s why limit check is needed.
    if HpGain<=0 then
        call DestroyBoolExpr(b)
        
        set g=null
        set b=null
        set u=null
        return // Ends function.
    endif
    
    // Limit Check
    if HpGain>level*HealLimit() then
        set HpGain=level*HealLimit()
    endif
    
    call GroupEnumUnitsInRange(g,UnitX,UnitY,radius,b)

    loop
        set TempUnit=null
        set TempUnit=FirstOfGroup(g)
        exitwhen TempUnit==null
            set currentHp=GetUnitState(TempUnit,UNIT_STATE_LIFE)

            call DestroyEffect(AddSpecialEffectTarget(abilityEffect(),TempUnit,"origin"))
            call SetUnitState(TempUnit, UNIT_STATE_LIFE,currentHp+HpGain)
            call GroupRemoveUnit(g,TempUnit)       
    endloop

    call FlushStoredReal(bj_lastCreatedGameCache,"manaBefore",key)
    call DestroyBoolExpr(b)

    set g=null
    set b=null
    set u=null
endfunction

function InitTrig_ManaCheckAoE takes nothing returns nothing
    local trigger ta=CreateTrigger()
    local trigger tb=CreateTrigger()
    
    if bj_lastCreatedGameCache==null then
        set bj_lastCreatedGameCache=InitGameCache("TempCache")
    endif
    
    call TriggerRegisterAnyUnitEventBJ( ta, EVENT_PLAYER_UNIT_SPELL_CAST )
    call TriggerRegisterAnyUnitEventBJ( tb, EVENT_PLAYER_UNIT_SPELL_FINISH )
    call TriggerAddCondition(ta, Condition ( function AbilityCon))
    
    call TriggerAddCondition(tb, Condition ( function AbilityCon))
    call TriggerAddAction(ta, function GettingManaBefore)
    call TriggerAddAction(tb, function ConvertUsedManaToHealth)
endfunction

Demo map is attached under my post.
Feedback always welcomed !

EDIT: Code updated, I have added very detailed README and fixed minor leaks what SFilip pointed out. Have fun making maps or using this ability.

 

[IKilledKEnny]

A little above my level, but I could understand parts of it, good job! +REP. (Once I could).

 

[Sooda]

>A little above my level.
Nice, it isn' t so hard like you think. Btw main is the concept (Though I got it from another person.) What you all think of it and how does it look "in game". I' m curious.

 

[IKilledKEnny]

It's ok, a bit minimal in my opinion, though, maybe add Animate Dead's Special Effect on the hero each time the aura shoots? I would look much better in my opinion.

 

[Sooda]

>It's ok, a bit minimal in my opinion
1000 thanks you checked it. Still it' s aura.
> though, maybe add Animate Dead's Special Effect on the hero each time the aura shoots? I would look much better in my opinion.
> You have opportunity to do so. It isn' t hard to change effect created on units- nice and simple.

 

[IKilledKEnny]

>1000 thanks you checked it. Still it' s aura.
No problem, it always nice to see a master at work.

> You have opportunity to do so. It isn' t hard to change effect created on units- nice and simple
I guess I could figure it out, but I doubt if few other, newer members, can do it. Maybe add a comment where you can add the special effect if you want to do it? I don't know just a suggestion, your call of course. Either way, again, great job.

 

[Ghan]

I like it. It's a nice idea. Though I can't code in JASS to save my life. +rep.

 

[SFilip]

Strings don't need to be set to "".
BoolExprs do need to be set to null. They also need to be destroyed using DestroyBoolExpr before that.

> I recommend you to use real CSCache still.
Then why didn't you use it? People usually don't know what it is, save knowing how to implement it and modify the code where needed.
Of course if you do so mention somewhere that it's needed.
Speaking of which you also need some implementation instructions - people usually don't look at the code that much. Mention which dummy unit/buff you used, how to copy it, what changes need to/can be made etc.

 

[Sooda]

Strings don't need to be set to "".
BoolExprs do need to be set to null. They also need to be destroyed using DestroyBoolExpr before that.

> I recommend you to use real CSCache still.
Then why didn't you use it? People usually don't know what it is, save knowing how to implement it and modify the code where needed.
Of course if you do so mention somewhere that it's needed.
Speaking of which you also need some implementation instructions - people usually don't look at the code that much. Mention which dummy unit/buff you used, how to copy it, what changes need to/can be made etc.

Eh constructive criticism, good. I try to fix these flaws asasp and reupload it.

EDIT: Updated and fixed ! It has now easy README included what explanes almost everything what you
could think of. Maybe even too much. Thanks all !

 

[substance]

Grats on your first JASS spell... doesnt it make you feel proud? I know mine did =p

 

[TheDamien]

Thats pretty cool, thanks for sharing.

 

[master maste]

Good aura spell, cant wait till I find a good idea for my one as I'm currently learning Jass. +rep

 

[Sooda]

>Grats on your first JASS spell... doesnt it make you feel proud?
I' m very proud. It took time and consumed my brains but I finished it.

EDIT: I' m very happy also !

 

[lh2705]

Hey Sooda, congrats on your first Fully Jass spell
Pretty Neat
Tho I can barely read it xD

 

[Sooda]

Will it be added to the Spell Forum also ? Looks like SFilip has much to do. Anyway it should be now completely leak free and pretty optimized.

 

[Chocobo]

function InitTrig_ManaCheckAoE takes nothing returns nothing
    local trigger ta=CreateTrigger()
    local trigger tb=CreateTrigger()
    
    if bj_lastCreatedGameCache==null then
        set bj_lastCreatedGameCache=InitGameCache("TempCache")
    endif
    
    call TriggerRegisterAnyUnitEventBJ( ta, EVENT_PLAYER_UNIT_SPELL_CAST )
    call TriggerRegisterAnyUnitEventBJ( tb, EVENT_PLAYER_UNIT_SPELL_FINISH )
    call TriggerAddCondition(ta, Condition ( function AbilityCon))
    
    call TriggerAddCondition(tb, Condition ( function AbilityCon))
    call TriggerAddAction(ta, function GettingManaBefore)
    call TriggerAddAction(tb, function ConvertUsedManaToHealth)
endfunction

can be :

function InitTrig_ManaCheckAoE takes nothing returns nothing
    local trigger t=CreateTrigger()
    if bj_lastCreatedGameCache==null then
        set bj_lastCreatedGameCache=InitGameCache("TempCache")
    endif
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_CAST)
    call TriggerAddCondition(t,Condition(function AbilityCon))
    call TriggerAddAction(t,function GettingManaBefore)
    set t=CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_FINISH)
    call TriggerAddCondition(t,Condition(function AbilityCon))
    call TriggerAddAction(t,function ConvertUsedManaToHealth)
    set t=null
endfunction

    local integer n=0
//[B] = local integer n[/B]

        set TempUnit=null
        set TempUnit=FirstOfGroup(g)
//[B]set TempUnit=FirstOfGroup(g)[/B]

Also avoid using bj_lastCreatedGameCache, if someone initializes it..

globals
    gamecache udg_g
endglobals

function TempCS_H2I takes handle h returns integer
    // I recommend you to use real CSCache still.
    // This is for example only.
    return h
    return 0
endfunction

constant function GameCache takes nothing returns gamecache
    //Gamecache
    return udg_g
endfunction

constant function abilityRawId takes nothing returns integer
    // Replace raw data with your ability raw Id. Default is custom Shakra Aura.
    return 'A000'
endfunction

constant function abilityBuffRawId takes nothing returns integer
    // Replace raw data with your ability buff raw Id. Default is custom Shakra Aura buff.
    return 'B000'
endfunction

constant function abilityEffect takes nothing returns string
    // Change this path to show different effect on units who gain Hp.
    // Effect should have death animation what can be seen by human eye. Otherwise you can' t see it.
    return "Abilities\\Spells\\Undead\\VampiricAura\\VampiricAuraTarget.mdl"
endfunction


constant function HealLimit takes nothing returns real
    // Limit per level is multiplied with level.
    return 50.
endfunction

function AbilityCon takes nothing returns boolean
    return GetUnitAbilityLevel(GetTriggerUnit(),abilityRawId())!= 0
endfunction

function MatchingUnit takes nothing returns boolean
    // Currently checks does unit is ally of caster and isn' t mechanical and has right buff.
    return IsUnitType(GetFilterUnit(),UNIT_TYPE_MECHANICAL) == false and IsUnitAlly(GetFilterUnit(),GetOwningPlayer(GetTriggerUnit())) == true and GetUnitAbilityLevel(GetFilterUnit(),abilityBuffRawId()) > 0
endfunction

function GettingManaBefore takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local string key=I2S(TempCS_H2I(u))

    // You will have to use now game cache to pull this off.
    // Use CSCache or KaTTana' s or whatever.
    call StoreReal(GameCache(),"manaBefore",key,GetUnitState(u,UNIT_STATE_MANA))

    set u=null
endfunction

function ConvertUsedManaToHealth takes nothing returns nothing
    local unit u=GetTriggerUnit()
    local unit TempUnit
    
    local real currentHp=GetUnitState(u,ConvertUnitState(0))
    local real currentMp=GetUnitState(u,ConvertUnitState(2))
    local real UnitX=GetUnitX(u)
    local real UnitY=GetUnitY(u)
    local real percent=.25 // Change this value to get higher, lower Mp to Hp conversion (1.00 is 100 %). Default is 0.25 what means 25 % grow per level.
    local real radius=900. // Change this value to get smaller, huger AoE. Default is 900.00 AoE.
    local real HpGain

    // Using H2I bug allows us to retrieve from cache each units mana before because it' s labled with unique Id what gives this bug.
    local string key=I2S(TempCS_H2I(u))
    local real manaBefore=GetStoredReal(GameCache(),"manaBefore",key)

    local integer level=GetUnitAbilityLevel(u,abilityRawId())
    local integer n
    
    local boolexpr b=Condition(function MatchingUnit)
    local group g=CreateGroup()

    // Level Check
    loop
        exitwhen n>level
        if n==level then
            set percent=level*percent
        endif
        set n=n+1
    endloop

    set HpGain=(manaBefore-currentMp)*percent
    // If unit has more mana than before end function or ability didn' t took mana.
    // There is potential enemy abuse when caster gets Mana Burn between effect of ability. That' s why limit check is needed.
    if HpGain<=0 then
        call DestroyBoolExpr(b)
        
        set g=null
        set b=null
        set u=null
        return // Ends function.
    endif
    
    // Limit Check
    if HpGain>level*HealLimit() then
        set HpGain=level*HealLimit()
    endif
    
    call GroupEnumUnitsInRange(g,UnitX,UnitY,radius,b)

    loop
        set TempUnit=FirstOfGroup(g)
        exitwhen TempUnit==null
            set currentHp=GetUnitState(TempUnit,ConvertUnitState(0))

            call DestroyEffect(AddSpecialEffectTarget(abilityEffect(),TempUnit,"origin"))
            call SetUnitState(TempUnit,ConvertUnitState(0),currentHp+HpGain)
            call GroupRemoveUnit(g,TempUnit)
    endloop

    call FlushStoredReal(GameCache(),"manaBefore",key)
    call DestroyBoolExpr(b)

    set g=null
    set b=null
    set u=null
endfunction

function InitTrig_ManaCheckAoE takes nothing returns nothing
    local trigger t=CreateTrigger()
    set udg_g=InitGameCache("TC")
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_CAST)
    call TriggerAddCondition(t,Condition(function AbilityCon))
    call TriggerAddAction(t,function GettingManaBefore)
    set t=CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t,EVENT_PLAYER_UNIT_SPELL_FINISH)
    call TriggerAddCondition(t,Condition(function AbilityCon))
    call TriggerAddAction(t,function ConvertUsedManaToHealth)
    set t=null
endfunction

but you will need a global. Useless but only for optimizations.

 

[SFilip]

> avoid using bj_lastCreatedGameCache
"// This is for example only."

Though I doubt many people know how to change it so that it uses handle vars/CSCache.
I still think you should modify it yourself to make it use CSCache instead.

But anyway approved. Sorry for the wait.

 

[BOOMER]

Because my knowing nothing about JASS can i ask you something how can i detect mana cost of a cast ability or mana used while doing somehing

 

[Sooda]

>Because my knowing nothing about JASS can i ask you something how can i detect mana cost of a cast ability
First you store current mana of triggering unit with event "unit starts casting ability" and then after unit has finished casting ability use event "unit finishes casting ability" and store again current mana. Then do math:
manaBefore- ManaCurrent= ManaUsedByAbility
> or mana used while doing somehing
For that detect when unit starts to channel ability and store current mana. Then use another event "Unit finishes casting ability" and store again current mana and do like before.

 

[BOOMER]

Thanks