System Status

[Weep]

The stun spell is set to target Air, Enemy, Friend, Ground, Invulnerable, Neutral, Organic, Vulnerable. Wouldn't that prevent casting on mechanical units?

Invulnerable, Vulnerable ought to be sufficient.

 

[Jesus4Lyf]

The stun spell is set to target Air, Enemy, Friend, Ground, Invulnerable, Neutral, Organic, Vulnerable. Wouldn't that prevent casting on mechanical units?

Invulnerable, Vulnerable ought to be sufficient.

100% correct. Updated and credit note updated. Thanks.

Mod review?

 

[Hatebreeder]

100% correct. Updated and credit note updated. Thanks.

Mod review?

Hey Jesus, i got a question:
Is AddStun(Unit,Timeout) Stackable?
For instance; Lets say you "stormbolt" (using AddStun), and stun for 3 seconds. 1 Second later, someone else uses the same ability to stun. Will it Stun for 5 Seconds?

 

[Jesus4Lyf]

Hey Jesus, i got a question:
Is AddStun(Unit,Timeout) Stackable?
For instance; Lets say you "stormbolt" (using AddStun), and stun for 3 seconds. 1 Second later, someone else uses the same ability to stun. Will it Stun for 5 Seconds?

Teh answer iz:
YES!

 

[Hatebreeder]

Teh answer iz:
YES!

Thanks xD
I counldn't figure it out :X

Also, very nice System, +REP =)

BTW, using AIDS and PUI wouldn't cause problems, no?

 

[Jesus4Lyf]

AIDS stands in place of PUI - if you use PUI you can delete it and replace it with AIDS and keep pretending you have PUI. But then you can use AIDS resources.

(But you should read the documentation on this.)

Otherwise, yes they conflict.

 

[Hatebreeder]

AIDS stands in place of PUI - if you use PUI you can delete it and replace it with AIDS and keep pretending you have PUI. But then you can use AIDS resources.

(But you should read the documentation on this.)

Otherwise, yes they conflict.

Bummers ! >_<

 

[Jesus4Lyf]

I'm gonna note here for myself that [LJASS]'Astn'[/LJASS] overwrites Stone Form and needs to be changed.

I'll do that ASAP, this should not be approved before that is fixed.

 

[Jesus4Lyf]

That is now fixed (v1.1.3), I move for this to be approved. :thup:

 

[quraji]

That is now fixed (v1.1.3), I move for this to be approved. :thup:

:thup:

I actually really like this. Works well and is very simple (in interface and implementation). The only thing I would say it's missing is an AddTimedStun function. I can understand why you wouldn't want to include one, but it seems like an essential part of a stun system (as it will be how most stuns will be used).

So, I tweaked a version to add this functionality and fix something I saw as a possible issue. It also gave me a chance to play with the new [ljass]static if[/ljass]:

library Stun initializer OnInit uses AIDS, DummyCaster, optional KT, optional TimerUtils
    globals
        public constant integer BUFF='Bstn'
        private constant integer ABIL='Astn'
        private constant integer OID_FIREBOLT=852231
    endglobals
    
    //====================================================================
    // AIDS struct for efficiently storing the "level" of stun for a unit.
    private struct StunData extends array
        integer level
        private static method AIDS_filter takes unit u returns boolean
            return GetUnitAbilityLevel(u,'Aloc')==0
        endmethod
        private method AIDS_onDestroy takes nothing returns nothing
            set this.level=0
        endmethod
        //! runtextmacro AIDS()
    endstruct
    
    //====================================================================
    // Functions.
    public function IsUnitStunned takes unit u returns boolean
        return GetUnitAbilityLevel(u,BUFF)>0
    endfunction
    
    function AddStun takes unit target returns nothing
        local StunData data=StunData[target]
        set data.level=data.level+1
        call IssueTargetOrderById(DUMMY,OID_FIREBOLT,target)
    endfunction
    
    /* qEdit: Added a check to make sure a stun is only "removed" from a unit if there is one present.
     *          This ensures that if a user accidentally uses RemoveStun extra times, it wont break.
     */
    function RemoveStun takes unit target returns nothing
        local StunData data=StunData[target]
        if data.level>0 then
            set data.level=data.level-1
        endif
        if data.level==0 then
            call UnitRemoveAbility(target,BUFF)
        endif
    endfunction
    
    /* qAdd: adds following function and automatically implements either TimerUtils or KT if they are present in the map
     * function AddTimedStun(unit target, real time)
     *     -stuns <target> for <time>
     */
    static if LIBRARY_TimerUtils then
    // timer utils first, it's better for one-shot timers, right?
        private struct tu_data
            unit u
        endstruct
        
        private function tu_RemoveTimedStun takes nothing returns nothing
            local tu_data d = GetTimerData(GetExpiredTimer())
            call RemoveStun(d.u)
            call d.destroy()
        endfunction
        
        function AddTimedStun takes unit target, real time returns nothing
            local timer t = NewTimer()
            local tu_data d = tu_data.create()
            set d.u = target
            call AddStun(target)
            call SetTimerData(t, d)
            call TimerStart(t, time, false, function tu_RemoveTimedStun)
        endfunction
        
    elseif LIBRARY_KT then
    
        private struct kt_data
            unit u
        endstruct
        
        private function kt_RemoveTimedStun takes nothing returns boolean
            local kt_data d = KT_GetData()
            call RemoveStun(d.u)
            call d.destroy()
            return true
        endfunction
        
        function AddTimedStun takes unit target, real time returns nothing
            local kt_data d = kt_data.create()
            set d.u = target
            call AddStun(target)
            call KT_Add(function kt_RemoveTimedStun, d, time)
        endfunction
    endif
    
    //====================================================================
    // Initialiser.
    private function OnInit takes nothing returns nothing
        call UnitAddAbility(DUMMY,ABIL)
    endfunction
endlibrary

Now of course you don't have to pay attention to this, but I thought I'd post it.

Once again nice little system.

 

[Jesus4Lyf]

That... is really cool. I wouldn't think it necessary for approval for this, but I'd like to add that. I think it is good. :thup:

I'll queue it up for when I have time (seems I do actually get around to it).

 

[quraji]

I agree, I don't think it's necessary to approval as the system is useful enough without the timed function. That doesn't make a self-expanding system any less cool though

Although I do think you should include the RemoveStun safety as I think it is plausible that someone call it too many times and put the stun level into the negative.

 

[Jesus4Lyf]

Bump for approval.

>Although I do think you should include the RemoveStun safety as I think it is plausible that someone call it too many times and put the stun level into the negative.

That should not be plausible - it could then remove stuns it didn't create... But I should add debug messages if you do this.

 

[quraji]

That should not be plausible - it could then remove stuns it didn't create... But I should add debug messages if you do this.

Well the problem isn't just removing stuns that aren't aren't yours, but it's also that if there stun level is 1 and you accidentally remove it twice (or if the stun level is 0 for that matter), then you have a problem.

Attached is a test map that gives an example of what I mean (in a believable way).

Even if it's not likely it could happen, breaking stuns for that unit.

 

[Jesus4Lyf]

That's the situation in which you would want a debug message, and not just a set-to-0 instead of -1. Let's say you had a massive 30 second stun spell, casting that smaller spell would remove that big stun, and if you stunned the unit again right before the end, it would only last a fraction of a second.

That's why I intend to add the debug message, but not the protection (because the protection would allow the system to behave incorrectly - doesn't actually solve anything <_<).

 

[quraji]

Let's say you had a massive 30 second stun spell, casting that smaller spell would remove that big stun, and if you stunned the unit again right before the end, it would only last a fraction of a second.

Not sure what you mean. All I know is that there should only be as many, or less, RemoveStun calls as there are AddStun calls, in total. If the stun level of a unit drops below 0 then something is wrong (and if it isn't fixed/prevented then future stuns for the unit may never work).

 

[Jesus4Lyf]

I mean like...

    function RemoveStun takes unit target returns nothing
        local StunData data=StunData[target]
        set data.level=data.level-1
        if data.level==0 then
            call UnitRemoveAbility(target,BUFF)
        endif
    endfunction

-->

    function RemoveStun takes unit target returns nothing
        local StunData data=StunData[target]
        set data.level=data.level-1
        if data.level==0 then
            call UnitRemoveAbility(target,BUFF)
        debug elseif data.level<0 then
            debug call BJDebugMsg("Stun Error - Removed more stuns than added.")
        endif
    endfunction

It is invariably going to be a code error that needs repairing, not just a user style that should be accepted. Therefore, a debug message, not a correction, is the best approach, imho. Does that makes sense?

An error like that should never be in a released version...

 

[quraji]

>I mean like...

I understand the debug message, I just didn't understand your spell example


>It is invariably going to be a code error that needs repairing, not just a user style that should be accepted. Therefore, a debug message, not a correction, is the best approach, imho. Does that makes sense?

Yes I agree that the user shouldn't do it, but if he does, and never sees the debug message...


>An error like that should never be in a released version...

True, which is why you should prevent it in your code

How about a check and a debug message, so they can fix it if they find it, but it won't be a problem if they don't catch it.

 

[Jesus4Lyf]

>but it won't be a problem if they don't catch it.
Since that will never be the case... I'd rather the mapper find it ASAP by a big phat permastun after an ability is used (with an explanation in debug mode), rather than the player find that stuns don't last the full duration randomly.

 

[quraji]

rather than the player find that stuns don't last the full duration randomly.

How does that happen?