Frustrating Issue

[Technomancer]

Going to be some code here, so bear with me, it's under construction so poorly commented but should be readable to anyone who has done this before.

I'm trying to make a unit based shooting system using the skill stasis ward as the target (projectiles (units) fly from the angle of the shooter you fire them towards the ward and trigger when they hit the opponent). That part works fine and good and was easy, so I went to do the second part, which is create a ward that appears at a fixed angle relative to the caster and moves with the caster. This works fine as well, and the two are seperate abilities on my unit and function perfectly, however the only remaining issue is that once you switch to fixed-angle-firing mode, you can't switch back for some reason, any new wards that are created get taken over by the fixed-angle timer and changed to the angle that they spawned at (effectively, Fixed Angle Ward is cast instead of Stationary Ward when you want to cast Stationary Ward).

Here's the code, from most related to unrelated:
*This is all using Vex's CSCache and Caster System

Functions for moving the ward when Fixed_Angle_Stasis_Ward is cast:
(AdjustAngleWard keeps taking over the non fixed angle wards)

function Trig_Set_Fixed_Angle_Stasis_Ward_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A001' ) ) then
        return false
    endif
    return true
endfunction

function AdjustAngleWard takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local string str = GetAttachmentTable(t)
    local unit ward = GetTableUnit(str, "ward")
    local unit castr = GetTableUnit(str, "u")
    local real ang = GetTableReal(str, "ang")
    if (ward == null) then
        call ReleaseTimer(t)
    else
        call SetUnitPosition(ward, GetUnitX(castr) + 100 * Cos(ang * bj_DEGTORAD), GetUnitY(castr) + 100 * Sin(ang * bj_DEGTORAD) )
    endif
endfunction

function Trig_Set_Fixed_Angle_Stasis_Ward_Actions takes nothing returns nothing
    local timer t = NewTimer()
    local unit WardU
    local unit TrigU = GetTriggerUnit()
    local group g = CreateGroup()
    local real x
    local real y
    local real targX
    local real targY
    local string timerstr = GetAttachmentTable(t)
    local real ang
    local real dist
    //local string wardstr = GetAttachmentTable(WardU)
    
    call TriggerSleepAction(.1)
    set g = GetUnitsOfPlayerMatching(GetOwningPlayer(TrigU), Condition(function UnitIsStasisWard) )
    set WardU = FirstOfGroup(g)
    set x = GetUnitX(TrigU)
    set y = GetUnitY(TrigU)
    set targX = GetUnitX(WardU)
    set targY = GetUnitY(WardU)

    //Get Angle
    set ang = bj_RADTODEG * Atan2(targY - y, targX - x)
    
    //Affix angle and base unit to timer table
    call SetTableReal(timerstr, "ang", ang)
    call SetTableObject(timerstr, "u", TrigU)
    call SetTableObject(timerstr, "ward", WardU)
    //call SetTableObject(wardstr, "timer", t)
    call TimerStart(t, .02, true, function AdjustAngleWard)[/B] //Calls AdjustAngleWard to adjust the angle as you move every .02
    //Start Timer
    
    
    
    //Null Vars
    call DestroyGroup(g)
    
    
endfunction

//===========================================================================
function InitTrig_Set_Fixed_Angle_Stasis_Ward takes nothing returns nothing
    set gg_trg_Set_Fixed_Angle_Stasis_Ward = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Set_Fixed_Angle_Stasis_Ward, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Set_Fixed_Angle_Stasis_Ward, Condition( function Trig_Set_Fixed_Angle_Stasis_Ward_Conditions ) )
    call TriggerAddAction( gg_trg_Set_Fixed_Angle_Stasis_Ward, function Trig_Set_Fixed_Angle_Stasis_Ward_Actions )
endfunction

Function for removing wards.
The issue might be here but it doesn't seem to be when I cast things... maybe I should use a global to grab the old ward and destroy it, then set the new ward to the global? Not a big fan of globalling everything up so early...

function Trig_Remove_Other_Wards_On_Cast_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local group g = GetUnitsOfPlayerMatching(GetOwningPlayer(u), Condition(function UnitIsStasisWard) )
    local unit w = FirstOfGroup(g)
    local string s = GetAttachmentTable(w)
    //local timer t = GetTableTimer(s, "timer")

    //call ReleaseTimer(t)
    call RemoveUnit(w)
    set u = null
    call DestroyGroup(g)
endfunction
//works fine as far as I can see

function Trig_Remove_Other_Wards_On_Cast_Conditions takes nothing returns boolean
    if ( not ( ( GetSpellAbilityId() == 'A001' ) or ( GetSpellAbilityId() == 'A002' ) ) ) then
        return false
    endif
    return true
endfunction
//works fine as far as I can see

function Trig_Fire_Projectile_Actions takes nothing returns nothing
    local unit TrigU = GetTriggerUnit()
    local group g = GetUnitsOfPlayerMatching(GetOwningPlayer(TrigU), Condition(function UnitIsStasisWard) )
    local location l = GetUnitLoc(FirstOfGroup(g))
    local real x = GetUnitX(TrigU)
    local real y = GetUnitY(TrigU)
    local real targX = GetLocationX(l)
    local real targY = GetLocationY(l)
    local real ang = bj_RADTODEG * Atan2( (targY - y) , (targX - x) )
    local trigger trig = CreateTrigger()
    local string strng = GetAttachmentTable(trig)
    local timer t = NewTimer()
    local string s = GetAttachmentTable(t)
    local unit u = CreateUnit(GetOwningPlayer(TrigU), 'n000', x, y, bj_UNIT_FACING)
    call UnitApplyTimedLife( u, 'BTLF', 2.80 )   
    
    call TriggerRegisterUnitInRange(trig,u,50,null)
    call TriggerAddCondition(trig, Condition(function Projectile_Hit_Cond ) )
    call SetTableObject(strng, "ta", TriggerAddAction( trig, function Projectile_Dam) )
    call SetTableObject(strng, "u", u)
    
    call SetTableReal( s, "ang", ang)
    call SetTableObject( s, "u", u)
    call SetTableObject( s, "trig", trig)
    call TimerStart(t, .03, true, function Projectile_Move)
    
    set u = null
    call RemoveLocation(l)
    call DestroyGroup(g)
    set l = null
    set trig = null     
endfunction
//works fine

Here's the catch: The ONLY thing that the fixed ward ability does is call the remove wards function on cast, and plant a stasis ward, and it still keeps getting grabbed by the other timer, even though that timer should not even be initialized for the first ward.

 

[Technomancer]

Ok, figured out one issue, and that is that I wasn't calling the remove wards func in the AdjustAngleWard function.

-Edit: No matter which way I work it, it either attaches itself to you every time, or never does. I'm probably going to end up rescripting it.

 

[Silvenon]

I don't have anything smart to say, just get rid of BJs and GUI > JASS conditions in your coding ASAP, they suck.

I'm probably going to check it up later, but someone will beat me to it by then......

EDIT: By GUI > JASS conditions I mean you should convert these:

function Trig_Set_Fixed_Angle_Stasis_Ward_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A001' ) ) then
        return false
    endif
    return true
endfunction

into this:

function Trig_Set_Fixed_Angle_Stasis_Ward_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A001'
endfunction

and you should probably learn JESP......

 

[Technomancer]

Right now I'm doing it the way that works, optimize later. <3 optimizing, but when I'm tooling around trying to make the effect happen changing one thing and bugging it while I change 3 other things before I test isn't worth the hassle but thanks for the comment.

 

[Silvenon]

Err....I'm a little confused. 'A001' is the stasis ward (moves with caster) ability, 'A002' is the other ward ability, right? Why do you have remove ward for both abilities then?

Just to note: unit variable which holds the unit which is removed later doesn't become null, you can check if a unit is removed like this (got it from Vex):

GetUnitTypeId(SomeUnit) != 0

You want to detach it from the timer, right? Instead of doing whatever you did, just detach it like this:

SetTableObject(string, &quot;Ward&quot;, <b>null</b>)

This is just a dummy example, parameters will be different in your code.

Did I understood this right?