Arrow Key Movement

[Tinkerhead]

How do I make units move a distance via JASS so I don't have to make a new trigger via GUI for every region? For example: I press right and it moves right a certain distance.

 

[Sim]

Detect when the player presses the arrow key, wait x seconds then force the unit to stop.

 

[Tinkerhead]

But I'd need the code unless I can do it in GUI.

 

[Sim]

You can do it with GUI.

 

[hobo218]

The initial event would be
Player - Player 1 (Red) Presses the Left Arrow key

or whatever you wanted configured for it.

 

[Doomhammer]

hm, it's a bit hard to explain out of context, especially as you're not giving any details about what kind of movement you'd like to have.
Is it some sort of 1st/3rd person perspective combined with arrow key movement? Is it for singleplayer only, or multiplayer?

in any case create 2 variables, and 6 triggers; (once you get it, you may experiment a bit, and ideally report how to make the movement smoother, especially when standing and turning around.)
the variables:
call the first sth like "walk" of type boolean
the second sth like "leftright" of type integer
your unit has to be declared as variable of course
I'm using triggers of type local here, as that was more practical for my purpose, but you'd better go with globals - so just create triggers with the events as I did. And don't get deterred by the amount of lines! Just gnaw through, it's actually pretty simple.

function Release takes nothing returns nothing
    local integer i = GetPlayerId(GetTriggerPlayer())+1
        set udg_InsLR[i] = 0
endfunction

function ReUp takes nothing returns nothing
    local integer i = GetPlayerId(GetTriggerPlayer())+1
        set udg_InsWalk[i] = false
        call IssueImmediateOrder( udg_InsUnit[i], "stop" )
endfunction

function Up takes nothing returns nothing
local integer i = GetPlayerId(GetTriggerPlayer())+1
local unit u = udg_InsUnit[i]
local real x
local real y
local real v = GetUnitDefaultMoveSpeed(u)
set udg_InsWalk[i] = true
  loop
      exitwhen udg_Insight[i] == false 
      exitwhen udg_InsWalk[i] == false
      set x = GetUnitX(u) + 2*v* Cos((GetUnitFacing(u) + udg_InsLR[i] * 30)* bj_DEGTORAD)
      set y = GetUnitY(u) + 2*v* Sin((GetUnitFacing(u) + udg_InsLR[i] * 30)* bj_DEGTORAD)
      call IssuePointOrder(u, "move", x, y )
      call TriggerSleepAction(0.7 )
  endloop
set u = null
endfunction

function Down takes nothing returns nothing
    local integer i = GetPlayerId(GetTriggerPlayer())+1
        call SetUnitFacingTimed( udg_InsUnit[i], ( GetUnitFacing(udg_InsUnit[i]) + 180.00 ), 0.80 )
endfunction

function Left takes nothing returns nothing
    local integer i = GetPlayerId(GetTriggerPlayer())+1
        if udg_InsWalk[i] == true then
            set udg_InsLR[i] = 1
        else
            call SetUnitFacingTimed( udg_InsUnit[i], ( GetUnitFacing(udg_InsUnit[i]) + 45.00 ), 0.50 )
        endif
endfunction

function Right takes nothing returns nothing
    local integer i = GetPlayerId(GetTriggerPlayer())+1
        if udg_InsWalk[i] == true then
            set udg_InsLR[i] = -1
        else
            call SetUnitFacingTimed( udg_InsUnit[i], ( GetUnitFacing(udg_InsUnit[i]) - 45.00 ), 0.50 )
        endif
endfunction

function InsLock takes player p, unit tar, camerasetup cam0 returns nothing
    local integer j = GetPlayerId(p) + 1
    local trigger TReUp 
    local trigger TRelease
    local trigger TUp
    local trigger TDown
    local trigger TLeft
    local trigger TRight
               
        set TReUp = CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TReUp, Player(j-1), bj_KEYEVENTTYPE_RELEASE, bj_KEYEVENTKEY_UP )
        call TriggerAddAction( TReUp, function ReUp )
        set TRelease = CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TRelease, Player(j-1), bj_KEYEVENTTYPE_RELEASE, bj_KEYEVENTKEY_LEFT )
        call TriggerRegisterPlayerKeyEventBJ( TRelease, Player(j-1), bj_KEYEVENTTYPE_RELEASE, bj_KEYEVENTKEY_RIGHT )
        call TriggerAddAction( TRelease, function Release )
        set TUp = CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TUp, Player(j-1), bj_KEYEVENTTYPE_DEPRESS, bj_KEYEVENTKEY_UP )
        call TriggerAddAction( TUp, function Up)
        set TDown = CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TDown, Player(j-1), bj_KEYEVENTTYPE_DEPRESS, bj_KEYEVENTKEY_DOWN )
        call TriggerAddAction( TDown, function Down )
        set TLeft=CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TLeft, Player(j-1), bj_KEYEVENTTYPE_DEPRESS, bj_KEYEVENTKEY_LEFT )
        call TriggerAddAction( TLeft, function Left)
        set TRight=CreateTrigger()
        call TriggerRegisterPlayerKeyEventBJ( TRight, Player(j-1), bj_KEYEVENTTYPE_DEPRESS, bj_KEYEVENTKEY_RIGHT )
        call TriggerAddAction( TRight, function Right)

//...more script in here which I cut out to simplify       
 
        call DestroyTrigger(TReUp)
        call DestroyTrigger(TRelease)
        call DestroyTrigger(TUp)
        call DestroyTrigger(TDown)
        call DestroyTrigger(TLeft)
        call DestroyTrigger(TRight)
        set udg_InsUnit[j] = null
        set tar = null
        set p = null
endfunction

EDIT:
it's probably too soon to get into detail already.
Better give more info about what you want. Can the unit die? If so, what is to happen after it died? Which perspective is it? What is supposed to happen when you press up/left/right/down, and in combinations up+left, down + right, etc. What is supposed to happen when you release a key?

 

[SFilip]

you can most likely get the same effect with simple polar offsets in gui...

 

[Doomhammer]

polar offset is the same maths, yet given the speed fetishism in the mind of a true jasser - and there is no denying the fact that the noticeable difference in calculation speed between GUI and Jass plays the key role here - I can only say that GUI is for kids.