Custom sheild breaker

[Never_Quit]

im creating a jump kill ability and it either goes too fast or too slow. does anyone know how to fix this problem?

for reference here's my code so far (just started)

• Melee Initialization
  • Events
    • Unit - A unit Begins casting an ability
  • Conditions
    • (Ability being cast) Equal to Flame Strike
  • Actions
    • Set distance = (Integer((Distance between (Position of (Triggering unit)) and (Target point of ability being cast))))
    • Game - Display to (All players) the text: (String(distance))
    • Unit - Make (Triggering unit) face (Target point of ability being cast) over 0.50 seconds
    • Set startingangle = (Angle from (Position of (Triggering unit)) to (Target point of ability being cast))
    • Set startingx = (X of (Position of (Triggering unit)))
    • Set startingy = (Y of (Position of (Triggering unit)))
    • Wait 1.00 seconds
    • For each (Integer A) from 1 to distance, do (Actions)
      • Loop - Actions
        • Unit - Move (Triggering unit) instantly to ((Point(startingx, startingy)) offset by (Real((Integer A))) towards startingangle degrees)

EDIT: if i add a wait within the loop of 0 or anything around that then it will take about .1 seconds to run each loop

 

[Azlier]

But of course. Waits are inaccurate. If they were precise, why do you think we would need all these timer attachment systems?

 

[Never_Quit]

so how do you attach a timer to it?

 

[Azlier]

You mean 'how do I attach it to a timer?'. Well, I don't know of any possible way using GUI. So... good luck?

 

[Never_Quit]

haha
do you have a link to a good JASS ex?

 

[Azlier]

The only attachment methods I know are a system which does the hard work for me, and a struct. Neither can be easily accessed from GUI.

 

[Never_Quit]

idc if its in gui or jass

edit: k i figured it out in GUI

• Melee Initialization
  • Events
    • Unit - A unit Begins casting an ability
  • Conditions
    • (Ability being cast) Equal to Flame Strike
  • Actions
    • Set distance = (Integer((Distance between (Position of (Triggering unit)) and (Target point of ability being cast))))
    • Game - Display to (All players) the text: (String(distance))
    • Unit - Make (Triggering unit) face (Target point of ability being cast) over 0.50 seconds
    • Set startingangle = (Angle from (Position of (Triggering unit)) to (Target point of ability being cast))
    • Set startingx = (X of (Position of (Triggering unit)))
    • Set startingy = (Y of (Position of (Triggering unit)))
    • Set speed = 400.00
    • Set castingunit = (Triggering unit)
    • Set distancetomove = 0
    • -------- speed = distance / time --------
    • Set timetocastit = ((Real(distance)) / speed)
    • Wait 1.00 seconds
    • Countdown Timer - Start abilitytimer as a Repeating timer that will expire in 0.01 seconds
    • Countdown Timer - Start abilitykiller as a One-shot timer that will expire in timetocastit seconds

• Expired
  • Events
    • Time - abilitytimer expires
  • Conditions
  • Actions
    • Unit - Move castingunit instantly to ((Point(startingx, startingy)) offset by (Real(distancetomove)) towards startingangle degrees)
    • Set distancetomove = (distancetomove + 4)

• Killer
  • Events
    • Time - abilitykiller expires
  • Conditions
  • Actions
    • Countdown Timer - Pause abilitytimer

and then i can just do everything in multi-dimensional arrays and add a dummy unit that flies for a hyperbolic jump and itll be perfect

 

[Azlier]

Ah, this turned out decently.

Requires Key Timers 2.

scope Slide initializer Init
//Requires Key Timers 2
globals
    private constant integer SpellId = 'AHfs'
    //Spell raw code.
    private constant real TimerInterval = 0.02
    //The caster will move every (timer interval) seconds.
    private constant real Speed = 5
    //The caster will move toward the target at this speed, every (Timer Interval) seconds.
endglobals

private struct Data
    unit Caster
    real TargetX
    real TargetY
    real Angle
    static method create takes nothing returns Data
        local Data d = Data.allocate()
        local location l = GetSpellTargetLoc()
        set d.Caster = GetTriggerUnit()
        set d.TargetX = GetLocationX(l)
        set d.TargetY = GetLocationY(l)
        set d.Angle = Atan2(d.TargetY - GetUnitY(d.Caster), d.TargetX - GetUnitX(d.Caster))
        call RemoveLocation(l)
        set l = null
        return d
    endmethod
endstruct

private function Callback takes nothing returns boolean
    local Data d = KT_GetData()
    local real cx = GetUnitX(d.Caster)
    local real cy = GetUnitY(d.Caster)
    local real dx = cx + Speed * Cos(d.Angle)
    local real dy = cy + Speed * Sin(d.Angle)
    local real disx = d.TargetX - dx
    local real disy = d.TargetY - dy
    call SetUnitX(d.Caster, dx)
    call SetUnitY(d.Caster, dy)
    if SquareRoot(disx * disx + disy * disy) <= Speed + 1 then
        call PauseUnit(d.Caster, false)
        call d.destroy()
        return true
    endif
    return false
endfunction

private function Actions takes nothing returns boolean
    local Data d = Data.create()
    call KT_Add(function Callback, d, TimerInterval)
    call PauseUnit(d.Caster, true)
    return false
endfunction

private function Init takes nothing returns nothing
    local trigger t = CreateTrigger()
    local integer i = 0
    loop
        exitwhen i == 16
        call TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_SPELL_EFFECT, null)
        set i = i + 1
    endloop
    call TriggerAddCondition(t, Condition(function Actions))
endfunction

endscope

 

[Never_Quit]

o sorry i figured it out

thanks for your help

 

[Azlier]

But mine's MUI .

 

[bOb666777]

What about a periodic event?
Have the first trigger add the unit to a group
Then the 2nd, with a periodic event, moves all units in that group.

 

[Never_Quit]

What about a periodic event?
Have the first trigger add the unit to a group
Then the 2nd, with a periodic event, moves all units in that group.

dude thats a great idea thanks

and then i can add a 1-12 loop so that it sets everything relative to the player... and if i want more units then i can add a two dimensional array with ((CUSTOM_UNIT_NUMBER x MAX_PLAYERS) + Player_number)

timer array events actually do register so my GUI one is actually a plausible solution even for a MUI and MPI setup haha