Jass Help

[NetherHawk]

Ok i know its old - fashioned and out of date to use kattana handle vars but i'm having some problems. My trigger does not fire all the time even if i set the random integer thingy to be 100%.

function AutoFire_Jass_Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'B00X' // autofire buff
endfunction

function AutoFire_Attacker takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    return GetAttacker() == u // to check if the attacking unit is still the same? could this be the problem?
endfunction

function AutoFireGroup_Conditions takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    local boolean b1 = IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(u)) == true
    local boolean b2 = IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) == false
    local boolean b3 = IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
    local boolean b4 = IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) == false
    return b1 and b2 and b3 and b4
endfunction

function AutoFire_Attack takes nothing returns nothing
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    local unit ux = GetHandleUnit(tr,"target")
    local location ul = GetUnitLoc(u)    
    local unit d = CreateUnit( GetOwningPlayer(u), 'n005',GetLocationX(ul),GetLocationY(ul), bj_UNIT_FACING ) // create dummy to attack
    local group g = CreateGroup()
    
    
    call SetUnitPathing(d,false)    
    
    call SetHandleHandle(tr,"attacker",u)
    
    call SetUnitAbilityLevel(d,'A01C',GetUnitAbilityLevel(u,'A01D') )
    set g = GetUnitsInRangeOfLocMatching(600,ul, Condition(function AutoFireGroup_Conditions))  
    call GetRandomSubGroup(1, g)  // i doubt its cuz of no units in the group cuz the map i use has plenty of units surrounding the hero
    call UnitApplyTimedLifeBJ( 1.00, 'BTLF', d)
    call SetUnitAnimation( u, "spell" )             
    call IssueTargetOrderBJ( d, "attackonce", ux)
    call UnitAddAbility(d, 'Aloc')
    
    call DisableTrigger(tr)
    call FlushHandleLocals(tr)
    call DestroyTrigger(tr) 
    call GroupClear(g)
    call DestroyGroup(g)
    set u = null
    set ux = null
    call RemoveLocation(ul)     
    set d = null  
endfunction



function AutoFire_Jass_Actions takes nothing returns nothing
    local unit u = GetAttacker()
    local unit ux = GetAttackedUnitBJ()       
    local trigger tr = CreateTrigger()
    
    if  GetRandomInt(1, 100) <= 100 then // the 100% thing
    //if  GetRandomInt(1, 100) <= (20 + (5*(GetUnitAbilityLevel(u,'A01D')))) then //A01D spell id
            call SetHandleHandle(tr,"attacker",u)    
            call TriggerRegisterUnitEvent(tr,ux,EVENT_UNIT_DAMAGED) // to get when unit is damaged instead of the abuse attack thing 
            call TriggerAddCondition(tr, Condition( function AutoFire_Attacker ) )
            call TriggerAddAction(tr , function AutoFire_Attack)
                                                                              
            call SetHandleHandle(tr,"attacker",u)
            call SetHandleHandle(tr,"target",ux)
        else
    endif     
endfunction

//===========================================================================
function InitTrig_Auto_Fire_Jass takes nothing returns nothing
    set gg_trg_Auto_Fire_Jass = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Auto_Fire_Jass, EVENT_PLAYER_UNIT_ATTACKED )
    call TriggerAddCondition( gg_trg_Auto_Fire_Jass, Condition( function AutoFire_Jass_Conditions ) )
    call TriggerAddAction( gg_trg_Auto_Fire_Jass, function AutoFire_Jass_Actions )
endfunction

several stuff i have done to try to find out the problem is, removing the locust thing, removing the AutoFireGroup_Conditions .

 

[cr4xzZz]

You are back? Dude I missed you (you still remember me, don't you? xD)...

I suggest you forget all these handle variables and learn vJASS - you can find everything in the Tutorial Repository. It's an extension of JASS so you may find a lot of useful things when using it.
http://www.thehelper.net/forums/showthread.php?t=80241&highlight=vJASS I know it's GUI to JASS but it has some common syntax used in vJASS (nothing special, just cleaner code).
http://www.thehelper.net/forums/showthread.php?t=79426 Basic usage of structs in vJASS.

 

[NetherHawk]

off topic: ahaha yeah .. x.x i lent someone my cd and then reformatted my com so i dint have wc3 with me for a vry long time >.<!

i know who to use structs but in the end u still use handle vars/cs-system/abc to attach? so whats the diff? this part i dont understand. what are methods for? =x

on topic: asides from my method, what is the problem with the coding?

 

[chobibo]

Welcome back dude, I hope you enjoy your stay lol.

many leaks. example:

function AutoFireGroup_Conditions takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    local boolean b1 = IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(u)) == true
    local boolean b2 = IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) == false
    local boolean b3 = IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
    local boolean b4 = IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) == false
    return b1 and b2 and b3 and b4
endfunction

null local variables after using them, warcraft's handle Id recycler won't recycle the handle Id's if a local pointing to a handle is not released.

function AutoFireGroup_Conditions takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    local boolean b1 = IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(u)) == true
    local boolean b2 = IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) == false
    local boolean b3 = IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false
    local boolean b4 = IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) == false
    set tr=null
    set u=null
    return b1 and b2 and b3 and b4
endfunction

some BJ's are causing execution slowdown, some not all:

GetAttackedUnitBJ()

from the Event "A unit is attacked" so:

GetTriggerUnit()

 

[Viikuna]

Handle Vars are outdated these days because they say that I2H is dangerous and can cause some weird bugs.

Structs are integers so you can safely use Handle Vars with structs.

just use SetHandleInt and GetHandleInt.

They also say that destroying triggers is dangerous, so you should maybe try to make that spell without dynamic triggers.

 

[NetherHawk]

thx chibobo! understood viikuna .

 

[darkbeer]

just a hint you can easily use a loop to avoid making 4 booleans:

function AutoFireGroup_Conditions takes nothing returns boolean
    local trigger tr = GetTriggeringTrigger()
    local unit u = GetHandleUnit(tr,"attacker")
    loop
        exitwhen IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(u)) == false
        exitwhen IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) == true
        exitwhen IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == true
        exitwhen IsUnitType(GetFilterUnit(), UNIT_TYPE_DEAD) == true
        set tr=null
         set u=null
        return true
    endloop
    set tr=null
    set u=null
    return false
endfunction

 

[emjlr3]

wtf do you need a loop for...

return IsUnitEnemy(GetFilterUnit(), GetOwningPlayer(u)) and not IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) and not IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) and GetWidgetLife(GetFilterUnit())>.405

GetSpellAbilityId() == 'B00X' // autofire buff

will never return true because its firing off the attack event not spell cast/effect/etc. event

you want to check if:

GetUnitAbilityLevel(GetAttacker(),'XXXX')>0

the attacker has the auto fire ability

 

[NetherHawk]

oh yes! thanks for that emjlr3! that solved my problem. er close the thread?