Snippet NewTextTag

[13lade619]

setting up floating texts is annoying right?
you call more than 5 functions yourself + most of them are BJs,

so here's a solution:
A text tag function that takes all the necessary arguments,
and no nasty BJs to get in the way (all calculations done inside BJs are redone).

library NewTextTag

function NewTextTagUnitFunc takes string txtstring,real size,unit U,real zOff,integer red,integer green,integer blue,integer alpha,boolean perma,real speed,real angle,real life,real fade returns texttag
    set bj_lastCreatedTextTag = CreateTextTag()
    call SetTextTagText(bj_lastCreatedTextTag, txtstring, (size * 0.0023))
    call SetTextTagPosUnit(bj_lastCreatedTextTag,U,zOff)
    call SetTextTagColor(bj_lastCreatedTextTag,red,green,blue,alpha)
    call SetTextTagPermanent( bj_lastCreatedTextTag, perma )
    call SetTextTagVelocity(bj_lastCreatedTextTag, (speed * 0.0005546875) * Cos(angle * bj_DEGTORAD) , (speed * 0.0005546875) * Sin(angle * bj_DEGTORAD))
    call SetTextTagLifespan(bj_lastCreatedTextTag, life )
    call SetTextTagFadepoint(bj_lastCreatedTextTag, fade )
    return bj_lastCreatedTextTag
endfunction

function NewTextTagPointFunc takes string txtstring,real size,real x, real y,real zOff,integer red,integer green,integer blue,integer alpha,boolean perma,real speed,real angle,real life,real fade returns texttag
    set bj_lastCreatedTextTag = CreateTextTag()
    call SetTextTagText(bj_lastCreatedTextTag, txtstring, (size * 0.0023))
    call SetTextTagPos(bj_lastCreatedTextTag, x, y, zOff)
    call SetTextTagColor(bj_lastCreatedTextTag,red,green,blue,alpha)
    call SetTextTagPermanent( bj_lastCreatedTextTag, perma )
    call SetTextTagVelocity(bj_lastCreatedTextTag, (speed * 0.0005546875) * Cos(angle * bj_DEGTORAD) , (speed * 0.0005546875) * Sin(angle * bj_DEGTORAD))
    call SetTextTagLifespan( bj_lastCreatedTextTag, life )
    call SetTextTagFadepoint( bj_lastCreatedTextTag, fade )
    return bj_lastCreatedTextTag
endfunction

endlibrary

Use:

function NewTextTagUnitFunc takes string txtstring,real size,unit U,real zOff,integer red,integer green,integer blue,integer alpha,boolean perma,real speed,real angle,real life,real fade returns texttag

or

function NewTextTagPointFunc takes string txtstring,real size,real x, real y,real zOff,integer red,integer green,integer blue,integer alpha,boolean perma,real speed,real angle,real life,real fade returns texttag

*Create a trigger, name it NewTextTag and paste the entire code.
**Or copy the code inside the library and paste in in the Map Header.
***Or copy the code inside the library inside your own library of custom functions.

*JASS / GUI Custom Script
*Leakless, since lifespan destroys the texttag after.
*RGB values take 0 to 255, not percentage.
*Alpha 0 is transparent, 255 is opaque.

*Functions return texttags, so you can manipulate them later (within their lifespan ofc).
*If you set permanence to false, be sure to destroy the text tag after.

Feel free to use. .

 

[Darthfett]

You're creating a BJ function so that people don't have to look up the functions they need?

This is not exactly the sort of thing we need filling our systems forum, this is just clutter. Blizzard has already provided us with a nice BJ function which does exactly this.

 

[13lade619]

the BJ for floating texts redirect to more BJs which redirect to more BJs..
this is a little cleaner.

take a look at this:

function CreateTextTagUnitBJ takes string s, unit whichUnit, real zOffset, real size, real red, real green, real blue, real transparency returns texttag
    set bj_lastCreatedTextTag = CreateTextTag()
    call SetTextTagTextBJ(bj_lastCreatedTextTag, s, size)
    call SetTextTagPosUnitBJ(bj_lastCreatedTextTag, whichUnit, zOffset)
    call SetTextTagColorBJ(bj_lastCreatedTextTag, red, green, blue, transparency)

    return bj_lastCreatedTextTag
endfunction

function SetTextTagTextBJ takes texttag tt, string s, real size returns nothing
    local real textHeight = TextTagSize2Height(size)

    call SetTextTagText(tt, s, textHeight)
endfunction

function TextTagSize2Height takes real size returns real
    return size * 0.023 / 10
endfunction

native SetTextTagText takes texttag t, string s, real height returns nothing

see? and that's only setting the text for the texttag. .

 

[Faust]

It makes stuff a little easier and shorter, you don't have to love it.
Simple and useful (to some level ).

 

[Jesus4Lyf]

boolean perma

... is useful for what when the function returns nothing?

0.023/10=0.0023
0.071/128=0.0005546875

real fade

If people need to figure out what this sort of thing does, it's probably faster to write the whole snippet themselves than get it from here.

 

[Tom_Kazansky]

@13lade619, I think your functions should return the texttag

//...
    set bj_lastCreatedTextTag = Ftext
    set Ftext = null
    return bj_lastCreatedTextTag
endfunction

and also add an argument for checking texttag is in fogs or not.

function CheckTexttagVisibility takes texttag tt, real x, real y returns nothing
    local integer int = 0
    local player p
    loop
        exitwhen int > 11
        set p = Player(int)
        if GetLocalPlayer() == p then
            call SetTextTagVisibility( tt , IsVisibleToPlayer(x,y, p )  )
        endif
        set int = int + 1
    endloop
    set p = null
endfunction

they are just suggestions, use or not is up to you

 

[13lade619]

//...
    set bj_lastCreatedTextTag = Ftext
    set Ftext = null
    return bj_lastCreatedTextTag
endfunction

umm.. are you sure it's a good idea to set it to the bj?
..'cuz i'm not..

 

[Tom_Kazansky]

>are you sure it's a good idea to set it to the bj?

bj_lastCreatedTextTag is just a global variable, if your function returns textag with the local var Ftext, you will get a leak.

//...
    return Ftext //didn't null Ftext -> leak
endfunction

 

[13lade619]

ok.. fix it up later..

/must write better docu first/

 

[Jesus4Lyf]

Should use bj_lastCreatedTextTag for the whole thing instead of a local at all.

 

[13lade619]

Should use bj_lastCreatedTextTag for the whole thing instead of a local at all.

@13lade619, I think your functions should return the texttag

0.023/10=0.0023
0.071/128=0.0005546875

done, done and DONE.

 

[Jesus4Lyf]

Good stuff. Good to see systems updated swiftly based on feedback.

function NewTextTagUnitFunc takes string txtstring,real size,unit U,real zOff,integer red,integer green,integer blue,integer alpha,boolean perma,real speed,real angle,real life,real fade returns texttag

>If people need to figure out what this sort of thing does, it's probably faster to write the whole snippet themselves than get it from here.

Try writing functions that have less parameters, or I fear this is unlikely to get approved or used. For example, I would remove size, zOff, alpha, perma, angle (??), and please explain what life and fade are... Those that I suggest you remove could be constants, inlined manually or as global constants, up to you. Grouping the natives together doesn't actually add user friendliness. Making more things constant so the user doesn't have to worry does.

PS. My ideal function would be: function FloatUpTextTag takes string txtstring,unit U,integer red,integer green,integer blue returns texttag
resulting in a critical strike style texttag.