Problems with BuffStruct&SpellStruct

I

Immolation

Member
Reaction score
20
JASS:
scope LightningStrike

    globals
        private constant integer ABILITY_ID = 'A006'
    endglobals
    
    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true)) * (0.8 + 0.2 * GetUnitAbilityLevel(caster, ABILITY_ID))
    endfunction
    
    private function Duration takes unit caster returns real
        return 10. + 2. * GetUnitAbilityLevel(caster, ABILITY_ID) + I2R(GetHeroInt(caster, true))
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct

        method onEffect takes nothing returns nothing
            local LightningStrike a = LightningStrike.create(caster)
            set a.damage = Damage(caster)
            call a.destroyTimed(Duration(caster))
        endmethod
            
        private static method onInit takes nothing returns nothing
            set thistype.abil = ABILITY_ID
        endmethod
    endstruct
endscope

JASS:
//! runtextmacro BuffType("LightningStrike")
    //! runtextmacro SetBuffName("Lightning Strike")
    //! runtextmacro SetBuffAlignment("POSITIVE")
    //! runtextmacro SetBuffTooltip("This unit is enhanced with lightning; its next attack will deal splashing damage.")
    //! runtextmacro SetBuffIcon("ReplaceableTextures\\CommandButtons\\BTNStormHammer.blp")
//! runtextmacro BuffStruct()
    private effect e
    real damage
    method onApply takes nothing returns nothing
        set this.e = AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", this.unit, "weapon")
    endmethod
    method onDamageDealt takes nothing returns nothing
        if Damage_IsAttack() then
            call Damage_Spell(this.unit, GetTriggerUnit(), .damage)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", GetTriggerUnit(), "chest"))
            call .setUnit(null)
        endif
    endmethod
    method onRemove takes nothing returns nothing
        call DestroyEffect(this.e)
    endmethod
//! runtextmacro EndBuff()


So I got these two triggers here, but I got two problems with them:
1) The buff doesn't appear on the unit. (EDIT: Restarting NewGen seemed to fix it.)
2) If I use the ability again, the effect is created twice instead of cancelling the other instance. How to solve this?
 
Laiev

Laiev

Hey Listen!!
Reaction score
188
2) check if the unit already got the buff, if yes, don't create, or destroy old and create a new
 
saw792

saw792

Is known to say things. That is all.
Reaction score
280
Now that I am thinking straight and it is no longer 3am:
JASS:
//! runtextmacro BuffType("LightningStrike")
    //! runtextmacro SetBuffName("Lightning Strike")
    //! runtextmacro SetBuffAlignment("POSITIVE")
    //! runtextmacro SetBuffTooltip("This unit is enhanced with lightning; its next attack will deal splashing damage.")
    //! runtextmacro SetBuffIcon("ReplaceableTextures\\CommandButtons\\BTNStormHammer.blp")
//! runtextmacro BuffStruct()
    private effect e
    real damage
    method onApply takes nothing returns nothing
        local TrackLightning t = TrackLightning[.unit]
        if t.lastinstance != 0 then
            call t.lastinstance.setUnit(null)
        endif
        set t.lastinstance = this
        set this.e = AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", this.unit, "weapon")
    endmethod
    method onDamageDealt takes nothing returns nothing
        if Damage_IsAttack() then
            call Damage_Spell(this.unit, GetTriggerUnit(), .damage)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", GetTriggerUnit(), "chest"))
            call .setUnit(null)
        endif
    endmethod
    method onRemove takes nothing returns nothing
        set TrackLightning[.unit].lastinstance = 0
        call DestroyEffect(this.e)
    endmethod
//! runtextmacro EndBuff()

struct TrackLightning extends array
  //! runtextmacro AIDS()
  LightningStrike lastinstance

  method AIDS_onCreate takes nothing returns nothing
    set .lastinstance = 0
  endmethod

endstruct
 
I

Immolation

Member
Reaction score
20
@Laeiv, @13lade619
I do know that I have to check for the buff, but I don't know how.

@saw792
Thanks for the help, your trigger works(effect is destroyed) but the buff icon is removed upon casting the second time.
 
Jesus4Lyf

Jesus4Lyf

Good Idea™
Reaction score
397
Immolation said:
@saw792
Thanks for the help, your trigger works(effect is destroyed) but the buff icon is removed upon casting the second time.
Click to expand...
If a buff goes on a unit twice, and then one instance is removed, there is a bug that will remove the icon. It is a known BuffStruct bug which will be fixed somewhere after July 23 when I get time. :)
JASS:
//          Use .isOn(unit) --> boolean to see if a buff is on a unit.

From the BuffStruct documentation.

I haven't read the whole thread, just throwing in two cents. If it's not resolved I'll look into it properly. :)
 
I

Immolation

Member
Reaction score
20
Ok, so I decided to screw BuffStruct for now, waiting for an update :mad: xD
I'll stick with SpellStruct :p

Anyway, I now got a problem with this trigger:
JASS:

scope LightningStrike

    globals
        private constant integer Ability_ID = 'A006'
        private constant integer Buff_ID = 'B000'
        private constant real Duration = 5.00
        private constant real Radius = 236
        
        private constant string SfxOnDamaged = "Abilities\\Weapons\\Bolt\\BoltImpact.mdl"
    endglobals
    
    globals
        private unit Caster
    endglobals

    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true) + GetHeroInt(caster,true)) * (1.6 + 0.4 * GetUnitAbilityLevel(caster, Ability_ID))
    endfunction
    
    private function Splash takes unit caster returns real
        return 0.45 + 0.05 * GetUnitAbilityLevel(caster, Ability_ID)
    endfunction

    private function IsValidEnemy takes nothing returns boolean
        return IsUnitAlive(GetFilterUnit()) == true and IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(Caster)) == true
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct
    
        private method onDamage takes nothing returns nothing
            local unit damagedUnit = GetTriggerUnit()
            local unit current
            set Caster = GetEventDamageSource()
            if Damage_IsPhysical() and GetUnitAbilityLevel(Caster, Buff_ID) > 0 then
                call UnitRemoveAbility(Caster, Buff_ID)
                call Damage_Physical(Caster, damagedUnit, Damage(Caster), ATTACK_TYPE_HERO, false, false)
                call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", damagedUnit, "origin"))
                call GroupEnumUnitsInRange(GROUP, GetUnitX(damagedUnit), GetUnitY(damagedUnit), Radius, Filter(function IsValidEnemy))
                call GroupRemoveUnit(GROUP, damagedUnit)
                loop
                    set current = FirstOfGroup(GROUP)
                    exitwhen current == null
                    call Damage_Physical(Caster, current, (Damage(Caster) + GetEventDamage()) * Splash(Caster), ATTACK_TYPE_HERO, false, false)
                    call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", current, "origin"))
                    call GroupRemoveUnit(GROUP, current)
                    set current = null
                endloop 
            endif
        endmethod
            
        private method timerCallback takes nothing returns nothing
            call this.stopTimer(thistype.timerCallback)
            call UnitRemoveAbility(caster, Buff_ID)
        endmethod

        private method onEffect takes nothing returns nothing
            call this.startTimer(thistype.timerCallback, Duration)
            call Damage_RegisterEvent(this.createTrigger(thistype.onDamage))
        endmethod

        private static method onInit takes nothing returns nothing
            set thistype.abil = Ability_ID
        endmethod

    endstruct
endscope


The problem lies when I cast the spell again while it's still activated.
How can I stop the other timer from running its callback and thus removing the buff?
 
Jesus4Lyf

Jesus4Lyf

Good Idea™
Reaction score
397
You could store the spell instance on the unit using AIDS, and then call SomeAidsStruct[Caster].theSpellInstance.stopTimer(thistype.timerCallback) to stop the already running instance. Then overwrite with the instance attached to AIDS? Something like that may do it.

Actually, this looks fun to write. I might give it a shot myself when I get a chance. SpellStruct has built in AoE functionality which could shrink this down a lot, I reckon. :)

You know within the timer callback you can refer to the caster of the spell with just .caster? :p

You can also just .destroy() a spell instance at any point, which will stop all timers and destroy all triggers created for it. :)
 
I

Immolation

Member
Reaction score
20
I got no clue as to how to use AIDS :p

Also, SpellStruct has AoE functionality, but my spell has no target. Well, it has, but only when the unit is damaged, so I can't use this.forUnitsInRangeTarget, since there's no target automatically set by SpellStruct.

New code(with .caster):
JASS:
scope LightningStrike

    globals
        private constant integer Ability_ID = 'A006'
        private constant integer Buff_ID = 'B000'
        private constant real Duration = 5.00
        private constant real Radius = 236
        
        private constant string SfxOnDamaged = "Abilities\\Weapons\\Bolt\\BoltImpact.mdl"
    endglobals
    
    globals
        private unit Caster
    endglobals

    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true) + GetHeroInt(caster,true)) * (1.6 + 0.4 * GetUnitAbilityLevel(caster, Ability_ID))
    endfunction
    
    private function Splash takes unit caster returns real
        return 0.45 + 0.05 * GetUnitAbilityLevel(caster, Ability_ID)
    endfunction

    private function IsValidEnemy takes nothing returns boolean
        return IsUnitAlive(GetFilterUnit()) == true and IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(Caster)) == true
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct
    
        private method onDamage takes nothing returns nothing
            local unit damagedUnit = GetTriggerUnit()
            local unit current
            set Caster = GetEventDamageSource()
            if Damage_IsPhysical() and GetUnitAbilityLevel(Caster, Buff_ID) > 0 then
                call UnitRemoveAbility(Caster, Buff_ID)
                call Damage_Physical(Caster, damagedUnit, Damage(Caster), ATTACK_TYPE_HERO, false, false)
                call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", damagedUnit, "origin"))
                call GroupEnumUnitsInRange(GROUP, GetUnitX(damagedUnit), GetUnitY(damagedUnit), Radius, Filter(function IsValidEnemy))
                call GroupRemoveUnit(GROUP, damagedUnit)
                loop
                    set current = FirstOfGroup(GROUP)
                    exitwhen current == null
                    call Damage_Physical(Caster, current, (Damage(Caster) + GetEventDamage()) * Splash(Caster), ATTACK_TYPE_HERO, false, false)
                    call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", current, "origin"))
                    call GroupRemoveUnit(GROUP, current)
                    set current = null
                endloop 
            endif
        endmethod
            
        private method timerCallback takes nothing returns nothing
            call this.stopTimer(thistype.timerCallback)
            call UnitRemoveAbility(.caster, Buff_ID)
        endmethod

        private method onEffect takes nothing returns nothing
            if GetUnitAbilityLevel(caster, Buff_ID) > 0 then
                call this.stopTimer(thistype.timerCallback)
                call UnitRemoveAbility(caster, Buff_ID)
            else
                call this.startTimer(thistype.timerCallback, Duration)
            endif
            call Damage_RegisterEvent(this.createTrigger(thistype.onDamage))
        endmethod

        private static method onInit takes nothing returns nothing
            set thistype.abil = Ability_ID
        endmethod
    endstruct
endscope


My spell looks fun to code? Why thanks :D
 
13lade619

13lade619

is now a game developer :)
Reaction score
398
JASS:
scope LightningStrike

    globals
        private constant integer ABILITY_ID = 'A006'
    endglobals
    
    //! runtextmacro PUI_PROPERTY("", "boolean", "LSActive", "false")
    
    //^ that does work. a global AIDS variable... so you can use it in the buffstruct.
    //^ i use those stuff in my map.
    
    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true)) * (0.8 + 0.2 * GetUnitAbilityLevel(caster, ABILITY_ID))
    endfunction
    
    private function Duration takes unit caster returns real
        return 10. + 2. * GetUnitAbilityLevel(caster, ABILITY_ID) + I2R(GetHeroInt(caster, true))
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct

        method onEffect takes nothing returns nothing
            local LightningStrike a 
        
            if not LSActive[.caster] then
                set LSActive[.caster] = true
                set a = LightningStrike.create(.caster)
                set a.damage = Damage(.caster)
                call a.destroyTimed(Duration(caster))
            endif
        
        endmethod
            
        private static method onInit takes nothing returns nothing
            set thistype.abil = ABILITY_ID
        endmethod
    endstruct
endscope

JASS:
//! runtextmacro BuffType("LightningStrike")
    //! runtextmacro SetBuffName("Lightning Strike")
    //! runtextmacro SetBuffAlignment("POSITIVE")
    //! runtextmacro SetBuffTooltip("This unit is enhanced with lightning; its next attack will deal splashing damage.")
    //! runtextmacro SetBuffIcon("ReplaceableTextures\\CommandButtons\\BTNStormHammer.blp")
//! runtextmacro BuffStruct()
    effect e
    real damage
    boolean finished
    method onApply takes nothing returns nothing
        set this.e = AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", this.unit, "weapon")
        set this.finished = false
    endmethod
    method onDamageDealt takes nothing returns nothing
        if Damage_IsAttack() and not this.finished then
            set this.finished = true
            set LSActive[this.unit] = false
            //used the AIDS from before.
            call Damage_Spell(this.unit, GetTriggerUnit(), this.damage)
            //
            //  Group stuff here.. haha.
            //
            //
            //
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", GetTriggerUnit(), "chest"))
            call DestroyEffect(this.e)
        endif
    endmethod
//! runtextmacro EndBuff()

.
 
I

Immolation

Member
Reaction score
20
Well, actually I was looking for a soluction without using BuffStruct. Its downsides are more than the upsides in my case. So...
 
Jesus4Lyf

Jesus4Lyf

Good Idea™
Reaction score
397
I told you this looks fun to code...
Here's one with BuffStruct, because I want to demonstrate PUI property with a BuffStruct instance. And using TU to make an extendable buff duration. :)
JASS:
//! runtextmacro PUI_PROPERTY("", "LightningStrike", "CurrentLightningStrike", "LightningStrike(0)")

//! runtextmacro BuffType("LightningStrike")
    //! runtextmacro SetBuffName("Lightning Strike")
    //! runtextmacro SetBuffAlignment("POSITIVE")
    //! runtextmacro SetBuffTooltip("This unit is enhanced with lightning; its next attack will deal splashing damage.")
    //! runtextmacro SetBuffIcon("ReplaceableTextures\\CommandButtons\\BTNStormHammer.blp")
//! runtextmacro BuffStruct()
    private effect e
    real damage = 0.
    method onApply takes nothing returns nothing
        set this.e = AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", this.unit, "weapon")
        set CurrentLightningStrike[unit]=this
    endmethod
    method onDamageDealt takes nothing returns nothing
        if Damage_IsAttack() then
            call Damage_Spell(this.unit, GetTriggerUnit(), .damage)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\FarseerMissile\\FarseerMissile.mdl", GetTriggerUnit(), "chest"))
            call .setUnit(null)
        endif
    endmethod
    method onRemove takes nothing returns nothing
        call DestroyEffect(this.e)
        set CurrentLightningStrike[unit]=thistype(0)
    endmethod
    
    // simple logic to allow extension of a buff's duration.
    private static method onExpire takes nothing returns nothing
        local thistype this=thistype(GetTimerData(GetExpiredTimer()))
        call this.destroy()
    endmethod
    private timer destroyTimer
    method onCreate takes nothing returns nothing
        set destroyTimer=NewTimer()
        call SetTimerData(destroyTimer,this)
    endmethod
    method preDestroy takes nothing returns nothing
        call ReleaseTimer(destroyTimer)
    endmethod
    method operator duration= takes real timeLeft returns nothing
        call PauseTimer(destroyTimer)
        call TimerStart(destroyTimer,timeLeft,false,function thistype.onExpire)
    endmethod
//! runtextmacro EndBuff()

scope LightningStrike

    globals
        private constant integer ABILITY_ID = 'A006'
    endglobals
    
    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true)) * (0.8 + 0.2 * GetUnitAbilityLevel(caster, ABILITY_ID))
    endfunction
    
    private function Duration takes unit caster returns real
        return 10. + 2. * GetUnitAbilityLevel(caster, ABILITY_ID) + I2R(GetHeroInt(caster, true))
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct

        method onEffect takes nothing returns nothing
            local LightningStrike a = CurrentLightningStrike[caster]
            if a==0 then
                set a=LightningStrike.create(caster)
            endif
            set a.damage = a.damage + Damage(caster)
            set a.duration = Duration(caster)
        endmethod
            
        private static method onInit takes nothing returns nothing
            set thistype.abil = ABILITY_ID
        endmethod
    endstruct
endscope


Ok, and here's just a modification of your code, which strips out the Caster global. :)
JASS:
scope LightningStrike

    globals
        private constant integer Ability_ID = 'A006'
        private constant integer Buff_ID = 'B000'
        private constant real Duration = 5.00
        private constant real Radius = 236
        
        private constant string SfxOnDamaged = "Abilities\\Weapons\\Bolt\\BoltImpact.mdl"
    endglobals

    private function Damage takes unit caster returns real
        return I2R(GetHeroAgi(caster, true) + GetHeroStr(caster, true) + GetHeroInt(caster,true)) * (1.6 + 0.4 * GetUnitAbilityLevel(caster, Ability_ID))
    endfunction
    
    private function Splash takes unit caster returns real
        return 0.45 + 0.05 * GetUnitAbilityLevel(caster, Ability_ID)
    endfunction

    private struct Spell extends SpellStruct
        implement SpellStruct
        
        private method damageSplash takes unit splashTarget returns nothing
            if IsUnitAlive(GetFilterUnit()) == true and IsUnitEnemy(splashTarget, GetOwningPlayer(caster)) == true then
                call Damage_Physical(caster, splashTarget, (Damage(caster) + GetEventDamage()) * Splash(caster), ATTACK_TYPE_HERO, false, false)
                call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", splashTarget, "origin"))
            endif
        endmethod
    
        private method onDamage takes nothing returns nothing
            local unit damagedUnit = GetTriggerUnit()
            local unit current
            if Damage_IsPhysical() and GetUnitAbilityLevel(caster, Buff_ID) > 0 then
                call UnitRemoveAbility(caster, Buff_ID)
                call Damage_Physical(caster, damagedUnit, Damage(caster), ATTACK_TYPE_HERO, false, false)
                call DestroyEffect(AddSpecialEffectTarget("Abilities\\Weapons\\Bolt\\BoltImpact.mdl", damagedUnit, "origin"))
                call GroupEnumUnitsInRange(GROUP, GetUnitX(damagedUnit), GetUnitY(damagedUnit), Radius, null) // shouldn&#039;t use null. Should use &quot;TRUE&quot;, or something. <img src="data:image/gif;base64,R0lGODlhAQABAIAAAAAAAP///yH5BAEAAAAALAAAAAABAAEAAAIBRAA7" class="smilie smilie--sprite smilie--sprite1" alt=":)" title="Smile    :)" loading="lazy" data-shortname=":)" />
                call GroupRemoveUnit(GROUP, damagedUnit)
                call forGroup(GROUP, damageSplash)
            endif
        endmethod
            
        private method timerCallback takes nothing returns nothing
            call this.stopTimer(thistype.timerCallback)
            call UnitRemoveAbility(.caster, Buff_ID)
        endmethod

        private method onEffect takes nothing returns nothing
            if GetUnitAbilityLevel(caster, Buff_ID) &gt; 0 then
                call this.stopTimer(thistype.timerCallback)
                call UnitRemoveAbility(caster, Buff_ID)
            else
                call this.startTimer(thistype.timerCallback, Duration)
            endif
            call Damage_RegisterEvent(this.createTrigger(thistype.onDamage))
        endmethod

        private static method onInit takes nothing returns nothing
            set thistype.abil = Ability_ID
        endmethod
    endstruct
endscope

And yes, I intend to add all the fancy SpellStruct stuff to BuffStruct, like damage in AoE, etc. I just haven't, yet. This will become a lot faster in BuffStruct once I do, obviously. :p

Edit:
Was there anything else you wanted this to do? Or does that do it...
 
I

Immolation

Member
Reaction score
20
Your code with Buffstruct works perfectly! Thanks! :)
Though, could you explain what you're doing there?
Especially this line:
JASS:
//! runtextmacro PUI_PROPERTY(&quot;&quot;, &quot;LightningStrike&quot;, &quot;CurrentLightningStrike&quot;, &quot;LightningStrike(0)&quot;)


Also, how do I make the same for all my buffs?
 
You must log in or register to reply here.
General chit-chat
Help Users
  • No one is chatting at the moment.
  • WildTurkey WildTurkey:
    is there a stephen green in the house?
     +1
  • The Helper The Helper:
    What is up WildTurkey?
  • The Helper The Helper:
    Looks like Google fixed whatever mistake that made the recipes on the site go crazy and we are no longer trending towards a recipe site lol - I don't care though because it motivated me to spend alot of time on the site improving it and at least now the content people are looking at is not stupid and embarrassing like it was when I first got back into this like 5 years ago.
  • The Helper The Helper:
    Plus - I have a pretty bad ass recipe collection now! That section of the site is 10 thousand times better than it was before
  • The Helper The Helper:
    We now have a web designer at my job. A legit talented professional! I am going to get him to redesign the site theme. It is time.
  • Varine Varine:
    I got one more day of community service and then I'm free from this nonsense! I polished a cop car today for a funeral or something I guess
  • Varine Varine:
    They also were digging threw old shit at the sheriff's office and I tried to get them to give me the old electronic stuff, but they said no. They can't give it to people because they might use it to impersonate a cop or break into their network or some shit? idk but it was a shame to see them take a whole bunch of radios and shit to get shredded and landfilled
  • The Helper The Helper:
    whatever at least you are free
  • The Helper The Helper:
    Here is a cool dessert recipe I found https://www.thehelper.net/threads/recipe-cherry-cheesecake-brownie.194048/
  • The Helper The Helper:
    Found a cool easy Chicken Pot Pie recipe! https://www.thehelper.net/threads/recipe-chicken-pot-pie.194064/
  • Monovertex Monovertex:
    How are you all? :D
     +1
  • Ghan Ghan:
    Howdy
  • Ghan Ghan:
    Still lurking
     +3
  • The Helper The Helper:
    I am great and it is fantastic to see you my friend!
     +1
  • The Helper The Helper:
    Here is a great appetizer recipe Texas style! https://www.thehelper.net/threads/recipe-chicken-stuffed-poblano-peppers.194086/
  • The Helper The Helper:
    If you are new to the site please check out the Recipe and Food Forum https://www.thehelper.net/forums/recipes-and-food.220/
  • Monovertex Monovertex:
    How come you're so into recipes lately? Never saw this much interest in this topic in the old days of TH.net
  • Monovertex Monovertex:
    Hmm, how do I change my signature?
  • tom_mai78101 tom_mai78101:
    Signatures can be edit in your account profile. As for the old stuffs, I'm thinking it's because Blizzard is now under Microsoft, and because of Microsoft Xbox going the way it is, it's dreadful.
  • The Helper The Helper:
    I am not big on the recipes I am just promoting them - I use the site as a practice place promoting stuff
     +2
  • Monovertex Monovertex:
    @tom_mai78101 I must be blind. If I go on my profile I don't see any area to edit the signature; If I go to account details (settings) I don't see any signature area either.
  • The Helper The Helper:
    You can get there if you click the bell icon (alerts) and choose preferences from the bottom, signature will be in the menu on the left there https://www.thehelper.net/account/preferences
  • The Helper The Helper:
    I think I need to split the Sci/Tech news forum into 2 one for Science and one for Tech but I am hating all the moving of posts I would have to do
  • The Helper The Helper:
    New dessert for Summer - https://www.thehelper.net/threads/recipe-lemon-blueberry-layer-cheesecake.194113/
  • The Helper The Helper:
    What is up Old Mountain Shadow?

      The Helper Discord

      Members online

      No members online now.
      Online now:
      284 (members: 0, guests: 284)

      Share this page

      Affiliates

      Hive Workshop NUON Dome World Editor Tutorials

      Network Sponsors

      Apex Steel Pipe - Buys and sells Steel Pipe.
      Top