Unit Spawned does not receive correct HP

[LearningCode]

This spell was based on Avaleirra's spell request under the GUI section.
One part of the spell is malfunctioning.

[lJASS]call SetUnitState(u, UNIT_STATE_MAX_LIFE, HP)[/lJASS]

function SpawnAct takes nothing returns nothing
   local real xC = GetUnitX(GetTriggerUnit())
   local real yC = GetUnitY(GetTriggerUnit())
   local real x
   local real y
   local real r = 100.00
   local unit u
   local real rad = (GetUnitFacing(GetTriggerUnit()) * bj_DEGTORAD)
   local integer AGI = GetHeroAgi(GetTriggerUnit(), true)
   local real HP = GetUnitState(GetTriggerUnit(), UNIT_STATE_MAX_LIFE)/2
   local integer i = 2
   local integer time = 20
   local location l
   local real SpawnHP
   set x = xC + r * Cos(rad)
   set y = yC + r * Sin(rad)
   call BJDebugMsg(R2S(HP))
   if GetUnitAbilityLevel(GetTriggerUnit(), 'A01P') > 0 then
   set u = CreateUnit(GetOwningPlayer(GetTriggerUnit()), 'nlv2', x, y, GetUnitFacing(GetTriggerUnit()))
      call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y))
      call SetUnitState(u, UNIT_STATE_MAX_LIFE, HP)
   elseif GetUnitAbilityLevel(GetTriggerUnit(), 'A01T') > 0 then
      call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\NightElf\\Starfall\\StarfallCaster.mdl", x, y))
      set u = CreateUnit(GetOwningPlayer(GetTriggerUnit()), 'nlv3', x, y, GetUnitFacing(GetTriggerUnit()))
      call SetUnitState(u, UNIT_STATE_MAX_LIFE, HP)
   endif
   call UnitAddAbility(u, 'AInv')
   loop
   exitwhen i == AGI
        call UnitAddItemById(u, 'I001')
        set i = i+1
   endloop
   call UnitRemoveAbility(u, 'AInv')
   loop
    exitwhen time == 0
        set l = GetUnitLoc(u)
        call TriggerSleepAction(1.00)
        call CreateTextTagLocBJ( I2S(time), l, 0, 10, 10, 80, 10, 0 )
        call SetTextTagLifespanBJ( bj_lastCreatedTextTag, 0.50 )
        call SetTextTagPermanentBJ( bj_lastCreatedTextTag, false )
        call RemoveLocation(l)
        set l = null
        set time = time-1
   endloop
   if GetWidgetLife(u)>=4.05 then
        call SetUnitOwner(u, Player(12), true)
        set SpawnHP = GetUnitState(u, UNIT_STATE_MAX_LIFE)/200
        set AGI = AGI + R2I(SpawnHP)
        call SetHeroAgi(GetTriggerUnit(), AGI, true)
        set l = GetUnitLoc(GetTriggerUnit())
        call TriggerSleepAction(1.00)
        call CreateTextTagLocBJ( "+"+I2S(R2I(SpawnHP))+" AGI", l, 0, 10, 100, 80, 80, 0 )
        call SetTextTagLifespanBJ( bj_lastCreatedTextTag, 1.50 )
        call SetTextTagPermanentBJ( bj_lastCreatedTextTag, false )
        call RemoveLocation(l)
        set l = null
   endif
endfunction

function SpawnCond takes nothing returns boolean
   return GetSpellAbilityId() == 'A020'
endfunction

//===========================================================================
function InitTrig_Spawn takes nothing returns nothing
    local trigger t = CreateTrigger(  )
    local integer i = 0
    loop
    exitwhen i == 8
    call TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
    set i = i+1
    endloop
    call TriggerAddCondition(t, Condition(function SpawnCond))
    call TriggerAddAction( t, function SpawnAct )
endfunction

To be more accurate:

   local real HP = GetUnitState(GetTriggerUnit(), UNIT_STATE_MAX_LIFE)/2
   
   call BJDebugMsg(R2S(HP))
   if GetUnitAbilityLevel(GetTriggerUnit(), 'A01P') > 0 then
   set u = CreateUnit(GetOwningPlayer(GetTriggerUnit()), 'nlv2', x, y, GetUnitFacing(GetTriggerUnit()))
      call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y))
      call SetUnitState(u, UNIT_STATE_MAX_LIFE, HP)
   elseif GetUnitAbilityLevel(GetTriggerUnit(), 'A01T') > 0 then
      call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\NightElf\\Starfall\\StarfallCaster.mdl", x, y))
      set u = CreateUnit(GetOwningPlayer(GetTriggerUnit()), 'nlv3', x, y, GetUnitFacing(GetTriggerUnit()))
      call SetUnitState(u, UNIT_STATE_MAX_LIFE, HP)
   endif

When my hero has 3550 HP and casts the spell, BJDebugMsg shows me 1775.00 (Correct) but my Spawn has only 1 hp

When my hero has 1800 HP and casts the spell, BJDebugMsg shows me 900.00 (Correct) but my Spawn has only 1 hp

My spawn always has 1 hp and I can't fix that =/
The object editor (By default) gives the spawn 1hp

 

[millz-]

I don't think it's possible to simply set a unit's max life like that. You would have to use abilities, either tomes or +hp item abilities.

 

[LearningCode]

I used tomes in the end =x

Haiz

 

[kingkingyyk3]

Tomes will leave a "dummy" after the hero use it, call a RemoveItem(tome) to prevent lag due to too many tomes "dummy" on map.

 

[ZugZugZealot]

[ljass]UNIT_STATE_MAX_LIFE[/ljass] is for this...

GetUnitState( whichUnit, UNIT_STATE_MAX_LIFE )

So you can be all like [ljass]call SetUnitState( whichUnit, UNIT_STATE_LIFE, GetUnitState( whichUnit, UNIT_STATE_MAX_LIFE ) )[/ljass] for a full (100%) heal.

The fact you can't set max health that way definitely does suck. But at least there are work arounds.

 

[LearningCode]

Tomes leave dummies? o.0
Oh lord..

What if I made 1775 HP tome dummies and 100+ damage tome dummies? xD
I didn't notice the lag, but I'll do it =x

 

[Narks]

Don't use tomes. You will leak items (i think items have that funky glitch like units where if you create one you leak memory no matter what)

 

[LearningCode]

Then..
Can't I follow kingyk's idea to remove the tomes?

Or is there a better alternative for setting a Spawned monster's Stats (HP and Attack)?

 

[millz-]

I personally have an ability in my map that increases a unit's max HP when learned. I use item ability that adds hp for it.

 

[LearningCode]

But they said it leaks =/
I don't want leaky leaks =(

 

[millz-]

Why would ability leak? I use UnitAddAbility to add the hp bonus ABILITY.

 

[kingkingyyk3]

library LeaklessTome initializer Init

    globals
        private item Tome = null
        private timer t = CreateTimer()
    endglobals
    
    private function RemoveTome takes nothing returns nothing
        if GetWidgetLife(Tome) < .405 then
            call RemoveItem(Tome)
        endif
        set Tome = null
    endfunction
    
    private function Cond takes nothing returns boolean
        set Tome = GetManipulatedItem()
        call TimerStart(t,0.,false,function RemoveTome)
        return false
    endfunction
    
    private function Init takes nothing returns nothing
        local trigger trig = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(trig, EVENT_PLAYER_UNIT_PICKUP_ITEM)
        call TriggerAddCondition(trig,Condition(function Cond))
    endfunction
    
endlibrary

Hmm, the better solution is make hp bonus abilities(which you can find from item section) for spawns.