Importing jass

[FireBladesX]

I've never imported a jass trigger in to my map before. But I was looking at Acehart's tree-regrow trigger, and it looked really neat, so I thought, why not?

I copied it and pasted it in to a blank trigger, but when I tried to save, it gave me a laundry list of errors. What went wrong?

Spoiler

library REGROWTREES initializer Init
globals
    private constant real RegrowAfter = 23.0 // seconds to wait until tree regrows
    private unit u
endglobals
private function IsTree takes nothing returns boolean
    local boolean b
    call SetUnitX(u, GetWidgetX(GetFilterDestructable()))
    call SetUnitY(u, GetWidgetY(GetFilterDestructable()))
    set b = IssueTargetOrder(u, "harvest", GetFilterDestructable())
    call IssueImmediateOrder(u, "stop")
    return b
endfunction
private function Regrow takes nothing returns nothing
    call TriggerSleepAction(RegrowAfter)
    call DestructableRestoreLife(GetDyingDestructable(), GetDestructableMaxLife(GetDyingDestructable()), true)
endfunction
private function Register takes nothing returns nothing
    call TriggerRegisterDeathEvent(bj_destInRegionDiesTrig, GetEnumDestructable())
endfunction
private function Init takes nothing returns nothing
    set u = CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), 'nmpe', 0, 0, 0) // Mur'gul Slave...
    call SetUnitInvulnerable(u, true)
    call ShowUnit(u, false)
    call UnitAddAbility(u, 'Aloc') // Locust
    call UnitAddAbility(u, 'Ahrl') // Harvest Lumber
    set bj_destInRegionDiesTrig = CreateTrigger()
    call EnumDestructablesInRect(bj_mapInitialPlayableArea, Condition(function IsTree), function Register)
    call TriggerAddAction(bj_destInRegionDiesTrig, function Regrow)
    call RemoveUnit(u)
    set u = null
endfunction
endlibrary

It says "Expected end of line, expected a reserved type or handle type, expected a name..."

 

[AceHart]

It requires NewGen. Normal editor won't do.

It also doesn't need any "blank trigger".
Map header is just fine.

 

[FireBladesX]

The man himself!

I don't have NewGen, I better go get it. :|

Ok, I got it. Ty

 

[Igor_Z]

Is NewGen some kind of program like WE?

 

[AceHart]

Local thread:
http://www.thehelper.net/forums/showthread.php?t=73936

Origin:
http://wc3campaigns.net/showthread.php?t=90999

 

[Igor_Z]

ok ty Ace gonna study it now

 

[Vassilev]

Just curious... why do you need a worker to harvest the destructible?

 

[AceHart]

Not every destructible is a tree.

And, well, unless you want to provide a list of what is a tree (or what isn't),
harvesting it is pretty much the only way to find out if yes or no it is one.

The script, as is, accepts any destructible that can be harvested for lumber as tree.
Custom and never before seen trees included.
Without the need to edit anything.