'Damage' (System) Help

[WolfieeifloW]

Hey there.
I've just 'installed' Damage, and am trying to convert all my spells over and I've already ran into problems ().
I've created a 'DamageText' system to pair up with the Damage system.
It's here:

scope DamageText initializer init
    
    private function Conditions takes nothing returns boolean
        local texttag tt
        
        set tt = CreateTextTag()
        call SetTextTagText(tt, I2S(R2I(GetEventDamage())), 8 * 0.023 / 10)
        call SetTextTagPosUnit(tt, GetTriggerUnit(), 0.)
        if (Damage_IsAttack()) then
            call SetTextTagColor(tt, 255, 255, 255, 255)
        elseif (Damage_IsSpell()) then
            call SetTextTagColor(tt, 255, 255, 0, 255)
        endif
        call SetTextTagPermanent(tt, false)
        call SetTextTagLifespan(tt, 2)
        call SetTextTagFadepoint(tt, 1)
        call SetTextTagVelocity(tt, 0, 0.05)
        set tt = null
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction
        
endscope

Now, I'm trying to convert my Death Coil spell over, so I set the damage in the Object Editor to 0.
I then created this code:

scope DeathCoilDK initializer init

    private function Damage takes integer level returns real
        return level * 10.
    endfunction

    private function Conditions takes nothing returns boolean
        call BJDebugMsg("Att: " + GetUnitName(GetAttacker()))
        call BJDebugMsg("EDS: " + GetUnitName(GetEventDamageSource()))
        call BJDebugMsg("Def: " + GetUnitName(GetTriggerUnit()))
        
        if (GetSpellAbilityId() == deathCoilDK) then
            call Damage_Spell(GetEventDamageSource(), GetTriggerUnit(), Damage(GetUnitAbilityLevel(GetEventDamageSource(), deathCoilDK)))
        endif
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterZeroEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction

endscope

No floating text is created, and the BJ's show this:

Att:
EDS:
Def: TargetUnit

So, I went ahead and set the damage of the Death Coil in the OE to 1, and tried the 'normal' event:

scope DeathCoilDK initializer init

    private function Damage takes integer level returns real
        return (level * 10.) - 1
    endfunction

    private function Conditions takes nothing returns boolean
        call BJDebugMsg("Att: " + GetUnitName(GetAttacker()))
        call BJDebugMsg("EDS: " + GetUnitName(GetEventDamageSource()))
        call BJDebugMsg("Def: " + GetUnitName(GetTriggerUnit()))
        
        if (GetSpellAbilityId() == deathCoilDK) then
            call Damage_Spell(GetEventDamageSource(), GetTriggerUnit(), Damage(GetUnitAbilityLevel(GetEventDamageSource(), deathCoilDK)))
        endif
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction

endscope

Note the change to the Damage function.
It now shows floating text that says '0', but the BJ's display the same thing.

What am I doing wrong?

 

[Ayanami]

Your code has some problems.

scope DeathCoilDK initializer init

    private function Damage takes integer level returns real
        return level * 10.
    endfunction

    private function Conditions takes nothing returns boolean
        call BJDebugMsg("Att: " + GetUnitName(GetAttacker())) // a damage event doesn't have an attacker, only damage source (GetEventDamageSource()) and damaged unit (GetTriggerUnit())
        call BJDebugMsg("EDS: " + GetUnitName(GetEventDamageSource())) // i'm not sure why this isn't showing :/
        call BJDebugMsg("Def: " + GetUnitName(GetTriggerUnit())) // works fine I presume
        
        if (GetSpellAbilityId() == deathCoilDK) then // in a damage event, you can't have GetSpellAbilityId(), as the event doesn't refer to any ability cast, etc
            call Damage_Spell(GetEventDamageSource(), GetTriggerUnit(), Damage(GetUnitAbilityLevel(GetEventDamageSource(), deathCoilDK)))
        endif
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterZeroEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction

endscope

Instead of detecting for zero damage, why not just deal damage directly from the first place?

scope DeathCoil initializer OnInit
    globals
        private constant integer ABILID = 'A000' // raw code of Death Coil
    endglobals

    private function OnCast takes nothing returns boolean
        call Damage_Spell(GetTriggerUnit(), GetSpellTargetUnit(), 100.) // deal the damage

        return false
    endfunction

    private function OnInit takes nothing returns nothing
        local trigger t = CreateTrigger()
        call GT_RegisterStartsEffectEvent(t, ABILID)
        call TriggerAddCondition(t, Condition(function OnCast))
        set t = null
    endfunction
endscope

Note that I used GTrigger. I recommend you use it too if you aren't.

 

[tooltiperror]

GTrigger is a lot of bloat for stuff most people don't need, but I can't complain about that...

Anyways, Glenphir, you should be inlining your GT calls I guess, that's what the kids do these days, since GT_RegisterXEvent returns the trigger passed in.

private function onInit takes nothing returns nothing
    call TriggerAddCondition(GT_RegisterStartsEffectEvent(CreateTrigger(), ABILID)), Condition(function OnCast))
endfunction

Also, nowadays it's onEvent, not OnEvent.

 

[WolfieeifloW]

Do I need GTrigger?
I have Event (Obviously, a requirement of Damage).
Is there anyway to use what I already have as to avoid another system?

 

[tooltiperror]

Don't try to avoid adding systems. That is foolish, and leads to making worse code.

GTrigger is really good. Let's say you have 50 spells in your map, as I assume you have something around that.

16 events generated per spell, that's 800 events being created.
With 50 spells, you are running 50 events every time a player casts any spell.

The solution is to use a trigger array, each trigger unique to a Spell ID. Or, to be simpler, use GTrigger. It's a really good system, and saves you a lot of events.

 

[Ayanami]

GTrigger is a lot of bloat for stuff most people don't need, but I can't complain about that...

Anyways, Glenphir, you should be inlining your GT calls I guess, that's what the kids do these days, since GT_RegisterXEvent returns the trigger passed in.

private function onInit takes nothing returns nothing
    call TriggerAddCondition(GT_RegisterStartsEffectEvent(CreateTrigger(), ABILID)), Condition(function OnCast))
endfunction

Also, nowadays it's onEvent, not OnEvent.

I thought camel casing is for methods only? I always thought functions are capital case for the first letter @_@

 

[Laiev]

most of system just don't care about the init function name, they use

function Init takes nothing returns nothing

or

function init takes nothing returns nothing

 

[WolfieeifloW]

It semi-works now.
It deals damage correctly, but the damage text shows a yellow "10", and then a white "0".
How would I fix this? Maybe stop zero damage events from triggering the DamageText?

Here's the Death Coil script:

scope DeathCoilDK initializer onInit

    private function Damage takes integer level returns real
        return level * 10.
    endfunction

    private function onCast takes nothing returns boolean
        call Damage_Spell(GetTriggerUnit(), GetSpellTargetUnit(), Damage(GetUnitAbilityLevel(GetTriggerUnit(), deathCoilDK)))
        return false
    endfunction

    private function onInit takes nothing returns nothing
        call TriggerAddCondition(GT_RegisterStartsEffectEvent(CreateTrigger(), deathCoilDK), Condition(function onCast))
    endfunction

endscope

Here's the DamageText script:

scope DamageText initializer init
    
    private function Conditions takes nothing returns boolean
        local texttag tt
        
        set tt = CreateTextTag()
        call SetTextTagText(tt, I2S(R2I(GetEventDamage())), 8 * 0.023 / 10)
        call SetTextTagPosUnit(tt, GetTriggerUnit(), 0.)
        if (Damage_IsAttack()) then
            call SetTextTagColor(tt, 255, 255, 255, 255)
        elseif (Damage_IsSpell()) then
            call SetTextTagColor(tt, 255, 255, 0, 255)
        endif
        call SetTextTagPermanent(tt, false)
        call SetTextTagLifespan(tt, 2)
        call SetTextTagFadepoint(tt, 1)
        call SetTextTagVelocity(tt, 0, 0.05)
        set tt = null
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction
        
endscope

 

[Ayanami]

This:

scope DamageText initializer init
    
    private function Conditions takes nothing returns boolean
        local texttag tt
        
        if GetEventDamage() > 0 then
            set tt = CreateTextTag()
            call SetTextTagText(tt, I2S(R2I(GetEventDamage())), 8 * 0.023 / 10)
            call SetTextTagPosUnit(tt, GetTriggerUnit(), 0.)
            if (Damage_IsAttack()) then
                call SetTextTagColor(tt, 255, 255, 255, 255)
            elseif (Damage_IsSpell()) then
                call SetTextTagColor(tt, 255, 255, 0, 255)
            endif
            call SetTextTagPermanent(tt, false)
            call SetTextTagLifespan(tt, 2)
            call SetTextTagFadepoint(tt, 1)
            call SetTextTagVelocity(tt, 0, 0.05)
        endif

        set tt = null
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction
        
endscope

 

[dudeim]

or change the isAttack() to isNormal() (i think that's how it's called) if it still doesn't work, it will register all normal attacks and normal damage dealt using the function provided.

 

[WolfieeifloW]

Any optimization I could do to that, besides switching it over to GTrigger?
Nevermind, I don't need to use GTrigger, I think?


/EDIT: It still shows both numbers, even with using IsPhysical() instead of IsAttack().

scope DamageText initializer init
    
    private function Conditions takes nothing returns boolean
        local texttag tt
        
        if GetEventDamage() > 0 then
            set tt = CreateTextTag()
            call SetTextTagText(tt, I2S(R2I(GetEventDamage())), 8 * 0.023 / 10)
            call SetTextTagPosUnit(tt, GetTriggerUnit(), 0.)
            if (Damage_IsAttack()) then
            //if (Damage_IsPhysical()) then
                call SetTextTagColor(tt, 255, 255, 255, 255)
            elseif (Damage_IsSpell()) then
                call SetTextTagColor(tt, 255, 255, 0, 255)
            endif
            call SetTextTagPermanent(tt, false)
            call SetTextTagLifespan(tt, 2)
            call SetTextTagFadepoint(tt, 1)
            call SetTextTagVelocity(tt, 0, 0.05)
        endif

        set tt = null
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction
        
endscope

 

[Laiev]

Damage_RegisterEvent

Don't register 0 damage, this is why we have a Damage_RegisterZeroEvent

 

[dudeim]

Instead of Death Coil spell use Channel and change it to your needs, channel is the ultimate custom spell as it can change the base order id and lots of other values too, and it doesn't deal damage so I think that might fix all your problems.

 

[WolfieeifloW]

I'm using Damage_RegisterEvent, but it still shows a yellow 10, followed by a white 0 for some reason.
I really don't want to have to change all my spells over to Channel, but I guess it would be better..

 

[Ayanami]

Actually, it could be that the damage isn't 0, but maybe somewhere in between 0 and 1. Try displaying the real value rather than the I2S value.

 

[Laiev]

I'm using Damage_RegisterEvent, but it still shows a yellow 10, followed by a white 0 for some reason.
I really don't want to have to change all my spells over to Channel, but I guess it would be better..

Whats the base ability of your spell?

Also, make sure that you set the damage in all fields to 0

No other trigger deals damage?

 

[WolfieeifloW]

The base ability is indeed Death Coil.
I didn't plan on using Damage, but I see it would be easier to use later on.

The damage for the level 1 field (What level I'm testing with) is 0.
And I'm quite certain no other trigger would be dealing damage.

And yeah...
The text is 10.000, then 0.500.
I have no idea where the half a damage is coming from though.


/EDIT: Changing the requirement to ">= 1" works though.

scope DamageText initializer init
    
    private function Conditions takes nothing returns boolean
        local texttag tt
        
        if GetEventDamage() >= 1 then
            set tt = CreateTextTag()
            call SetTextTagText(tt, I2S(R2I(GetEventDamage())), 8 * 0.023 / 10)
            call SetTextTagPosUnit(tt, GetTriggerUnit(), 0.)
            if (Damage_IsAttack()) then
                call SetTextTagColor(tt, 255, 255, 255, 255)
            elseif (Damage_IsSpell()) then
                call SetTextTagColor(tt, 255, 255, 0, 255)
            endif
            call SetTextTagPermanent(tt, false)
            call SetTextTagLifespan(tt, 2)
            call SetTextTagFadepoint(tt, 1)
            call SetTextTagVelocity(tt, 0, 0.05)
        endif

        set tt = null
        return false
    endfunction

    private function init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call Damage_RegisterEvent(t)
        call TriggerAddCondition(t, Condition(function Conditions))
        set t = null
    endfunction
        
endscope

I have one quick question though.
Will showing the floating text to only the localplayer cause desyncs?
I want it so that only the person dealing that damage sees the text, or else your screen would get sort of crowded with everyone's damage.
Just like:

if (GetLocalPlayer() == GetTriggerPlayer()) then

Is this even possible with Damage?
Wouldn't it be like, [ljass]GetOwningPlayer(GetEventDamageSource())[/ljass] or something?

 

[Laiev]

>>Will showing the floating text to only the localplayer cause desyncs?

You can use like this:

call SetTextTagVisibility(tt, GetLocalPlayer() == GetOwningPlayer(GetEventDamageSource()))

 

[Ayanami]

Do note that using GetLocalPlayer() can cause de-syncs. I heard this happens when you create a handle for the local player. So if you were to create the floating text for GetLocalPlayer(), I believe that would cause a de-sync. Laiev did it in a way that hides the floating text, and not creating it. Thus, it won't cause de-sync. Just saying in case you don't know.

 

[WolfieeifloW]

Yeah, I knew it was when handles were created.
I just had trouble finding the texttag thing to see what it extended.
Of course, I found it right after posting