Why won't this trigger work?

[Arkan]

My revival trigger, it works when you die the first time, but when you die a second time you won't respawn, and the camera will pan you to the center of the map instead of the base as it does when you die the first time, really weird...

function Trig_Revival_Conditions takes nothing returns boolean
return IsUnitType(GetTriggerUnit(), UNIT_TYPE_HERO) == true
endfunction

function Trig_Revival_Actions takes nothing returns nothing
local unit dying=GetTriggerUnit()
local player p=GetOwningPlayer(dying)
local location l
set udg_DeadTimer[GetConvertedPlayerId(p)]=GetHeroLevel(dying)*5
loop
    exitwhen udg_DeadTimer[GetConvertedPlayerId(p)]==0
        call MultiboardSetItemValueBJ(udg_MB,5,udg_Playerrow[GetPlayerId(p)],"|cffAFEEEE"+I2S(udg_DeadTimer[GetConvertedPlayerId(p)])+"|r")
        call PolledWait(1)
        set udg_DeadTimer[GetConvertedPlayerId(p)]=udg_DeadTimer[GetConvertedPlayerId(p)]-1
endloop
if(IsPlayerInForce(p,udg_NorthPlayers)==true)then
set l=udg_NRegen
call PanCameraToTimedLocForPlayer(p,udg_NRegen,1)
else
set l=udg_SRegen
call PanCameraToTimedLocForPlayer(p,udg_SRegen,1)
endif
call MultiboardSetItemValueBJ(udg_MB,5,udg_Playerrow[GetPlayerId(p)],"")
call BJDebugMsg(GetUnitName(dying))
call ReviveHeroLoc(dying,l,true)
set dying=null
set p=null
call RemoveLocation(l)
set l=null
endfunction

//===========================================================================
function InitTrig_Revival takes nothing returns nothing
    set gg_trg_Revival = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Revival, EVENT_PLAYER_UNIT_DEATH )
    call TriggerAddCondition( gg_trg_Revival, Condition( function Trig_Revival_Conditions ) )
    call TriggerAddAction( gg_trg_Revival, function Trig_Revival_Actions )
endfunction

udg_DeadTimer is an integer array.
And the reason I use a global integer instead of a local is because I want players to be able to write -revive and that will set the global to 0.

 

[Arkan]

Hmm.. appearently it works if I remove "call RemoveLocation(l)". But doesn't that mean that it will leak?

 

[AceHart]

Your regions are stored in global variables.

Which basically means two things:
- it isn't leaking, since they are permanently stored
- if you destroy them, they are gone...

 

[Arkan]

Yeah, but I thought the local location l would be a "copy" of the real global location, so I thought I could destroy the "copy", but it destroyed the global aswell. Whatever, it works now and it should be leak free so I guess everything is alright.

 

[Capt Griffen]

Handle variables are pointers. So long as you are using natives, and don't use Create____() or Location(X,Y), then you aren't creating any new objects, and thus don't need to destroy anything. Some BJ functions create objects, however.