How do you do a condition with Or?

[MasterRofl]

I have this:

private function Conds takes nothing returns boolean
    return GetUnitTypeId(GetAttacker()) == 'u002'
    return GetUnitTypeId(GetAttacker()) == 'u003'
    return GetUnitTypeId(GetAttacker()) == 'u000'
endfunction

but my trigger isn't working correctly, so I'm assuming that's wrong.

But just in case, here's the entire trigger:

Spoiler

library Entangle initializer Init
    
private struct Entangle
    unit a
    unit d
    unit t
    real x
    real y
        method onDestroy takes nothing returns nothing
            set.a = null
            set.d = null
            set.t = null
        endmethod
endstruct
    
private function Actions takes nothing returns nothing
    local Entangle e = Entangle.create()
    set e.a = GetAttacker()
    set e.t = GetTriggerUnit()
    set e.x = GetUnitX(e.t)
    set e.y = GetUnitY(e.t)
    if GetRandomInt(1, 100) < 81 then
        set e.d = CreateUnit( GetOwningPlayer(e.a), 'n000', e.x, e.y, 0. )
        call UnitAddAbility(e.d, 'A02R')
        call SetUnitAbilityLevel(e.d, 'A02R', 1)
        call IssueTargetOrder(e.d, "entanglingroots", e.t)
        //call RemoveUnit(e.d)
        call UnitApplyTimedLife(e.d, 'BTLF', 1.)
    endif
    call e.destroy()
endfunction
        
private function Conds takes nothing returns boolean
    return GetUnitTypeId(GetAttacker()) == 'u002'
    return GetUnitTypeId(GetAttacker()) == 'u003'
    return GetUnitTypeId(GetAttacker()) == 'u000'
endfunction
    
private function Init takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_ATTACKED)
    call TriggerAddCondition(t, Condition( function Conds ))
    call TriggerAddAction(t, function Actions)
    set t = null
endfunction

endlibrary

 

[Uberplayer]

private function Conds takes nothing returns boolean
    return GetUnitTypeId(GetAttacker()) == 'u002' or GetUnitTypeId(GetAttacker()) == 'u003' or GetUnitTypeId(GetAttacker()) == 'u000'
endfunction

You mean.. when any of those conditions are true, it returns true?

 

[MasterRofl]

I see, didn't think it was that simple. Newb to JASS is misleading... >_> Thanks!