Struct problems - not executing..?

[Vestras]

library SpellSystem

    // NOTICE: This system uses DAMAGE POINT!
    
    struct line
        unit c
        real x
        real y
        real tx
        real ty
        string fx
        integer n
        real dmg
        real dmgaoe
        
        static method make takes nothing returns line
            local line l = line.allocate()
            local integer i = 0
            local real dx = l.tx - l.x
            local real dy = l.ty - l.y
            local real dist = SquareRoot(dx * dx + dy * dy) / l.n
            local real angle = Atan2(l.ty - l.y, l.tx - l.x)
            local real px
            local real py
                
                loop
                    set i = i + 1
                    exitwhen i > l.n
                        set px = l.x + (dist * i) * Cos(angle)
                        set py = l.y + (dist * i) * Sin(angle)
                        call DestroyEffect(AddSpecialEffect(l.fx, px, py))
                        call UnitDamagePoint(l.c, 0, l.dmgaoe, px, py, l.dmg, false, true, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, null)
                endloop
            return l
        endmethod
        method GetLastCreatedLine takes nothing returns line
            return 0
        endmethod
    endstruct

endlibrary

As some of you might know, I have never been good at structs. Now, I'm trying to make it so that you can create different spell stuff with some structs. Somehow, my make() doesn't execute, when I do this:

library test requires SpellSystem

function Trig_test_Actions takes nothing returns nothing
    local line l = line.create()
    set l.x = GetUnitX(udg_unit[1])
    set l.y = GetUnitY(udg_unit[1])
    set l.tx = GetUnitX(udg_unit[2])
    set l.ty = GetUnitY(udg_unit[2])
    set l.fx = "Abilities\\Weapons\\ChimaeraLightningMissile\\ChimaeraLightningMissile.mdl"
    set l.n = 5
    set l.dmg = 0
    set l.dmgaoe = 0
    call l.make()
endfunction

//===========================================================================
function InitTrig_test takes nothing returns nothing
        set gg_trg_test = CreateTrigger(  )
        call TriggerAddAction( gg_trg_test, function Trig_test_Actions )
        call TimerStart(CreateTimer(), 1, false, function Trig_test_Actions)
endfunction

endlibrary

Any ideas?

 

[Forty]

what do you expect? you create a line, give him values and then run a method which creates a new line and has no values. so what should your code do?

if you want to reuse the values dont allocate a new line, but use the current (called this) so your members are called

this.fx
or even simpler
.fx

for further information look into the jasshelper manual

 

[Artificial]

The method is running.
Do you know what static methods and allocate do? I'd suppose not, because what you're doing doesn't make much sense.

.allocate
This is the same as the create method, but this one can't be overridden as create. So it creates a new instance of the struct.

So when you're doing this:

//
            local real dx = l.tx - l.x
            local real dy = l.ty - l.y
            local real dist = SquareRoot(dx * dx + dy * dy) / l.n
            local real angle = Atan2(l.ty - l.y, l.tx - l.x)

in your make method, those l.tx, l.x, l.ty, l.n, and l.y don't have any value, as you just created the struct instance l! (Well, that isn't true if the struct instance is a recycled instance, but this is what's happening for you at the moment).

You'd probably want to make the method non-static, remove the line

local line l = line.create()

and replace every instance of

l.<something>

inside the method with

.<something>

Or what I think you really should do is rename the method (to create), make it take values for the struct members, and modify the method so that it sets the values for the members.

So eg. if you'd have this:

struct astruct
    integer i
    unit u
    
    method make takes nothing returns nothing
        local integer i = .i + 5
        call KillUnit(.u)
    endmethod
endstruct

function Soo takes nothing returns nothing
    local astruct a = astruct.create()
    set a.i = 5
    set a.u = GetTriggerUnit()
    call a.make()
endfunction

It'd become this:

struct astruct
    integer i
    unit u
    
    static method create takes integer i, unit u returns astruct
        local astruct a = astruct.allocate()
        set a.i = i
        set a.u = u
        return a
    endmethod
endstruct

function Soo takes nothing returns nothing
    local astruct a = astruct.create(5, GetTriggerUnit())
endfunction

Ok, this is probably written a bit unclearly, but I hope you still understand what I said. ^_^

 

[Vestras]

Whoa, I'm worse at this than I thought, +rep'd guys!