Adding onto a local integer?

[Beetlebomb]

Good to know

 

[N-a-z-g-u-l]

(only two BJ's used [DisplayTextToForce and GetPlayersAll] but avoiding them is probably more trouble than it's worth)

well, the problem is:

//===========================================================================
function GetUnitsOfTypeIdAllFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == bj_groupEnumTypeId
endfunction

//===========================================================================
function GetUnitsOfTypeIdAll takes integer unitid returns group
    local group   result = CreateGroup()
    local group   g      = CreateGroup()
    local integer index

    set index = 0
    loop
        set bj_groupEnumTypeId = unitid
        call GroupClear(g)
        call GroupEnumUnitsOfPlayer(g, Player(index), filterGetUnitsOfTypeIdAll)
        call GroupAddGroup(g, result)

        set index = index + 1
        exitwhen index == bj_MAX_PLAYER_SLOTS
    endloop
    call DestroyGroup(g)

    return result
endfunction

that means, you create another useless group and add units to it 16 times, then you call GroupAddGroup 16 times, which loops through the whole created group...

//===========================================================================
function GroupAddGroupEnum takes nothing returns nothing
    call GroupAddUnit(bj_groupAddGroupDest, GetEnumUnit())
endfunction

//===========================================================================
function GroupAddGroup takes group sourceGroup, group destGroup returns nothing
    // If the user wants the group destroyed, remember that fact and clear
    // the flag, in case it is used again in the callback.
    local boolean wantDestroy = bj_wantDestroyGroup
    set bj_wantDestroyGroup = false

    set bj_groupAddGroupDest = destGroup
    call ForGroup(sourceGroup, function GroupAddGroupEnum)

    // If the user wants the group destroyed, do so now.
    if (wantDestroy) then
        call DestroyGroup(sourceGroup)
    endif
endfunction

so... the optimized version is more than twice as fast, the only reason for not optimizing this function is, that you dont need that much performance

but, are you completely sure that my second code did not work? ive just tried it and it worked perfectly... perhaps you did some mistake adding it into your trigger, or used my function named Condition as the trigger-condition (should be the filter, now renamed it)

here is what the whole trigger should look like

function Trig_Remove_Archers_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'AHtc'
endfunction

function Trig_Remove_Archers_Filter takes nothing returns boolean
    local unit U = GetFilterUnit()
    if (GetUnitTypeId(U)=='earc') and (GetUnitState(U,UNIT_STATE_LIFE)>0) then
        set bj_groupCountUnits = bj_groupCountUnits + 1
        call KillUnit(U)
    endif
    set U = null
    return false
endfunction

function Trig_Remove_Archers_Actions takes nothing returns nothing
    local group g = CreateGroup()
    set bj_groupCountUnits = 0
    call GroupEnumUnitsInRect(g, GetWorldBounds(), Condition( function Trig_Remove_Archers_Filter ) )
    call DestroyGroup(g)
    set g = null
    call DisplayTextToPlayer(GetLocalPlayer(), 0, 0, I2S(bj_groupCountUnits)+" Archers have been killed.")
endfunction



//===========================================================================
function InitTrig_Remove_Archers takes nothing returns nothing
    set gg_trg_Remove_Archers = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Remove_Archers, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Remove_Archers, Condition( function Trig_Remove_Archers_Conditions ) )
    call TriggerAddAction( gg_trg_Remove_Archers, function Trig_Remove_Archers_Actions )
endfunction

 

[Beetlebomb]

Yea I guess I must've done something wrong. The point of this whole thread was for me to just figure out a little bit more then I currently knew about Jass-- and I did.


I'm not going to give up on learning, but I will be taking a little break from all this scripting; it's making my head hurt!

thx though nazgul, i'll be sure to keep this thread subscribed so I can come back to it.

 

[AdamGriffith]

Could that not have been just made in gui! xD
Sorry if the thread is closed.

 

[N-a-z-g-u-l]

of course it could be done in gui
most things can be done in gui, but to learn jass, you should always use jass... and jass will always help you to get a script with better performance and less leaks...

but, it could be done in gui, yes^^

 

[AdamGriffith]

Well it seems pointless to me. xD
You can remove leaks just fine in GUI and that's the only thing you would need in this trigger...
Oh well, up to you isn't it. xD

 

[Flare]

How else are you supposed to learn JASS other than to use it? And I doubt anyone who uses JASS started out at a very high level and even alot of complicated things would utilise some simple things associated with JASS

 

[N-a-z-g-u-l]

and by the way... you are faster typing jass than creating gui triggers, if you know the basic commands and how jass works

 

[Romek]

It can be difficult to persuade people to use JASS... But once you start using it, you'll see how much better it is to GUI

And... I just made this Code for what you wanted... [I only read last few posts]

globals
    integer i = 0
endglobals

function Add takes nothing returns nothing
    if GetWidgetLife(GetEnumUnit()) > 0.405 then // I won't get involved with the "Is it .405" thing =P
         set i = i + 1
    endif
endfunction

function Trig_Remove_Archers_Actions takes nothing returns nothing
    local group g = GetUnitsOfTypeIdAll('earc') //only need 1 group
    call ForGroup(g, function Add )
    call ForGroup(g, function kill2 ) // Kill the archers AFTER you've counted them...
    call DestroyGroup(g)
    set g = null
    call DisplayTextToForce(GetPlayersAll(),I2S(i)+" Archers have been killed." )
    set i = 0
endfunction

 

[PurgeandFire]

    call DisplayTextToForce(GetPlayersAll(),I2S(i)+" Archers have been killed." )

    call DisplayTextToPlayer(GetLocalPlayer(),0,0,I2S(i)+" Archers have been killed.")