How to get a destructables type?

[WindexIsBack]

How do I get a destructables type? Such as 'B005' ?

I tried "GetDestructableTypeId" but that simply returned varying numbers.

If it matters, the destructables I need this on have variations. + rep for answering.

 

[AceHart]

'B005' may not look like it, but actually is an integer.

 

[WindexIsBack]

Yes, I know. How would I know a destructable is 'B005'?

What I'm doing is checking if a destructable is a specific-type of one.

 

[AceHart]

if GetDestructableTypeId( ... ) == 'B005' then?
'B005' can be seen in the Object Editor (ctrl + D).

 

[WindexIsBack]

function Trig_Debug_Actions takes nothing returns nothing
    call DisplayTextToForce(GetPlayersAll(), I2S(GetDestructableTypeId(GetDyingDestructable())))
endfunction

When I destroy a destructable however, this is what I get (Once again, these have variations..)
1110454324
With variation 0 (other destructables have different end numbers)

 

[AceHart]

Sounds about normal.
Those 'B005' integers are base 256...

Display I2S('B005'), to see.


The variations are of no importance.

function Char2Id takes string c returns integer
    local integer i = 0
    local string abc = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"
    local string t

    loop
        set t = SubString(abc,i,i + 1)
        exitwhen t == null or t == c
        set i = i + 1
    endloop
    if i < 10 then
        return i + 48
    elseif i < 36 then
        return i + 65 - 10
    endif
    return i + 97 - 36
endfunction

function String2Id takes string s returns integer
    return ((Char2Id(SubString(s,0,1)) * 256 + Char2Id(SubString(s,1,2))) * 256 + Char2Id(SubString(s,2,3))) * 256 + Char2Id(SubString(s,3,4))
endfunction

function Id2Char takes integer i returns string
    local string abc = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz"

    if i >= 97 then
        return SubString(abc,i - 97 + 36,i - 96 + 36)
    elseif i >= 65 then
        return SubString(abc,i - 65 + 10,i - 64 + 10)
    endif
    return SubString(abc,i - 48,i - 47)
endfunction

function Id2String takes integer id returns string
    local integer t = id / 256
    local string r = Id2Char(id - 256 * t)
    set id = t / 256
    set r = Id2Char(t - 256 * id) + r
    set t = id / 256
    return Id2Char(t) + Id2Char(id - 256 * t) + r
endfunction

A simple call to "string2id" or "id2string"...