Proper Syntax to declare "Type"

[Tyrulan]

What is the proper syntax to declare a type?

type someFunc extends myFunc

Thanks.

 

[Joker(Div)]

What are you trying to do? I never seen "type" be used. I'm not sure if it even exists.

 

[Tyrulan]

It's part of Zinc, which is downloaded as a part of NewGen.

I'm trying to declare a function pointer.

 

[Romek]

It's used like that in Zinc.
In vJass, you'd use a function interface.

// Decleration
function interface Name takes nothing returns nothing

// Example function
function Example takes nothing returns nothing
endfunction

// Within a function or method
local Name anothername = Name.Example

You can also declare your own variable types like that, but they can only extend primitive types IIRC.

type text extends string

// Function/method:
local text name = "Hello" // (I THINK this is how you use something like this; I've never found a use for these)

 

[Tyrulan]

Here's my trigger I was making as a test for it. Maybe you can get an idea where I'm going with it.

library Test

type TortureUnit extends TortureUnit
type HealFunc extends HealUnit

function TortureUnit takes unit u returns nothing
    call BJDebugMsg("Torturing Unit")
endfunction

function HealUnit takes unit u returns nothing
    call BJDebugMsg("Healing Unit")
endfunction

function AllyOrEnemy takes player p, unit u, TortureFunc c, HealFunc c2 returns nothing
    if (IsUnitAlly(u, p)) then
       // c.evaluate(u)
    else
       // c2.evaluate(u)
    endif

endfunction

function Conditions takes nothing returns boolean
    if (GetSpellAbilityId() == 'A004') then 
        return true
    endif
    return false
endfunction

function Actions takes nothing returns nothing    
    local unit caster = GetTriggerUnit()
    local unit target = GetSpellTargetUnit()
    call AllyOrEnemy (GetOwningPlayer(caster), target, TortureUnit, HealUnit)    
endfunction

//===========================================================================
function InitTrig_sandbox takes nothing returns nothing
    set gg_trg_sandbox = CreateTrigger(  )    
    call TriggerRegisterAnyUnitEventBJ(gg_trg_sandbox, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_sandbox, Condition(function Conditions))
    call TriggerAddAction( gg_trg_sandbox, function Actions )
endfunction

endlibrary

 

[Nestharus]

type someFunc extends function(args) -> returnType;

type hello extends function(unit) -> boolean;

extends is like extending in JASS. You extend the type function and you are creating a new type called hello (similar to JASS ideals).

The arguments are in the () like normal.


From here, you can create a new someFunc and set it to a function and from there call someFunc without knowing what it was, or even pass it (similar to interfaces : P).


The only issue is that it works fully off of trigger evaluations, so be careful, it'll slow you down. Ambiguous data comes at a price ;p.


Simplest that takes nothing returns nothing-

type hi extends function()

; D


Here it is out of Zinc Manual-

library Test
{
    //a function type with a single unit argument
    type onHitFunc extends function(unit);

    //a function type with two integer arguments that returns a boolean
    type evFunction extends function(itneger, integer) -> boolean;
}

I probably need to continue my guide, covering vJASS, cJASS, and Zinc : \.

 

[Romek]

> Here's my trigger I was making as a test for it. Maybe you can get an idea where I'm going with it.
You would use Function Interfaces for something like that.
Simply change the 'type..' to 'function interface..'.

 

[Nestharus]

Those are function interfaces... they are just Zinc style.

His goal is using Zinc features rather than vJASS : D.


Oh yes, you do need wrappers around your zinc code

//!zinc
//!endzinc

 

[Romek]

> Those are function interfaces... they are just Zinc style.
Yes, I know.

Though he clearly is not using Zinc in his code. I'm sure even you can see that.

 

[Tyrulan]

I'm not a pro with the Zinc wrappers. I thought there were more than just the two ie) importing files etc.

All I wanted was to have a function pointer.

I just keep getting syntax errors. :thdown:

EDIT:

Ooh got it to work. Thanks again guys.

By the way //!zinc and //!endzinc will not work.

It is:

//! zinc
....
//! endzinc

 

[Romek]

Zinc has different syntax to vJass. Read the Zinc Manual for more information.

 

[Tyrulan]

Mhm, yeah been looking at it. I took some code from it as a learning tool. Here's my completed trigger if you'd like to see it.

//! zinc
 
 library Test
    {        
        type unitFunc extends function(unit);

        function TortureUnit(unit u)
        {
            debug BJDebugMsg(GetUnitName(u)+" is being tortured!");
            AddSpecialEffectTarget("Objects\\Spawnmodels\\Orc\\Orcblood\\BattrollBlood.mdl", u, "overhead");
        }

        function HealUnit(unit u)
        {          
            debug BJDebugMsg(GetUnitName(u)+" is being healed!");    
            SetWidgetLife(u, 1000);
        }
         
        function AllyEnemyFunctionPicker(player p, unit u, unitFunc Torture, unitFunc Heal)
        {            
            if (IsUnitAlly(u, p)) 
            {
                Heal.evaluate(u);
            } else 
            {
                Torture.evaluate(u);
            }

        }
        
        function spellIDMatch() -> boolean
        {            
            return (GetSpellAbilityId() == 'A004');
        }

        function test()
        {            
            unit target = GetSpellTargetUnit();                        
            AllyEnemyFunctionPicker( Player(0), target,  TortureUnit, HealUnit );
            
            /*Will torture the unit if it is an ally, or heal it otherwise.*/
        }            
        
        function onInit()
        {            
            trigger t = CreateTrigger();
            TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT);
            TriggerAddCondition(t, Condition(function spellIDMatch));
            TriggerAddAction(t, function test);                                
        }
    }
//! endzinc