Fatal Error in Code

[Zackreaver]

Hey there, still learning Jass, but I believe I got the hang of it, I read some tutorials and found jass to truly be a much more efficient method for triggering. Anyway, this one piece of code's been bugging me, it functions alright, but in certain occasion's it causes the game to crash

function CondRockHarvest takes nothing returns boolean
    return GetSpellAbilityId() == 'A036'
endfunction

function RockCasterSize takes unit u returns integer
    if (GetUnitTypeId(u) == 'h00S' ) then
        return 3
    elseif (GetUnitTypeId(u) == 'h00T' ) then
        return 2
    endif
    return 1
endfunction


function RockGroup takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local texttag t
    local location p = GetDestructableLoc(GetEnumDestructable())
    local destructable d = GetEnumDestructable()
    local integer money
    local real rocklife
    local real size
    local integer multiplier

    set multiplier = RockCasterSize(u)

    if (GetDestructableTypeId(d) == 'LTrc') then

        call SetDestructableLife( d, (GetDestructableLife(d) + 50) * multiplier )
        call AddSpecialEffectLocBJ( p, "Doodads\\LordaeronSummer\\Terrain\\LoardaeronRockChunks\\LoardaeronRockChunks0.mdl" )
        call DestroyEffectBJ( GetLastCreatedEffectBJ() )
        set rocklife = GetDestructableLife(d)

        set money = R2I(GetDestructableLife(d) / 10)
        set size = 0.10 + (0.05 * I2R(money))
        set money = money * multiplier

        call RemoveDestructable( d )
        call CreateDestructableLoc( 'LTrc', p, GetRandomDirectionDeg(), size, 0 )
        set d = GetLastCreatedDestructable()
        call SetDestructableOccluderHeight( d, 0.00 )
        call SetDestructableLife( d, rocklife )

        call AdjustPlayerStateBJ( money, GetOwningPlayer(u), PLAYER_STATE_RESOURCE_GOLD )
        call CreateTextTagLocBJ( ( "+" + I2S(money) ), p, 0, 10, 100, 100, 0.00, 0 )
        set t = GetLastCreatedTextTag()
        call ShowTextTagForceBJ( false, t, GetPlayersAll() )
        call ShowTextTagForceBJ( true, t, GetForceOfPlayer(GetOwningPlayer(u)) )
        call SetTextTagPermanentBJ( t, false )
        call SetTextTagVelocityBJ( t, 64, 90 )
        call SetTextTagLifespanBJ( t, 5 )
        call SetTextTagFadepointBJ( t, 3.00 )

    endif

    set size = 0
    set rocklife = 0
    set money = 0
    set d = null
    set t = null
    set u = null
    call RemoveLocation(p)
    set p = null
endfunction




function StartRockHarvest takes nothing returns nothing
    local location p = GetSpellTargetLoc()
    call EnumDestructablesInCircleBJ( 200.00, p, function RockGroup )
    call RemoveLocation(p)
endfunction


//===========================================================================
function InitTrig_Rock_Harvest takes nothing returns nothing
    local trigger t
    set t = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( t, Condition( function CondRockHarvest ) )
    call TriggerAddAction( t, function StartRockHarvest )
endfunction

I had error's with this before, I think it was when I was trying to read real's as integer's, I think i fixed that, but now im getting strange crashes.

The way the trigger works is, i cast this spell over a group of rock chunks, each rock chunk is replaced with a bigger rock chunk with more hp, and the player gets gold depending on the size, and the unit type casting the spell.

Now the error is happening apparently when the rocks are being attacked after the spell has been cast. It's strange.


PS. I'm still getting the hang of jass, any advice would be lovely.

 

[--Thanatos--]

When attacked?

Well, I think that's probably because of something the destructable has... Maybe in the Object Editor.

Or maybe you should try to remove the SetDestructableLife or SetDestructableOccluderHeight.

 

[wantok]

Try setting the destructable's max life to rocklife before you set its actual life. That could possibly be a problem.

A couple of other things:

function RockGroup takes nothing returns nothing
    local unit u = GetTriggerUnit()//there is no triggering unit this will equal null
    //if you want to get the casting unit you need to make a global and pass it that way.
   //like so
    local unit u = udg_CastingUnit
    local texttag t
    local player pl = GetOwningPlayer(u)
    local destructable d = GetEnumDestructable()
    local location p = GetDestructableLoc(d)
    local integer money
    local real rocklife
    local real size
    local integer multiplier

    set multiplier = RockCasterSize(u)

    if (GetDestructableTypeId(d) == 'LTrc') then
        
        //there really is no need to set this destructable's life here since you are removing it anyways
        set rocklife = (GetDestructableLife(d) + 50) * multiplier
        //you can destroy the special effect immediately here.
       call DestroyEffect(AddSpecialEffectLoc("Doodads\\LordaeronSummer\\Terrain\\LoardaeronRockChunks\\LoardaeronRockChunks0.mdl", p )

        set money = R2I(rocklife / 10)
        set size = 0.10 + (0.05 * (money)
        set money = money * multiplier

        call RemoveDestructable( d )
        set d = CreateDestructableLoc( 'LTrc', p, GetRandomDirectionDeg(), size, 0 )
        call SetDestructableOccluderHeight( d, 0.00 )
        call SetDestructableMaxLife(d, rocklife)//i don't know if this will help but it doesnt hurt to try.
        call SetDestructableLife( d, rocklife )

        call SetPlayerState(pl, PLAYER_STATE_RESOURCE_GOLD, GetPlayerState(pl, PLAYER_STATE_RESOURCE_GOLD) + money)
        set t = CreateTextTagLocBJ( ( "+" + I2S(money) ), p, 0, 10, 100, 100, 0.00, 0 )
        call ShowTextTagForceBJ( false, t, GetPlayersAll() )
        call ShowTextTagForceBJ( true, t, GetForceOfPlayer(GetOwningPlayer(u)) )
        call SetTextTagPermanentBJ( t, false )
        call SetTextTagVelocityBJ( t, 64, 90 )
        call SetTextTagLifespanBJ( t, 5 )
        call SetTextTagFadepointBJ( t, 3.00 )

    endif

    set size = 0//you don't need to set integers and reals to zero
    set rocklife = 0
    set money = 0
    set d = null
    set t = null
    set u = null
    call RemoveLocation(p)
    set p = null
endfunction
function StartRockHarvest takes nothing returns nothing
    local location p = GetSpellTargetLoc()
    set udg_CastingUnit = GetTriggerUnit()//set the global variable here
    call EnumDestructablesInCircleBJ( 200.00, p, function RockGroup )
    call RemoveLocation(p)
    set p = null
endfunction

You still have a lot of BJ functions that can be replaced with natives if you want.

 

[Sim]

function RockGroup takes nothing returns nothing
    local unit u = GetTriggerUnit()//there is no triggering unit this will equal null
    //if you want to get the casting unit you need to make a global and pass it that way.

You can use Event responses in Enum functions. No need for a global variable.

You could also enum yourself the destructibles, using a loop.

 

[wantok]

You can use Event responses in Enum functions. No need for a global variable.

Really? I was unaware of that. Disregard that part then.

edit: After further consideration, I did know that. I was thinking about the function was like ForGroup(), but clearly it is not.

 

[Zackreaver]

Found it

Found the cause of the crash, apparently if you remove a destructable or unit (Haven't tested on units) just as its getting attacked, the game tries to deal damage to a unit that doesnt exist, and it crashes.

So I just killed the destructable instead, that way it hits the corpse.

If you want to see what I mean, make a trigger that removes a destructable on command. Attack it, then remove it before the animation reaches its damage point, your game should crash immediately.

It's seems strange, but my trigger did stop crashing when I changed it to killdestructable instead of removedestructable.