How to make unit flash on low health ?

[megaddd]

I was playng on b.net and it was a massive unit game and all of them are important, but i couldnt see when one is about to die. So I wanted to make a trigger that makes a unit Flash so that I could notice when its dying. BUT I got 1 problem, I can't find an action "If (current health of (picked unit) is equal or below 10%) then do (blah, blah)". Please reply as soon as possible. Thanks

 

[wellwish3r]

This makes a unit below 25% health flash in random colors

Spoiler

Add to flash
    Events
        Time - Every 0.05 seconds of game time
    Conditions
    Actions
        Unit Group - Pick every unit in (Units in (Playable map area)) and do (Actions)
            Loop - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                    If - Conditions
                        (Life of (Picked unit)) Less than or equal to (25.00 x (Max life of (Picked unit)))
                    Then - Actions
                        Unit Group - Add (Picked unit) to Flash_unit_group
                    Else - Actions

Remove From flash
    Events
        Time - Every 0.50 seconds of game time
    Conditions
    Actions
        Unit Group - Pick every unit in (Units in (Playable map area)) and do (Actions)
            Loop - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                    If - Conditions
                        (Life of (Picked unit)) Greater than (0.25 x (Max life of (Picked unit)))
                    Then - Actions
                        Unit Group - Remove (Picked unit) from Flash_unit_group
                    Else - Actions

Flash
    Events
        Time - Every 0.20 seconds of game time
    Conditions
    Actions
        Unit Group - Pick every unit in Flash_unit_group and do (Actions)
            Loop - Actions
                Animation - Change (Picked unit)'s vertex coloring to ((Random real number between 0.00 and 100.00)%, (Random real number between 0.00 and 100.00)%, (Random real number between 0.00 and 100.00)%) with 0.00% transparency

youcan increase/decrease the periodic time of the Flash trigger to make it flash faster/slower

 

[megaddd]

Thanks a lot, but at what Comparison do i find the "(Life of (Picked unit)) Less than or equal to (25.00 x (Max life of (Picked unit)))" ?

 

[wellwish3r]

Thanks a lot, but at what Comparison do i find the "(Life of (Picked unit)) Less than or equal to (25.00 x (Max life of (Picked unit)))" ?

Real Comparison

 

[megaddd]

Big Thanks

 

[Flare]

(Life of (Picked unit)) Less than or equal to ([B][U]25.00[/U][/B] x (Max life of (Picked unit)))

You might wanna fix that - I don't think a unit can have 25 times more than it's maximum life

 

[MurderMode]

I dunno I think this would work easier... lol I just spent time working it out so I thought I'd post it anyways...

Hp Flash 1
    Events
        Time - Every 2.00 seconds of game time
    Conditions
    Actions
        Countdown Timer - Start HpFlashTimer as a One-shot timer that will expire in 1.00 seconds
        Unit Group - Pick every unit in (Units in (Playable map area)(((Matching unit) is A Hero) Equal to True)) and do (Actions)
            Loop - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                    If - Conditions
                        And - All (Conditions) are true
                            Conditions
                                (Percentage life of (Picked unit)) Less than or equal to 15.00
                                ((Picked unit) is in LowHP_group) Equal to False
                    Then - Actions
                        Animation - Change (Picked unit)'s vertex coloring to (100.00%, 0.00%, 0.00%) with 0.00% transparency
                        Unit Group - Add (Picked unit) to LowHP_group
                    Else - Actions

Hp Flash 2
    Events
        Time - HpFlashTimer expires
    Conditions
    Actions
        Unit Group - Pick every unit in LowHP_group and do (Actions)
            Loop - Actions
                Unit Group - Remove (Picked unit) from LowHP_group
                Animation - Change (Picked unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 0.00% transparency

 

[ManyTimes]

>>Unit Group - Pick every unit in (Units in (Playable map area)(((Matching unit) is in LowHP_group) Equal to True)
Pick every unit in "lowHP_group"?

Careful about the leaks in these triggers, picking every unit...

Instead of checking every unit in the map, you could use the event "A unit is attacked", or "A unit takes damage"... So it just checks the ones who are fighting...

Edit, seeing post beneath, if I say it could be done like this, why fight against it... If you dont know about leaks, search?

 

[MurderMode]

Well I dont know about leaks in it... it's not picking every unit in the map in that trigger, just every unit in a unit group. It should just read 'pick every unit in lowhp_group'... I just forgot to change it to that after i finished screwing with different methods. You couldn't do it any other way anyhow, if you read this thread starter its about making a unit flash when below a certain hp. If you have to wait for a unit to attack then it won't exactly flash on queue. I fixed the trigger to read correctly. I tested it simultaneously with 60 units and didn't notice any obvious slowdown so I guess it must be ok.

 

[martix]

wellwish3r, you leak, don't reset and pick an unnecessary huge amount of units all over your triggers.
So... my suggestion being:

Spoiler

Flash Event
    Events
        Unit - A unit enters (Playable map area)
    Conditions
        ((Triggering unit) is A structure) Equal to False
    Actions
        Trigger - Add to Detector <gen> the event (Unit - (Entering unit) Takes damage)

Detector
    Events
    Conditions
    Actions
        If (All Conditions are True) then do (Then Actions) else do (Else Actions)
            If - Conditions
                (Life of (Triggering unit)) Less than or equal to (0.20 x (Max life of (Triggering unit)))
            Then - Actions
                Unit Group - Add (Triggering unit) to Flasher
            Else - Actions

Flasher
    Events
        Time - Every 1.00 seconds of game time
    Conditions
    Actions
        Unit Group - Pick every unit in Flasher and do (Actions)
            Loop - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                    If - Conditions
                        (Life of (Picked unit)) Greater than or equal to (0.20 x (Max life of (Picked unit)))
                    Then - Actions
                        Unit Group - Remove (Picked unit) from Flasher
                    Else - Actions
                If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                    If - Conditions
                        FlashOn Equal to False
                    Then - Actions
                        Animation - Change (Picked unit)'s vertex coloring to (100.00%, 0.00%, 0.00%) with 0.00% transparency
                        Set FlashOn = True
                    Else - Actions
                        Animation - Change (Picked unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 0.00% transparency
                        Set FlashOn = False

Flasher - Unit Group
FlashOn - Boolean

Does not leak as far as I know, is fast, simple and foolproof.