Missile-dummy moving, but not it's attached sfx ?!

[Komaqtion]

Hi !

I was just making an everyday custom shockwave spell, where a dummy slides over a set distance damaging all units in it's path, and I would believe, with every inch of experience I have, that this would be easily done, and that my simple code would do the job of at least moving the missile...

Here it is:

scope Shockwave initializer Init // requires T32

    globals
        private constant integer DUMMY_ID        =     '1337'
        private constant integer SPELL_ID        =     'wave'
        
        private constant string  SFX_PATH        =     "Abilities\\Spells\\Undead\\Possession\\PossessionMissile.mdl"
        private constant string  ATTACH_POINT    =     "chest"
        
        private constant real    MISSILE_SPEED   =     250.
    endglobals
    
    private constant function SpellDistance takes integer lvl returns real
        return lvl * 200. + 250.
    endfunction
    
    private function SpellDamage takes integer lvl returns real
        return 75. + 25. * Pow( 2., lvl - 1. )
    endfunction
    
    native UnitAlive takes unit id returns boolean

    private struct MissileData
        unit missileCaster = null
        unit missileDummy = null
        
        player casterOwner = null
        
        real missileAngle = 0.
        real missileSpeed = MISSILE_SPEED * T32_PERIOD
        real distanceTraveled = 0.
        real distanceLeft = 0.
        real missileX = 0.
        real missileY = 0.
        real targetX = 0.
        real targetY = 0.
        real missileDmg
        
        private effect missileSFX = null
        
        private group missileDamaged = CreateGroup()
        
        static method create takes unit u, real tx, real ty returns thistype
            local thistype this = thistype.allocate()
            local real dx
            local real dy
            
            set missileCaster = u
            set casterOwner = GetOwningPlayer( u )
            set missileX = GetUnitX( u )
            set missileY = GetUnitY( u )
            set targetX = tx
            set targetY = ty
            set dx = tx - missileX
            set dy = ty - missileY
            set missileAngle = Atan2( dy, dx )
            set missileDummy = CreateUnit( casterOwner, DUMMY_ID, missileX, missileY, missileAngle )
            set missileSFX = AddSpecialEffectTarget( SFX_PATH, missileDummy, ATTACH_POINT )
            set distanceLeft = SpellDistance( GetUnitAbilityLevel( u, SPELL_ID ) )
            set missileDmg = SpellDamage( GetUnitAbilityLevel( u, SPELL_ID ) )
            
            call startPeriodic()
            
            return this
        endmethod
        
        private method periodic takes nothing returns nothing
            local real newx = missileX + missileSpeed * Cos( missileAngle )
            local real newy = missileY + missileSpeed * Sin( missileAngle )
            
            call SetUnitX( missileDummy, newx )
            call SetUnitY( missileDummy, newy )
            
            set missileX = newx
            set missileY = newy
        endmethod
        
        implement T32x
    endstruct

    private function Conditions takes nothing returns boolean
        local unit u
        local unit t
        local real x
        local real y
        local real tx
        local real ty
        local real dx
        local real dy
        local MissileData m
        
        if GetSpellAbilityId() == SPELL_ID then
            set u = GetTriggerUnit()
            set t = GetSpellTargetUnit()
            set x = GetUnitX( u )
            set y = GetUnitY( u )
            
            if t == null then
                set tx = GetSpellTargetX()
                set ty = GetSpellTargetY()
            else
                set tx = GetUnitX( t )
                set ty = GetUnitY( t )
            endif
            
            set dx = tx - x
            set dy = ty - y
            set m = MissileData.create( u, tx, ty )
        endif
        
        return false
    endfunction

    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        
        call TriggerRegisterAnyUnitEventBJ( t, EVENT_PLAYER_UNIT_SPELL_EFFECT )
        call TriggerAddCondition( t, Condition( function Conditions ) )
    endfunction
    
endscope

Now, but only small problem here is that, the dummy itself is moving as I've checked that with some debug messages, but the sfx is staying at the caster's feet (?!), any ideas to why this would happen ? :S

And yes, the dummy has the dummy.mdx model, and I've even tried to create a new map with this trigger and a whole bunch of systems and it still won't work...

 

[hgkjfhfdsj]

the dummy itself is moving as I've checked that with some debug messages
try using a visible model instead

and im not too sure... shouldnt there be a '.' next to start in [ljass]call startPeriodic()[/ljass]?

 

[Weep]

Have you forgotten to give your dummy unit at least 1 movement speed? (Unit models don't move if the unit has an MS of 0.)

 

[Komaqtion]

try using a visible model instead

That isn't necessary But I tried that too

Have you forgotten to give your dummy unit at least 1 movement speed? (Unit models don't move if the unit has an MS of 0.)

THANKS ! Will try it...

But does this make the actual UNIT move, but not the attached model ?

 

[Weep]

But does this make the actual UNIT move, but not the attached model ?

A unit with a move speed of 0 will move as far as the game is concerned (selection circle, shadow?, GetUnitX/Y(), range checks) but its model will remain unmoved, in place, not matching the unit's game position.

 

[Komaqtion]

Hehe, yeah I saw this
Thanks

 

[Jedi]

You can use SetUnitPosition with 0 ms.

 

[kingkingyyk3]

You can use SetUnitPosition with 0 ms.
SetUnitPosition is ~2700% slower than SetUnitX + SetUnitY, LOL.

 

[Jedi]

Who cares LOL?Your pc crashing while using it?

 

[kingkingyyk3]

No, it will cause fps to drop drastically.
I tried it, 72 instances of dummy sliding by using SetUnitPosition.
FPS dropped to ~32.
Another test, used SetUnitX/Y.
FPS didn't drop.