Stop unit upon casting the ability

[Nexor]

I'm creating a morphing hero with a twist:
He has the same hero abilities in both form with different effects.
There is a spell, that will heal allies in the human form and in animal form he charges towards an enemy.

I tried stopping the Hero on casting the ability ( I'm using vJASS, but I know this is possible to make in GUI too ) in the condition function or at the action function wit the event: "Begins casting an ability" but it seems that somehow he is still able to cast it The spell is based on Channel and it uses the wispharvest order string.
What should I do to properly stop the unit?

 

[Nherwyziant]

Since you understand vJass

scope StopCast initializer I
    private function A takes nothing returns nothing
        call IssueImmediateOrder(GetSpellAbilityUnit(),"stop")
    endfunction

    //===========================================================================
    private function I takes nothing returns nothing
        local trigger g = CreateTrigger()
        local integer i = 0
        loop
            call TriggerRegisterPlayerUnitEvent(g,Player(i),EVENT_PLAYER_UNIT_SPELL_CHANNEL,null)
            set i = i+1
            exitwhen i == bj_MAX_PLAYER_SLOTS
        endloop
        call TriggerAddAction(g,function A)
    endfunction
endscope

or in GUI

• StopCast
  • Events
    • Unit - A unit Begins channeling an ability
  • Conditions
  • Actions
    • Unit - Order (Casting unit) to Stop

But I suggest use the vJass one.

 

[Laiev]

    private function I takes nothing returns nothing
        local trigger g = CreateTrigger()
        local integer i = 0
        loop
            call TriggerRegisterPlayerUnitEvent(g,Player(i),EVENT_PLAYER_UNIT_SPELL_CHANNEL,null)
            set i = i+1
            exitwhen i == bj_MAX_PLAYER_SLOTS
        endloop
        call TriggerAddAction(g,function A)
    endfunction

he don't need this -.- just use bj..

instead of Casting Unit/[ljass]GetSpellAbilityUnit()[/ljass] use Triggering Unit/[ljass]GetTriggerUnit()[/ljass]

EDIT: i think he don't want a channeling spell..... the Channel spell is just base, which is a good one..

 

[Nherwyziant]

instead of Casting Unit/[ljass]GetSpellAbilityUnit()[/ljass] use Triggering Unit/[ljass]GetTriggerUnit()[/ljass]

[/QUOTE]

I know that, but i love GetSpellAbilityUnit more.

 

[Nexor]

Isn't it begins casting?

 

[Laiev]

begin cast an ability is more fast then start effect, but begin can and will bug, cuz you can just press the hotkey and then stop, the spell will cast but the cd and mana cost don't.

 

[Nherwyziant]

Isn't it begins casting?

Just try what I said and it will work fine.

 

[Nexor]

Yeah it's working, it seems, that my cooldown system interferes with the spell, but I don't understand because the system uses the event SPELL_FINISH. Hm that's strange

EDIT: Sry it uses ENDCAST

 

[Nexor]

Sry for doublepost

I got it working using SPELL_EFFECT event, but now, it uses mana too :S even if I'm adding it back to the unit

 

[SwedishChef]

Show the trigger maybe?

 

[Nexor]

Here ya go:

scope HolyDeath initializer onInit

globals
    private constant integer SpellID = 'A00N'
    private constant integer Human   = 'H001'
    private constant integer Wolf    = 'H002'
    
    private constant real Speed   = 30.
    private unit Dummy
    
    private unit Unit
    private timer T = CreateTimer()
endglobals

private constant function Manacost takes integer level returns real
    return 100.
endfunction

private constant function healDuration takes integer level returns real
    return 8.
endfunction 

private constant function Damage takes integer level returns real
    return 70. + level * 50.
endfunction

private constant function Heal takes integer level returns real
    return 70. + level * 50.
endfunction

private struct charge
    unit hero
    unit target
    real speed = Speed
    
    
    method periodic takes nothing returns boolean
        local real hx = GetUnitX(.hero)
        local real hy = GetUnitY(.hero)
        local real tx = GetUnitX(.target)
        local real ty = GetUnitY(.target)
        local real dx = hx-tx
        local real dy = hy-ty
        local real distance = dx*dx+dy*dy
        local real angle = Atan2(ty-hy,tx-hx)
        local real newx = hx + .speed * Cos(angle)
        local real newy = hy + .speed * Sin(angle)
        
        
        set .speed = .speed * 1.25
        call SetUnitPosition(.hero,newx,newy)
    
        if distance < 200*200 then
            set Dummy = CreateUnit(GetOwningPlayer(.hero),'dumy',newx,newy,0)
            call UnitAddAbility(Dummy,'Stun')
            call IssueTargetOrder(Dummy,"thunderbolt",.target)
            call UnitApplyTimedLife(Dummy,'BTLF',2)
            
            call PauseUnit(.hero,false)
            call SetUnitInvulnerable(.hero,false)
            call SetUnitPathing(.hero,true)
            call SetUnitAnimation(.hero,"stand")
            call IssueTargetOrder(.hero,"attackonce",.target)
            return true
        endif
        return false
    endmethod
    
    implement T32
endstruct

private struct heal
    unit hero
    real heal
    integer ticks
    
    
    method periodic takes nothing returns boolean
    
        call SetUnitState(.hero,UNIT_STATE_LIFE,GetUnitState(.hero,UNIT_STATE_LIFE)+.heal)
    
        set .ticks = .ticks - 1
        if .ticks == 0 or GetWidgetLife(.hero) < .405 then
            return true
        endif
        return false
    endmethod
    
    implement T32
endstruct



private function onConditions takes nothing returns boolean
    return GetSpellAbilityId() == SpellID
endfunction

private function onCallback takes nothing returns nothing
    call SetUnitState(Unit,UNIT_STATE_MANA,GetUnitState(Unit,UNIT_STATE_MANA)+Manacost(GetUnitAbilityLevel(Unit,SpellID)))
endfunction

private function onActions takes nothing returns nothing
    local unit caster = GetTriggerUnit()
    local unit target = GetSpellTargetUnit()
    local integer id = GetUnitTypeId(caster)
    local integer level = GetUnitAbilityLevel(caster,SpellID)
    local heal H
    local charge C
    local real xc = GetUnitX(caster)
    local real yc = GetUnitY(caster)
    local real xt = GetUnitX(target)
    local real yt = GetUnitY(target)
    local real dx = xc - xt
    local real dy = yc - yt
    local real distance = SquareRoot(dx*dx+dy*dy)
    
    if       id == Human then
        if IsUnitEnemy(target,GetOwningPlayer(caster)) == true then
                call IssueImmediateOrder(caster,"stop")
                call DisplayTextToPlayer(GetOwningPlayer(caster),0,0,"|cffffcc00Unable to target enemies in this form.")
                set Unit = caster
                call TimerStart(T,0,false,function onCallback)
        else
            set H = heal.create()
            set H.hero = target
            set H.ticks = R2I(healDuration(level) / T32_PERIOD)
            set H.heal = Heal(level) / H.ticks
            call H.startPeriodic()
        endif
    elseif  id == Wolf then
        if IsUnitAlly(target,GetOwningPlayer(caster)) == true or caster == target then
            call IssueImmediateOrder(caster,"stop")
            call DisplayTextToPlayer(GetOwningPlayer(caster),0,0,"|cffffcc00Unable to target allies in this form.")
            set Unit = caster
            call TimerStart(T,0,false,function onCallback)
        elseif distance*1.1 < 300 or distance*0.9 > 600 then
            call IssueImmediateOrder(caster,"stop")
            call DisplayTextToPlayer(GetOwningPlayer(caster),0,0,"|cffffcc00Minimum range is 300, maximum is 600.")
            set Unit = caster
            call TimerStart(T,0,false,function onCallback)
        else
            set C = charge.create()
            call PauseUnit(caster,true)
            call SetUnitInvulnerable(caster,true)
            call SetUnitPathing(caster,false)
            call SetUnitAnimation(caster,"walk")
            set C.hero = caster
            set C.target = target
            call C.startPeriodic()
        endif
        
    endif
    
    set caster = null
    set target = null
endfunction

//===========================================================================
private function onInit takes nothing returns nothing
    local trigger t = CreateTrigger()
    
    call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    
    call TriggerAddCondition( t, Condition(function onConditions) )
    call TriggerAddAction( t, function onActions )
    
    set t = null
endfunction

endscope

But I think it's working now