Question on struct.destroy()...

[Steel]

Can't seem to remember this....Does anyone know how this actually functions? If you have a struct like

struct Example
unit u
texttag tt
etc...
endstruct

.destroy() only nullifies the data within the struct, it doesn't actually delete/remove/destroy/kill anything, correct?

 

[cr4xzZz]

Yep. And you could use method onDestroy to clean leaks

 

[Vexorian]

.destroy() only nullifies the data within the struct, it doesn't actually delete/remove/destroy/kill anything, correct?

neither.

 

[cr4xzZz]

> neither.
Neither? What does it do then? Clean the struct's values?

 

[Weyrling]

Destroys the struct itself and leaks the data, I imagine.

 

[Uberplayer]

struct MyStruct
    group g = CreateGroup()
endstruct

That's our struct.

//Generated destructor of MyStruct
function s__MyStruct_destroy takes integer this returns nothing
    if this==null then
            call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,1000.,"Attempt to destroy a null struct of type: MyStruct")
        return
    elseif (si__MyStruct_V[this]!=-1) then
            call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,1000.,"Double free of type: MyStruct")
        return
    endif
    set si__MyStruct_V[this]=si__MyStruct_F
    set si__MyStruct_F=this
endfunction

That is the function which is called when the struct is destroyed. As you can see, it doesn't nothing to the group variable.

 

[Sooda]

> What does it do then?

structName.destroy() calls thatStructType.onDestroy(). You have to manually create .onDestroy() method yourself. Otherwise struct id will be recycled, but all references and values stays and could cause memory leaks. To illustrate:

struct Point
    location spellLoc
endstruct

function SaveLoc takes nothing returns nothing
    local Point data = Point.create()
    
    set data.spellLoc = GetSpellTargetLoc()
    // Next line only releases struct id for overwriting by new
    // Point.create() calls. but dosn' t clean its content.
    call data.destroy()
    // Currently new given struct still points to our old struct
    // target point of ability being cast location.
    set data = Point.create()
    call BJDebugMsg("Newly created struct spellLoc X is " +R2S(GetLocationX(data.spellLoc)) + " and Y is " + R2S(GetLocationY(data.spellLoc)))
    // We now create memory leak because we don' t remove old location
    // instead we replace it with new one and erase reference to old
    // location where it previously was referring to.
    set data.spellLoc = Location(0.,0.)
    // We now don' t have any way to remove old location whatsoever.
    // end of exaple how you create memory leaks.
endfunction

Now we create our custom onDestroy method to remove structs stored location if we call Point.destroy()

struct Point
    location spellLoc
    
    method onDestroy takes nothing returns nothing
        // we refer to currently being destroyed struct with
        // . (dot) syntax.
        // Also would work 'this.spellLoc' (without '').
        call RemoveLocation(.spellLoc)
    endmethod
endstruct

function SaveLoc takes nothing returns nothing
    local Point data = Point.create()
    
    set data.spellLoc = GetSpellTargetLoc()
    // struct content will be cleaned.
    call data.destroy()
    set data = Point.create()
    // Not going to call BJDebugMsg() because there isn' t any location
    // anymore stored in newly given struct.
    // Nothing goes missing because our onDestroy() method took care
    // of our old struct location.
    set data.spellLoc = Location(0.,0.)
    // end of exaple how you avoid memory leaks.
endfunction

Check out this tutorial how to create and destroy structs: Basics of Structs by Andrewgosu
Also keep in mind that destroy method onDestroy is case sensitive. OnDestroy dosn' t equal with onDestroy! Use only onDestroy!

EDIT:
Thought to use similar struct example what involved CreateGroup(), but unit groups should not be destroyed, instead recycled. It took me time to write example with location instead.

 

[~GaLs~]

>>Neither? What does it do then? Clean the struct's values?
Free the index count of struct.
Struct are actually global arrays, it has 8191 limit. You'll need to free it in order to create more and mroe struct in the mean time, before it reaches the limit.

 

[Uberplayer]

>global arrays
global integer arrays.

 

[Vexorian]

>global arrays
global integer arrays.

Not necessarily.

 

[Uberplayer]

>Not necessarily.
What do you mean?

 

[phyrex1an]

>Not necessarily.
What do you mean?

That structs don't necessarily consist of integer arrays.

struct
     unit coolUnit
     real randomReal
endstruct

Is one unit array an one real array. Then I suppose there is some integer array somewhere handling index recycling but that's not exactly part of the struct.